Доброго дня!

Есть два запроса. Формируют одну и ту же таблицу.
Но запрос2 в 3-4 раза быстрее формирует чем запрос1. По логике запрос1 быстрее должен формироваться.
В чем подвох?

Запрос1 = Новый Запрос;
Запрос1.Текст = "ВЫБРАТЬ
    ЭСФ.СчетФактура КАК СчетФактура,
    ЭСФ.РегистрационныйНомер,
    ЭСФ.ПометкаУдаления
ПОМЕСТИТЬ втЭСФ
ИЗ
    Документ.ЭСФ КАК ЭСФ
ГДЕ
    НЕ ЭСФ.Статус В (&СтатусОтозван)

ИНДЕКСИРОВАТЬ ПО
    СчетФактура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    РеализацияТоваровУслугТоварыПоГТД.НомерСтроки,
    РеализацияТоваровУслугТоварыПоГТД.ГТДДокумент КАК ГТДДокумент
ПОМЕСТИТЬ ВТ_Документы
ИЗ
    Документ.РеализацияТоваровУслуг.ТоварыПоГТД КАК РеализацияТоваровУслугТоварыПоГТД
ГДЕ
    РеализацияТоваровУслугТоварыПоГТД.Ссылка = &Ссылка

ИНДЕКСИРОВАТЬ ПО
    ГТДДокумент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ДокументыСФ.НомерСтроки,
    ДокументыСФ.ГТДДокумент,
    ДокументыСФ.СФ,
    МАКСИМУМ(втЭСФ.РегистрационныйНомер) КАК РегистрационныйНомер
ИЗ
    (ВЫБРАТЬ
        ВТ_Документы.НомерСтроки КАК НомерСтроки,
        ВТ_Документы.ГТДДокумент КАК ГТДДокумент,
        МАКСИМУМ(СчетФактураВыданныйДокументыОснования.Ссылка) КАК СФ
    ИЗ
        ВТ_Документы КАК ВТ_Документы
            ЛЕВОЕ СОЕДИНЕНИЕ Документ.СчетФактураПолученный.ДокументыОснования КАК СчетФактураВыданныйДокументыОснования
            ПО ВТ_Документы.ГТДДокумент = СчетФактураВыданныйДокументыОснования.ДокументОснование
    ГДЕ
        СчетФактураВыданныйДокументыОснования.Ссылка В
                (ВЫБРАТЬ
                    втЭСФ.СчетФактура
                ИЗ
                    втЭСФ КАК втЭСФ)
    
    СГРУППИРОВАТЬ ПО
        ВТ_Документы.НомерСтроки,
        ВТ_Документы.ГТДДокумент) КАК ДокументыСФ
        ЛЕВОЕ СОЕДИНЕНИЕ втЭСФ КАК втЭСФ
        ПО ДокументыСФ.СФ = втЭСФ.СчетФактура
            И (НЕ втЭСФ.ПометкаУдаления)

СГРУППИРОВАТЬ ПО
    ДокументыСФ.ГТДДокумент,
    ДокументыСФ.НомерСтроки,
    ДокументыСФ.СФ"



Запрос2 = Новый Запрос;
Запрос2.Текст = "ВЫБРАТЬ
    РеализацияТоваровУслугТоварыПоГТД.НомерСтроки,
    РеализацияТоваровУслугТоварыПоГТД.ГТДДокумент КАК ГТДДокумент
ПОМЕСТИТЬ ВТ_Документы
ИЗ
    Документ.РеализацияТоваровУслуг.ТоварыПоГТД КАК РеализацияТоваровУслугТоварыПоГТД
ГДЕ
    РеализацияТоваровУслугТоварыПоГТД.Ссылка = &Ссылка

ИНДЕКСИРОВАТЬ ПО
    ГТДДокумент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ДокументыСФ.НомерСтроки,
    ДокументыСФ.ГТДДокумент,
    ДокументыСФ.СФ,
    МАКСИМУМ(ЭСФ.РегистрационныйНомер) КАК РегистрационныйНомер
