Как в условии указать что ПОСЛЕДНИЙ документ был позже чем полгода назад?

Максимум()<подгоданазад

Выбрать максимум(датадок), Клиентос
ИЗ...
Сгруппировтаь по клиентос
имеющие максимум(датаДок)>Твоядата

спасибо

ВЫБРАТЬ
    РеализацияТоваровУслуг.Ссылка КАК Ссылка,
    МАКСИМУМ(РеализацияТоваровУслуг.Дата) КАК Дата,
    РеализацияТоваровУслуг.Контрагент.Ссылка КАК КонтрагентСсылка,
    РеализацияТоваровУслуг.Контрагент.ИНН КАК КонтрагентИНН,
    РеализацияТоваровУслуг.Контрагент.ОсновнойМенеджерПокупателя КАК КонтрагентОсновнойМенеджерПокупателя
ИЗ
    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
ГДЕ
    РеализацияТоваровУслуг.Контрагент.Родитель = &Родитель
    И РеализацияТоваровУслуг.Дата < &Дата

СГРУППИРОВАТЬ ПО
    РеализацияТоваровУслуг.Контрагент.Ссылка,
    РеализацияТоваровУслуг.Ссылка,
    РеализацияТоваровУслуг.Контрагент.ИНН,
    РеализацияТоваровУслуг.Контрагент.ОсновнойМенеджерПокупателя
ИТОГИ ПО
    КонтрагентСсылка

чот фигня получается(в консоли запросов делаю)

ИМЕЮЩИЕ МАКСИМУМ(РеализацияТоваровУслуг.Дата) < &Дата

(5) Ошибка при вызове метода контекста (Выполнить): {(3, 2)}: Синтаксическая ошибка "ИМЕЮЩИЕ"
<<?>>ИМЕЮЩИЕ МАКСИМУМ(РеализацияТоваровУслуг.Дата) КАК Дата,

ой не то скопировал

Ошибка при вызове метода контекста (Выполнить): {(11, 4)}: Синтаксическая ошибка "ИМЕЮЩИЕ"
И <<?>>ИМЕЮЩИЕ МАКСИМУМ(РеализацияТоваровУслуг.Дата) < &Дата

(8) и в какое место ты это запихал ?
И Итоги выкинь

и группировку по ссылке

и обращение к .ссылка везде

а чтоб ещё условие "у контрагента нет задолженности" нужно запрос дописывать к Хозрасчетный 62 счет?

(12) нужно программиста позвать

(13) Чего ты такой токсичный (тм) у утра?

(14) я ядовит всегда.

Ну короч, сделал отчет, который показывает контрагентов, которые ничего не покупали полгода последние, нужно ещё из них выбрать тех, у кого нет задолженности, подсккажите

(16) >> выбрать тех, у кого нет задолженности.

Нет задолженности на какую дату? На сегодня, на "полгода назад", вообще в течении этого последнего полугодовая? Может у контрагента сейчас задолженности нет, но ещё вчера была и он её закрыл или бухи её списали в убытки как безнадёжную.

(16)
Добавь левое соединение с продажами и наложи условие СуммаПродаж ЕСТЬ NULL
Добавь левое соединение с регистром взаиморасчётов и наложи условие ЕСТЬNULL(СуммаДолга,0) = 0

(17) не было продаж полгода и на сегодняшний день нет задолженности

(18) спасибо, сча попробую

(19) Как-то так.

Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
|    ХозрасчетныйОстатки.Субконто1 КАК Контрагент,
|    ХозрасчетныйОстатки.СуммаОстаток КАК СуммаОстаток
|ПОМЕСТИТЬ КонтрагентыИмеющиеЗадолженность
|ИЗ
|    РегистрБухгалтерии.Хозрасчетный.Остатки(&Дата, Счет В (&СчетаУчетаВзаиморасчетов), ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.Контрагенты)) КАК ХозрасчетныйОстатки
|
|ИНДЕКСИРОВАТЬ ПО
|    Контрагент
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|    МАКСИМУМ(РеализацияТоваровУслуг.Дата) КАК Дата,
|    РеализацияТоваровУслуг.Контрагент КАК Контрагент
|ПОМЕСТИТЬ СбежавшиеОтНасПокупатели
|ИЗ
|    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
|ГДЕ
|    РеализацияТоваровУслуг.Проведен
|
|СГРУППИРОВАТЬ ПО
|    РеализацияТоваровУслуг.Контрагент
|
|ИМЕЮЩИЕ
|    МАКСИМУМ(РеализацияТоваровУслуг.Дата) < &Дата
|
|ИНДЕКСИРОВАТЬ ПО
|    Контрагент
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|    СбежавшиеОтНасПокупатели.Контрагент КАК Контрагент
|ИЗ
|    СбежавшиеОтНасПокупатели КАК СбежавшиеОтНасПокупатели
|        ЛЕВОЕ СОЕДИНЕНИЕ КонтрагентыИмеющиеЗадолженность КАК КонтрагентыИмеющиеЗадолженность
|        ПО СбежавшиеОтНасПокупатели.Контрагент = КонтрагентыИмеющиеЗадолженность.Контрагент
|ГДЕ
|    КонтрагентыИмеющиеЗадолженность.СуммаОстаток ЕСТЬ NULL";
Запрос.УстановитьПараметр("Дата", Дата);
Запрос.УстановитьПараметр("СчетаУчетаВзаиморасчетов", УчетВзаиморасчетов.ПолучитьТаблицуСчетовУчетаВзаиморасчетов().ВыгрузитьКолонку("СчетУчета"));