СтрНайти СтрРазделить на УТ10 но новой 1С

Функция СтрСравнить(Перем1, Перем2) Экспорт

    СравнениеЗначений = Новый СравнениеЗначений;

    Результат = СравнениеЗначений.Сравнить(Перем1, Перем2);

    Возврат Результат;

КонецФункции

Функция СтрРазделить(Текст, Разделитель, ВключатьПустые = Ложь) Экспорт

    Результат = РазложитьСтрокуВМассивПодстрокБСП(Текст, Разделитель);

    Возврат Результат;

КонецФункции

// Функция "расщепляет" строку на подстроки, используя заданный
//        разделитель. Разделитель может иметь любую длину.
//        Если в качестве разделителя задан пробел, рядом стоящие пробелы
//        считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр
//        игнорируются.
//        Например,
//        РазложитьСтрокуВМассивПодстрок(",ку,,,му", ",") возвратит массив значений из пяти элементов,
//        три из которых - пустые строки, а
//        РазложитьСтрокуВМассивПодстрок(" ку   му", " ") возвратит массив значений из двух элементов
//
//    Параметры:
//        Стр -             строка, которую необходимо разложить на подстроки.
//                        Параметр передается по значению.
//        Разделитель -     строка-разделитель, по умолчанию - запятая.
//
//
//    Возвращаемое значение:
//        массив значений, элементы которого - подстроки
//
Функция РазложитьСтрокуВМассивПодстрокБСП(Знач Стр, Разделитель = ",") Экспорт

    МассивСтрок = Новый Массив();
    Если Разделитель = " " Тогда
        Стр = СокрЛП(Стр);
        Пока 1=1 Цикл
            Поз = Найти(Стр,Разделитель);
            Если Поз=0 Тогда
                МассивСтрок.Добавить(Стр);
                Возврат МассивСтрок;
            КонецЕсли;
            МассивСтрок.Добавить(Лев(Стр,Поз-1));
            Стр = СокрЛ(Сред(Стр,Поз));
        КонецЦикла;
    Иначе
        ДлинаРазделителя = СтрДлина(Разделитель);
        Пока 1=1 Цикл
            Поз = Найти(Стр,Разделитель);
            Если Поз=0 Тогда
                МассивСтрок.Добавить(Стр);
                Возврат МассивСтрок;
            КонецЕсли;
            МассивСтрок.Добавить(Лев(Стр,Поз-1));
            Стр = Сред(Стр,Поз+ДлинаРазделителя);
        КонецЦикла;
    КонецЕсли;

КонецФункции // глРазложить

Функция СтрСоединить(МассивСтрок, Разделитель = "") Экспорт

    Результат = "";

    Для Каждого ЭлементМассива Из МассивСтрок Цикл

        Результат = Результат + ЭлементМассива + Разделитель;

    КонецЦикла;

    ОтрезатьСимволов = СтрДлина(Разделитель);

    ОставитьСимволов = СтрДлина(Результат) - ОтрезатьСимволов;

    Результат = Лев(Результат, ОставитьСимволов);

    Возврат Результат;

КонецФункции

Функция СтрНачинаетсяС(НачалоСтроки, СтрокаПоиска) Экспорт

    КолВоСимволов = СтрДлина(СтрокаПоиска);

    КолВоСимволовНачалоСтроки = СтрДлина(НачалоСтроки);

    Если КолВоСимволов = 0 ИЛИ КолВоСимволовНачалоСтроки = 0 Тогда

        Возврат Ложь;

    КонецЕсли;

    Если Лев(НачалоСтроки, КолВоСимволов) = СтрокаПоиска Тогда

        Результат = Истина;

    Иначе

        Результат = Ложь;

    КонецЕсли;

    Возврат Результат;

КонецФункции

Функция СтрНайти(Строка, ПодстрокаПоиска, НаправлениеПоиска = Неопределено, НачальнаяПозиция = Неопределено, НомерВхождения = 1) Экспорт
    // НаправлениеПоиска: СКонца,СНачала. По умолчанию: СНачала

    Если Строка = "" и ПодстрокаПоиска = "" Тогда
        // чтобы отрабатывало как в платформе
        Если НаправлениеПоиска = "СКонца" Тогда
            Если НомерВхождения = 1 Тогда
                Возврат 1;
            Иначе
                Возврат 0;
            КонецЕсли;
        Иначе
            Возврат мин(НомерВхождения, ?(НачальнаяПозиция=Неопределено, 1, НачальнаяПозиция));
        КонецЕсли;
    КонецЕсли;

    Если НачальнаяПозиция = Неопределено Тогда
        Если НаправлениеПоиска = "СКонца" Тогда
            лНачальнаяПозиция = СтрДлина(Строка);
        Иначе
            лНачальнаяПозиция = 1;
        КонецЕсли;
    Иначе
        лНачальнаяПозиция = НачальнаяПозиция;
    КонецЕсли;

    Если НаправлениеПоиска = "СКонца" Тогда
        лСтрока = "";
        Для сч = 1 По СтрДлина(Строка) Цикл
            лСтрока = Сред(Строка, сч, 1) + лСтрока;
        КонецЦикла;
        лПодстрокаПоиска = "";
        Для сч = 1 По СтрДлина(ПодстрокаПоиска) Цикл
            лПодстрокаПоиска = Сред(ПодстрокаПоиска, сч, 1) + лПодстрокаПоиска;
        КонецЦикла;
        лНачальнаяПозиция = макс(1, СтрДлина(Строка)-лНачальнаяПозиция-СтрДлина(ПодстрокаПоиска)+2);
    Иначе
        лСтрока = Строка;
        лПодстрокаПоиска = ПодстрокаПоиска;
        лНачальнаяПозиция = лНачальнаяПозиция;
    КонецЕсли;

    лНомерВхождения = 0;
    Результат = Найти(Сред(лСтрока, лНачальнаяПозиция), лПодстрокаПоиска);
    Пока Результат Цикл
        лНачальнаяПозиция = Результат + лНачальнаяПозиция + СтрДлина(ПодстрокаПоиска)-1;
        лНомерВхождения = лНомерВхождения + 1;
        Если лНомерВхождения = НомерВхождения Тогда
            Прервать;
        КонецЕсли;
        Результат = Найти(Сред(лСтрока, лНачальнаяПозиция), лПодстрокаПоиска);
    КонецЦикла;

    Если лНомерВхождения = НомерВхождения Тогда
        Результат = лНачальнаяПозиция - СтрДлина(ПодстрокаПоиска);
    Иначе
        Результат = 0;
    КонецЕсли;

    Если НаправлениеПоиска = "СКонца" И Результат<>0 Тогда
        Результат = СтрДлина(Строка) - Результат - СтрДлина(ПодстрокаПоиска) + 2;
    КонецЕсли;

    Возврат Результат;

КонецФункции