ИЗ
    (ВЫБРАТЬ
        ВТ_Документы.НомерСтроки КАК НомерСтроки,
        ВТ_Документы.ГТДДокумент КАК ГТДДокумент,
        МАКСИМУМ(СчетФактураВыданныйДокументыОснования.Ссылка) КАК СФ
    ИЗ
        ВТ_Документы КАК ВТ_Документы
            ЛЕВОЕ СОЕДИНЕНИЕ Документ.СчетФактураПолученный.ДокументыОснования КАК СчетФактураВыданныйДокументыОснования
            ПО ВТ_Документы.ГТДДокумент = СчетФактураВыданныйДокументыОснования.ДокументОснование
    ГДЕ
        СчетФактураВыданныйДокументыОснования.Ссылка В
                (ВЫБРАТЬ
                    ЭСФ.СчетФактура
                ИЗ
                    Документ.ЭСФ КАК ЭСФ
                ГДЕ
                    НЕ ЭСФ.Статус В (&СтатусОтозван))
    
    СГРУППИРОВАТЬ ПО
        ВТ_Документы.НомерСтроки,
        ВТ_Документы.ГТДДокумент) КАК ДокументыСФ
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЭСФ КАК ЭСФ
        ПО ДокументыСФ.СФ = ЭСФ.СчетФактура
            И (НЕ ЭСФ.ПометкаУдаления)
            И (НЕ ЭСФ.Статус В (&СтатусОтозван))

СГРУППИРОВАТЬ ПО
    ДокументыСФ.ГТДДокумент,
    ДокументыСФ.НомерСтроки,
    ДокументыСФ.СФ"

(7) Результат один, время выполнения - разное, ибо в 1 случае бесполезную ВТ создаем. Что именно не понятно?

(9) Ну вот. А во втором случае условие могло отработать "наоборот" - искать небольшое количество вхождений в большой таблице, не загоняя всю эту выборку во временную таблицу.

(10) Ну индексировать чтоб потом в другом запросе использовать при соединении. Или во временной таблице не надо ее?

(12) Конечно не надо

(12) Не надо, потому что только ещё больше времени потеряем на её создание как говорит (11). К тому же реквизит ЭСФ.СчетФактура вполне возможно уже индексирован (свойство реквизита в конфигурации задано) и соединение и без ВТ быстро отработает.

А нафига там вообще "В"? Почему не через соединение с ВЫРАЗИТЬ для получения статуса?

(15) +1 так сделать можно ещё ускорить

(16) Вряд ли. Скорее всего план выполнения будет похож для второго случая. Но шансов на правильный план выполнения в этом случае больше.

Еще один вопрос.

Вот здесь формируется быстро и 35 строк:

ВЫБРАТЬ
    ВТ_Документы.НомерСтроки КАК НомерСтроки,
    ВТ_Документы.ГТДДокумент КАК ГТДДокумент,
    МАКСИМУМ(СчетФактураВыданныйДокументыОснования.Ссылка) КАК СФ
ИЗ
    ВТ_Документы КАК ВТ_Документы
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.СчетФактураПолученный.ДокументыОснования КАК СчетФактураВыданныйДокументыОснования
        ПО ВТ_Документы.ГТДДокумент = СчетФактураВыданныйДокументыОснования.ДокументОснование
ГДЕ
    СчетФактураВыданныйДокументыОснования.Ссылка В
            (ВЫБРАТЬ
                ЭСФ.СчетФактура
            ИЗ
                Документ.ЭСФ КАК ЭСФ
            ГДЕ
                НЕ ЭСФ.Статус В (&СтатусОтозван))

СГРУППИРОВАТЬ ПО
    ВТ_Документы.НомерСтроки,
    ВТ_Документы.ГТДДокумент


А здесь очень долго

ВЫБРАТЬ
                ЭСФ.СчетФактура
            ИЗ
                Документ.ЭСФ КАК ЭСФ
            ГДЕ
                НЕ ЭСФ.Статус В (&СтатусОтозван)

Получается здесь подзапрос эффективнее чем через времнную таблицу?

(18) Если скорость - критерий эффективности, то чем быстрее - тем эффективнее! Ваш кэп.

(18) во втором, долгом запросе - скан всей таблицы
В первом, быстром - сик на запись ибо  ЭСФ.СчетФактура скорее всего индексировано, как предполагают выше

мне кажется, без значения статистики (состояния базы) польза от такой темы ну разве что в поиске грубых ошибок, т.к. при разной статистике планы запросов могут быть разными.
т.е. получается какой-то сферический конь в ваккуме. по факту если есть проблема- смотришь план и разбираешь его.

(21) Возможно ли средствами 1с посмотреть план запроса? Или только скул?

(18) первый запрос в плане выполнения вырождается в такое:

ИЗ
    ВТ_Документы КАК ВТ_Документы
        ВНУТР СОЕДИНЕНИЕ Документ.СчетФактураПолученный.ДокументыОснования КАК СчетФактураВыданныйДокументыОснования
        ПО ВТ_Документы.ГТДДокумент = СчетФактураВыданныйДокументыОснования.ДокументОснование
        ВНУТР СОЕДИНЕНИЕ Документ.ЭСФ КАК ЭСФ
        ПО СчетФактураВыданныйДокументыОснования.Ссылка = ЭСФ.СчетФактура И НЕ ЭСФ.Статус В (&СтатусОтозван)

(20) Т.е. если ЭСФ.СчетФактура не индексирован то в первом запросе тоже будет полное сканирование?

А вот так:

ВЫБРАТЬ
    ВТ_Документы.НомерСтроки КАК НомерСтроки,
    ВТ_Документы.ГТДДокумент КАК ГТДДокумент,
    МАКСИМУМ(СчетФактураВыданныйДокументыОснования.Ссылка) КАК СФ
ИЗ
    ВТ_Документы КАК ВТ_Документы
        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
                         СчетФактураВыданныйДокументыОснования.Ссылка
                        ,СчетФактураВыданныйДокументыОснования.ДокументОснование
                ИЗ Документ.СчетФактураПолученный.ДокументыОснования КАК СчетФактураВыданныйДокументыОснования
                ГДЕ
                    СчетФактураВыданныйДокументыОснования.Ссылка В
                            (ВЫБРАТЬ
                                ЭСФ.СчетФактура
                            ИЗ
                                Документ.ЭСФ КАК ЭСФ
                            ГДЕ
                                НЕ ЭСФ.Статус В (&СтатусОтозван))
                ) как СчетФактураВыданныйДокументыОснования

        ПО ВТ_Документы.ГТДДокумент = СчетФактураВыданныйДокументыОснования.ДокументОснование

СГРУППИРОВАТЬ ПО
    ВТ_Документы.НомерСтроки,
    ВТ_Документы.ГТДДокумент

(24) да

(22) https://its.1c.ru/db/metod8dev/content/5808/hdoc читать про plansql, много думать, пробовать.

В (25) к (18).

(24) зачем людям голову морочить? сложно посмотреть и ответить??

(0) Потому что голову нужно включать.
Тебе нужны СФ по указанным реализациям.
Зачем ты выбираешь ВСЕ СФ?

Порядок должен быть такой:
1. выбрать реализацию за период.
2. выбрать сф по указанным реализациям (с фильтром по статусу).
3. Собрать всё в кучу.

(28) Тоже долго

(31) Это понятно. Но в сравнении с 18 обоими как?

(32) Первоначально первом запрос в среднем было 6-8 сек. во втором 1-2 сек. В твоем 5-6

(33) Первый и второй, которые в (18) или который в (0)?

(34) 0

НЕЕЕЕ сравнивай с (18)

Ещё вопрос. В //*** не пробовал кусочек добавить?

ИЗ
    ВТ_Документы КАК ВТ_Документы
        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
                         ...
                ИЗ Документ.СчетФактураПолученный.ДокументыОснования
                ГДЕ
                    СчетФактураВыданныйДокументыОснования.Ссылка В (...)

//**********************************
И СчетФактураВыданныйДокументыОснования.ДокументОснование в (
ВЫБРАТЬ
    ВТ_Документы.ГТДДокумент КАК ГТДДокумент,
ИЗ
    ВТ_Документы КАК ВТ_Документы
)
//**********************************

) как СчетФактураВыданныйДокументыОснования

Ок, всем спасибо. Попробую варианты

У тебя основная таблица ВТ_Документы. К ней ты цепляешь другую таблицу, связывая по некому полю. Так возьми сразу только те, которые входят в значение этого поля.

(39) ок, попробую

И условие тоже можно поменять. Сначала то что в //**** максимально обрежет множество, а потом уточняющее условие на ГДЕ СчетФактураВыданныйДокументыОснования.Ссылка В (...).
По идее должно быть одинаково, но бывают случаи, что не одинаково.

дааа, стыдно на мою седую голову ))))

ВЫБРАТЬ
    РеализацияТоваровУслугТоварыПоГТД.НомерСтроки,
    РеализацияТоваровУслугТоварыПоГТД.ГТДДокумент КАК ГТДДокумент
ПОМЕСТИТЬ ВТ_Документы
ИЗ
    Документ.РеализацияТоваровУслуг.ТоварыПоГТД КАК РеализацияТоваровУслугТоварыПоГТД
ГДЕ
    РеализацияТоваровУслугТоварыПоГТД.Ссылка = &Ссылка

ИНДЕКСИРОВАТЬ ПО
    ГТДДокумент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
     СчетФактураВыданныйДокументыОснования.Ссылка
    ,СчетФактураВыданныйДокументыОснования.ДокументОснование
ПОМЕСТИТЬ ВТ_СФ
ИЗ
    Документ.СчетФактураПолученный.ДокументыОснования КАК СчетФактураВыданныйДокументыОснования
ГДЕ
    СчетФактураВыданныйДокументыОснования.ДокументОснование В
                (ВЫБРАТЬ
                    Т.ГТДДокумент
                ИЗ
                    ВТ_Документы КАК Т
                 )
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЭСФ.СчетФактура КАК СчетФактура,
    ЭСФ.РегистрационныйНомер,
    ЭСФ.ПометкаУдаления
ПОМЕСТИТЬ втЭСФ
ИЗ
    Документ.ЭСФ КАК ЭСФ
ГДЕ
         ЭСФ.СчетФактура в (ВЫБРАТЬ Т.Ссылка ИЗ ВТ_СФ КАК Т)
    И (НЕ ЭСФ.ПометкаУдаления)
    И НЕ ЭСФ.Статус В (&СтатусОтозван)

ИНДЕКСИРОВАТЬ ПО
    СчетФактура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ДокументыСФ.НомерСтроки,
    ДокументыСФ.ГТДДокумент,
    ДокументыСФ.СФ,
    МАКСИМУМ(ЭСФ.РегистрационныйНомер) КАК РегистрационныйНомер
ИЗ
    (ВЫБРАТЬ
        ВТ_Документы.НомерСтроки КАК НомерСтроки,
        ВТ_Документы.ГТДДокумент КАК ГТДДокумент,
        МАКСИМУМ(СчетФактураВыданныйДокументыОснования.Ссылка) КАК СФ
    ИЗ
        ВТ_Документы КАК ВТ_Документы
            ЛЕВОЕ СОЕДИНЕНИЕ ВТ_СФ КАК СчетФактураВыданныйДокументыОснования
            ПО ВТ_Документы.ГТДДокумент = СчетФактураВыданныйДокументыОснования.ДокументОснование
    
    СГРУППИРОВАТЬ ПО
        ВТ_Документы.НомерСтроки,
        ВТ_Документы.ГТДДокумент
    ) КАК ДокументыСФ

    ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЭСФ КАК ЭСФ
    ПО ДокументыСФ.СФ = ЭСФ.СчетФактура

СГРУППИРОВАТЬ ПО
    ДокументыСФ.ГТДДокумент,
    ДокументыСФ.НомерСтроки,
    ДокументыСФ.СФ

Что-то скопировалось не всё....
Посмотри на английские и русские буквы, мог напортачить. Ну так по мелочи....

ВЫБРАТЬ
    РеализацияТоваровУслугТоварыПоГТД.НомерСтроки,
    РеализацияТоваровУслугТоварыПоГТД.ГТДДокумент КАК ГТДДокумент
ПОМЕСТИТЬ ВТ_Документы
ИЗ
    Документ.РеализацияТоваровУслуг.ТоварыПоГТД КАК РеализацияТоваровУслугТоварыПоГТД
ГДЕ
    РеализацияТоваровУслугТоварыПоГТД.Ссылка = &Ссылка

ИНДЕКСИРОВАТЬ ПО
    ГТДДокумент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
     СчетФактураВыданныйДокументыОснования.Ссылка
    ,СчетФактураВыданныйДокументыОснования.ДокументОснование
ПОМЕСТИТЬ ВТ_СФ
ИЗ
    Документ.СчетФактураПолученный.ДокументыОснования КАК СчетФактураВыданныйДокументыОснования
ГДЕ
    СчетФактураВыданныйДокументыОснования.ДокументОснование В
                (ВЫБРАТЬ
                    Т.ГТДДокумент
                ИЗ
                    ВТ_Документы КАК Т
                 )
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЭСФ.СчетФактура КАК СчетФактура,
    ЭСФ.РегистрационныйНомер,
    ЭСФ.ПометкаУдаления
ПОМЕСТИТЬ втЭСФ
ИЗ
    Документ.ЭСФ КАК ЭСФ
ГДЕ
         ЭСФ.СчетФактура в (ВЫБРАТЬ Т.Ссылка ИЗ ВТ_СФ КАК Т)
    И (НЕ ЭСФ.ПометкаУдаления)
    И НЕ ЭСФ.Статус В (&СтатусОтозван)

ИНДЕКСИРОВАТЬ ПО
    СчетФактура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ДокументыСФ.НомерСтроки,
    ДокументыСФ.ГТДДокумент,
    ДокументыСФ.СФ,
    МАКСИМУМ(ЭСФ.РегистрационныйНомер) КАК РегистрационныйНомер
ИЗ
    (ВЫБРАТЬ
        ВТ_Документы.НомерСтроки КАК НомерСтроки,
        ВТ_Документы.ГТДДокумент КАК ГТДДокумент,
        МАКСИМУМ(СчетФактураВыданныйДокументыОснования.Ссылка) КАК СФ
    ИЗ
        ВТ_Документы КАК ВТ_Документы
            ЛЕВОЕ СОЕДИНЕНИЕ ВТ_СФ КАК СчетФактураВыданныйДокументыОснования
            ПО ВТ_Документы.ГТДДокумент = СчетФактураВыданныйДокументыОснования.ДокументОснование
    
    СГРУППИРОВАТЬ ПО
        ВТ_Документы.НомерСтроки,
        ВТ_Документы.ГТДДокумент
    ) КАК ДокументыСФ

    ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЭСФ КАК ЭСФ
    ПО ДокументыСФ.СФ = ЭСФ.СчетФактура

СГРУППИРОВАТЬ ПО
    ДокументыСФ.ГТДДокумент,
    ДокументыСФ.НомерСтроки,
    ДокументыСФ.СФ

Результат отпишись. Интересно же.

(45) По сравнению с первым запросом (0) 30 раз быстрее ))

респект! спасибо! ознакомлюсь с твоим запросом на досуге

(46) вообще-то еще из-за кеша может быть. Если запустить 2 идентичных запроса, то 2-й запрос обычно выполняется в 10 раз быстрее, чем первый. Потому что он использует кеш после первого запроса.

(47) Не за что.
Это не мой запрос, а твой :-)
Просто не вдумываясь, что он там делает и какая структура данных он был немного переписан.
Если структуру глянуть, где и какие индексы, то возможно можно ещё быстрее. В данном случае изначально не оптимально был сделан сам запрос.

(49) Вообщето запрос не мой тоже )) Дали мне просьбу оптимизировать )

:-)
Везет же кому-то!!! :-)

(44) Можешь объяснить такой нюанс?

Ф.СчетФактура в (ВЫБРАТЬ Т.Ссылка ИЗ ВТ_СФ КАК Т)
    И (НЕ ЭСФ.ПометкаУдаления)
    И НЕ ЭСФ.Статус В (&СтатусОтозван)ЭС


вот этот "И НЕ ЭСФ.Статус В (&СтатусОтозван)" будет сканировать уже отобранные ЭСФшки?

Если был бы так, то замедлился бы?

НЕ ЭСФ.Статус В (&СтатусОтозван)
    И (НЕ ЭСФ.ПометкаУдаления)
    И ЭСФ.СчетФактура в (ВЫБРАТЬ Т.Ссылка ИЗ ВТ_СФ КАК Т)

(44) И еще. Третий пакет вроде нигде не используется. Странно

3-й пакет убрал, три раза быстрее стало

Вместо
    ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЭСФ КАК ЭСФ
    ПО ДокументыСФ.СФ = ЭСФ.СчетФактура

    ЛЕВОЕ СОЕДИНЕНИЕ втЭСФ КАК ЭСФ
    ПО ДокументыСФ.СФ = ЭСФ.СчетФактура

Это я забыл доисправлять...

При создании "ВТ_СФ" необходимо добавить Индекс по полю "ДокументОснование"....
И т.д.

Это примерный вариант, но ход мысли понятно думаю...

А вообще если нужна производительность, то виртуальные таблицы лучше не использовать....
Но тогда будет малочитаемый код и копипаст сплошной.
Виртуальные таблицы не сильно влияют на производительность, если они не большие. Тогда на производительность это сильно не повлияет.

(58) Имел ввиду временные таблицы?

да

ок, спасибо

(58) Настало время оуительных историй

(57) Индексы в ВТ не нужны.

(58) иногда лучше ничего не писать

(62) (64) Пишите свой вариант.

(62) и (64) Где ваши варианты? Ждать?

(66) Мой не ждать. Мне лениво в этой каше разбираться.

(67) Тогда каков вклад в пользу дела?

(68) Покритиковать глупые высказывания.

(69) одно из таких в (63)

(70) Давай, расскажи, как ты юудешь использовать индексы в ВТ

(71) Мне лениво

(72) Ну значит ваш удел прозябать в невежестве.

(71), (72)
А мне не лень. Ниже запрос с закомментированным индексом. Выполнить можно на любой базе - от данных не зависит.
Без интекса у меня выполняется 3 сек. С индексом 1 сек.
(71) Давай расскажи почему так?

ВЫБРАТЬ
    0 КАК А
ПОМЕСТИТЬ ВТ_Два

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    1

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    2
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ ПЕРВЫЕ 11
    ВТ_Два.А * 3 + ВТ_Два1.А * 2 + ВТ_Два2.А КАК А
ПОМЕСТИТЬ ВТ_Десять
ИЗ
    ВТ_Два КАК ВТ_Два,
    ВТ_Два КАК ВТ_Два1,
    ВТ_Два КАК ВТ_Два2

УПОРЯДОЧИТЬ ПО
    А
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ВТ_Два
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ ПЕРВЫЕ 5000
    ВТ_Десять3.А * 1000 + ВТ_Десять2.А * 100 + ВТ_Десять1.А * 10 + ВТ_Десять.А КАК А
ПОМЕСТИТЬ ВТ_1000
ИЗ
    ВТ_Десять КАК ВТ_Десять,
    ВТ_Десять КАК ВТ_Десять1,
    ВТ_Десять КАК ВТ_Десять2,
    ВТ_Десять КАК ВТ_Десять3

УПОРЯДОЧИТЬ ПО
    А
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_1000.А КАК А,
    ДОБАВИТЬКДАТЕ(&ДатаН, ДЕНЬ, ВТ_1000.А) КАК Дата
ПОМЕСТИТЬ ВТ_Даты
ИЗ
    ВТ_1000 КАК ВТ_1000

//ИНДЕКСИРОВАТЬ ПО
//    А,
//    Дата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    т1.А КАК А,
    т1.Дата КАК Дата,
    т2.А КАК А1,
    т2.Дата КАК Дата1
ИЗ
    ВТ_Даты КАК т1
        ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Даты КАК т2
        ПО т1.А <= т2.А
            И т1.Дата >= т2.Дата

К (74) "Без интекса у меня выполняется 3 сек. С индексом 1 сек." - это когда десяток раз запускаешь с индексом и десяток раз без индекса и в перемешку по нескольку раз. Для чистоты эксперимента.

(74) Потому что используется индекс. В этом уникальном случае.

Но когда ты соединяешь свою 'относительно' небольшую временную таблицу с большой физической, то индекс временной таблицы использоваться не будет. В лучшем случае используется индекс физической таблицы и !порядок! записей временной таблицы.

(77) и почему же в запросе ниже индекс ВТ использоваться не будет (если бы он был)
ИЗ
    Документ.ЭСФ КАК ЭСФ
ГДЕ
         ЭСФ.СчетФактура в (ВЫБРАТЬ Т.Ссылка ИЗ ВТ_СФ КАК Т)

(78) + или в таком
ИЗ
        ВТ_Документы КАК ВТ_Документы
            ЛЕВОЕ СОЕДИНЕНИЕ ВТ_СФ КАК СчетФактураВыданныйДокументыОснования
            ПО ВТ_Документы.ГТДДокумент = СчетФактураВыданныйДокументыОснования.ДокументОснование

(78) Потому что, чтобы использовался индекс, надо, чтобы каждый документ ЭСФ поискал своим полем в таблице ВТ_СФ
Нужно перебрать все документы ЭСФ

(78) тут нужен индекс ВТ_СФ.Ссылка
(79) а тут - ВТ_СФ.ДокументОснование

(79) В таком, если записей мало, то проще обойти весь индекс (indexscan) через mergejoin. А если записей много - то вы сами себе злые буратины пихать большие куски в ВТ.
Это у вас сейчас, в спокойной системе ВТ и индексы строятся махом, вы попробуйте в нагруженной.

(76) В (63) вы написали "Индексы в ВТ не нужны."
А тут оказывается нужны.

(80) справедливо, если знаем, что есть индекс ЭСФ.СчетФактура

(82) а mergejoin по вашему святым духом питается?
Вообще то, для его выполнения, нужно для начала два источника упорядочить. За сколько то и где то.

(82) Я это ещё в (58) написал. Но в данном случае в (0) просил найти узкое место. В самом запросе их хватало. На выходе ВТ не большие будут - в разрезе ТЧ с ГТД по одному документу. Это не большие ВТ. Так что большой потери производительности тут не будет и что бы понять в чем узкое место вполне достаточно оставить ВТ, что бы не путать сложными конструкциями.

А вам бы только покритиковать, вместо того что бы применить свои знания с пользой дела. Как-то так получается. :-(

(0) Вам сильно помогла критика "H A D G E H O G s" и "Жан Пердежон"?

(85) поэтому, лучше вместо условно двух наборов упорядочивающих служебных данных (индексов по сути), один индекс и лупджойн по нему

(85) СОртировка проще индексации, так как индексация включает в себя сортировку.

(87) Нет, не индексов по сути, а сортировок.

(88) а я бы сказал наоборот: сортировка включает в себя индексацию, если сортировка не предполагает перестановку записей источника.

SQL, кстати, вполне себе сам выполнит сортировку, если захочет сделать merge. Но, тут можно оказать медвежью услугу, когда SQL не хотел делать merge, а у него на входе отсортированная таблица (не особо важно, через Индекс или через Упорядочить).

(90) Сортировка строит и хранит копию части данных в B+ дереве? Я все правильно вас понял?

(91) "SQL, кстати, вполне себе сам выполнит сортировку, если захочет сделать merge"
да, именно. И это нифига не дешево

(93) Но дешевле индексации

(84) есть или нет индекса в ЭСФ.СчетФактура - это не важно. Важно, что индекс в ВТ_СФ в лучшем случае будет использоваться в mergejoin как источник упорядоченных данных и может подтолкнуть SQL к mergejoin вместо nestedloop.

(95) нет, индекс в ВТ_СФ как раз подтолкнет SQL к nestedloop вместо mergejoin

(96) + повторю. в случае отсутствия индекса ЭСФ.СчетФактура. И это важно

(86) Помог только твой лайфхак

(96) Будет цикл, для каждой записи таблицы документа ЭСФ, будет искаться соответствующая запись в ВТ по ее индексу? Я правильно понял?

(92) нет, сортировка - выстраивание идентификаторов записей источник в нужном порядке.

Например:
имеем источник И1 - много записей, и И2 - мало записей
и И1 join И2

для мерджа нужно отсортировать и И1 и И2
для лупа можно проиндексировать только И2, по И1 пройтись как есть выдергивая из И2 то что нужно

(100) + и если И2 - это наша ВТ, то вполне оправдано ее проиндексировать, и не утверждать что "Индексы в ВТ не нужны."

(100) А индексирование - это выстраивание идентификаторов записей источник в нужном порядке и построение по ним b+ дерева.

(101) Это если не нарвешься на hashjoin. В вашем, синтетическом, не нарвешься.

(102) только двоичное дерево строится по ключу индекса, а идентификаторы записей в листьях

(103) ну так все таки, индексы в ВТ бывают нужны?

(104) Чтобы построить дерево поиска, данные нужно отсортировать
Не находишь никакой закономерности?
http://cburch.com/cs/340/reading/btree/btree-6.png

(105) Нужно соединять 2 таблицы, временная таблица должна быть мала (но это очевидно и так) при этом физическая таблица не должна содержать индексов по полям соединения и условие соединения должно быть больше или меньше. Да, в таком охренено распространном случае нужно индексировать.

На как и прогнозировалось.

Выполнил твой пример без индексов и без больше-меньше

        ПО т1.А = т2.А
            И т1.Дата = т2.Дата

Прекрасный hashjoin за 0.03 секунды.

http://prntscr.com/uvgw7i

(108) "без индексов и без больше-меньше" - это не мой пример
Я привел пример, когда индекс оправдан