Привет честнОй компании!

Требуется обмен информацией через OData с несколькими базами по нажатию кнопки из журнала документов.
Конфигурация БП 3.0
Реализовал дополнительную обработку "Вызов серверного метода", но неясно как извещать пользователя о возникающих ошибках.

Оборачивать в попытки и вызывать исключения? Или есть какой-нибудь внятный БСПшный механизм?

(0) Сообщить()

(1) я так понимаю ему надо в другой базе сообщить, мол обмен не прошел, но вы держитесь)

(2) в этом случае как вариант:  письмом на корпоративную почту. Можно сервер взаимодействия попробовать прикрутить. Можно файл лога вести. Можно регистр для этого дела завести. В общем тут на ваш цвет и вкус, хоть ВК пишите и слушайте что вам другая база скажет)

(2) Не, просто сообщить текущему пользователю.

"Вызов серверного метода" запускается как фоновое задание, и Сообщить() оттуда не сообщает(

файл лога спасает меня при отладке, но для пользователя это неприемлимо.

Пользователю надо показать окошко с кнопкой или типа того. Что-нибудь самое понятное и незамысловатое.

Пиши в лог, а у клиента крути обработку ожидания, которая читает его.
Или систему взаимодействия покупай.

(4) все что я перечислил и для текущего пользователя сканает.

(4) самое простое это письмо слать

ФоновоеЗадание (BackgroundJob)
ПолучитьСообщенияПользователю (GetUserMessages)

Вроде в БСП было что-то такое

Самое простое - открывать форму, а из неё уже стартовать задание и в форме же ловить сообщения.

А чтобы и форму не рисовать?
(8)  Покурим...

(10) что то мне подсказывает, что ПолучитьСообщенияПользователю  не взлетит, но могу ошибаться.

Что там ни пиши, оно будет выполняться в контексте фонового задания, можно накопить сообщения, но показать их должна БСП, которая запускает фоновое задание.

Попробую вызывать Исключения. Письма слать - не вариант)

(10) форма есть уже "по нажатию кнопки из журнала документов" в (0)

(0) Для начала какому пользователю собираешься сообщать?

(14)+ И что делать если он сволочь такая в базу 1С не заходит?

(11) ошибаешься

(14) Сообщение пользователю, который запускает обработку из базы -источника.

База -источник будет стучаться в сторонний сервис, в базу- приемник, собирать ГУИДы, формировать структуру данных и, наконец, постить документ в базу-приемник.

ПолучитьСообщенияПользователю() как я понимаю нужно вызывать как бы "со стороны" по отношению к фоновому заданию. А при "Вызове серверного метода" я буду кхм.. "внутри" фонового задания. Или чо?)

(16) типо так?
ФоновоеЗадание (BackgroundJob)
ПолучитьСообщенияПользователю (GetUserMessages)
Синтаксис:
ПолучитьСообщенияПользователю(<УдалятьПолученные>)
Параметры:
<УдалятьПолученные> (необязательный)
Тип: Булево.
Признак необходимости удаления полученных сообщений.
Истина - удалять.
Значение по умолчанию: Ложь.
Возвращаемое значение:
Тип: ФиксированныйМассив.
Описание:
Получает массив объектов СообщениеПользователю, которые были выведены в процессе работы фонового задания. Получение сообщений может выполняться как в процессе работы задания, так и по его завершении.

Добавил в свой серверный метод вызов БСП

ОбщегоНазначения.СообщитьПользователю("Мяу!");

"Вызов серверного метода" запускается из общей формы "Дополнительные отчеты и обработки", вставил туда вызов "ПолучитьСообщенияПользователю()"

&Вместо("ВыполнитьСерверныйМетодОбработкиЗавершение")

&НаКлиенте
Процедура Интеркампани_ВыполнитьСерверныйМетодОбработкиЗавершение(Задание, ДополнительныеПараметры) Экспорт
    
    Если Задание = Неопределено Тогда
        Возврат;
    КонецЕсли;
    
    Если Задание.Статус <> "Выполнено" Тогда
        Текст = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
            НСтр("ru = 'Команда ""%1"" не выполнена:'"),
            ВыполняемаяКоманда.Представление);
        Если Открыта() Тогда
            Закрыть();
        КонецЕсли;
        ВызватьИсключение Текст + Символы.ПС + Задание.КраткоеПредставлениеОшибки;
    КонецЕсли;
//============================добавил в расширении    
    СообщенияОбработки = СообщенияОбработкиНаСервере();
    Для Каждого Сообщ Из СообщенияОбработки Цикл
        Сообщить(Сообщ);
    КонецЦикла;    
//============================    
    
    
    // Показ всплывающего оповещения и закрытие этой формы.
    Если ВыполняемаяКоманда.ПоказыватьОповещение Тогда
        ПоказатьОповещениеПользователя(НСтр("ru = 'Команда выполнена'"),, ВыполняемаяКоманда.Представление);
    КонецЕсли;
    Если Открыта() Тогда
        Закрыть();
    КонецЕсли;
    
    // Обновление формы владельца.
    Если ЭтоФормаОбъекта Тогда
        Попытка
            ВладелецФормы.Прочитать();
        Исключение
            // Действие не требуется.
        КонецПопытки;
    КонецЕсли;
    
    // Оповещение других форм.
    РезультатВыполнения = ПолучитьИзВременногоХранилища(Задание.АдресРезультата);
    ОповеститьФормы = ОбщегоНазначенияКлиентСервер.СвойствоСтруктуры(РезультатВыполнения, "ОповеститьФормы");
    Если ОповеститьФормы <> Неопределено Тогда
        СтандартныеПодсистемыКлиент.ОповеститьФормыОбИзменении(ОповеститьФормы);
    КонецЕсли;
    
КонецПроцедуры
&НаСервере
Функция СообщенияОбработкиНаСервере()
    Возврат ПолучитьСообщенияПользователю();
    
КонецФункции    


Ничего не выводится.

Как минимум
не  Сообщить(Сообщ)
а Сообщ.Сообщить()

хотя вряд ли дело в этом

ну для фонового нужно вызывать
Фоновое.ПолучитьСообщенияПользователю()

(20) (21) Да, и то и другое.

Пришлось в форме "дополнителные отчеты и обработки" еще одну процедурку допилить:

&Вместо("ВыполнитьСерверныйМетодОбработки")
&НаКлиенте
Процедура Интеркампани_ВыполнитьСерверныйМетодОбработки()
    
    Задание = ЗапуститьФоновоеЗадание(ВыполняемаяКоманда, УникальныйИдентификатор);
    
    НастройкиОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
    НастройкиОжидания.ВыводитьОкноОжидания = Ложь;
//Добавил эту строчку===============
    НастройкиОжидания.ВыводитьСообщения = Истина;
//==================================        
    Обработчик = Новый ОписаниеОповещения("ВыполнитьСерверныйМетодОбработкиЗавершение", ЭтотОбъект);
    ДлительныеОперацииКлиент.ОжидатьЗавершение(Задание, Обработчик, НастройкиОжидания);
    
КонецПроцедуры

После этого в
&Вместо("ВыполнитьСерверныйМетодОбработкиЗавершение")
&НаКлиенте
Процедура Интеркампани_ВыполнитьСерверныйМетодОбработкиЗавершение(Задание, ДополнительныеПараметры) Экспорт
    
    Если Задание = Неопределено Тогда
        Возврат;
    КонецЕсли;
    
    Если Задание.Статус <> "Выполнено" Тогда
        Текст = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
            НСтр("ru = 'Команда ""%1"" не выполнена:'"),
            ВыполняемаяКоманда.Представление);
        Если Открыта() Тогда
            Закрыть();
        КонецЕсли;
        ВызватьИсключение Текст + Символы.ПС + Задание.КраткоеПредставлениеОшибки;
    КонецЕсли;

//================Появились сообщения в структуре "Задания" (видно в отладчике)
    СообщенияОбработки = Задание.Сообщения;
    Для Каждого Сообщ Из СообщенияОбработки Цикл
        Сообщить(Сообщ); // Ничего не сообщает.
//ПоказатьПредупреждение(,Сообщ.Текст); //Это работает
//ПоказатьОповещениеПользователя(НСтр("ru = 'Команда выполнена'"),, Сообщ.Текст);// И это работает , но перекрывается следующим оповещением.
    КонецЦикла;    
//============================    

    
    
    // Показ всплывающего оповещения и закрытие этой формы.

    Если ВыполняемаяКоманда.ПоказыватьОповещение Тогда
        ПоказатьОповещениеПользователя(НСтр("ru = 'Команда выполнена'"),, ВыполняемаяКоманда.Представление);
    КонецЕсли;
    Если Открыта() Тогда
        Закрыть();
    КонецЕсли;
    
    // Обновление формы владельца.

    Если ЭтоФормаОбъекта Тогда
        Попытка
            ВладелецФормы.Прочитать();
        Исключение
            // Действие не требуется.

        КонецПопытки;
    КонецЕсли;
    
    // Оповещение других форм.

    РезультатВыполнения = ПолучитьИзВременногоХранилища(Задание.АдресРезультата);
    ОповеститьФормы = ОбщегоНазначенияКлиентСервер.СвойствоСтруктуры(РезультатВыполнения, "ОповеститьФормы");
    Если ОповеститьФормы <> Неопределено Тогда
        СтандартныеПодсистемыКлиент.ОповеститьФормыОбИзменении(ОповеститьФормы);
    КонецЕсли;
    
КонецПроцедуры

Вот тут все сообщения выводятся как надо
https://infostart.ru/public/943888/

(23) Жлобмани не хватает скачать(

Всё получилось.

Если Задание.Сообщения.Количество()>0 Тогда
    Для Каждого Сообщ Из Задание.Сообщения Цикл
    Сообщ.ИдентификаторНазначения = ВладелецФормы.УникальныйИдентификатор;    //Владелец формы в данном случае - Форма списка документа "Реализация".
    Сообщ.Сообщить();
    КонецЦикла;    
КонецЕсли;

Не получилось.

Из нескольких сообщений иногда показывается только последнее.

(26) Собери все сообщения в один текст и один раз сообщи

(27) Свежее решение! )

В БСП есть общая форма "Длительная операция" для показа сообщений и индикации прогресса, которая выводит сообщения на общую форму "ДополнительныеОтчетыИОбработки", которая при завершении Вызова серверного метода тут же закрывается.

Процедура ВыполнитьСерверныйМетодОбработки()
    
    Задание = ЗапуститьФоновоеЗадание(ВыполняемаяКоманда, УникальныйИдентификатор);
    
    НастройкиОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
//    НастройкиОжидания.ВыводитьОкноОжидания = Ложь;
    НастройкиОжидания.ВыводитьОкноОжидания = Истина; // Будет показана общая форма "ДлительнаяОперация"

    НастройкиОжидания.ВыводитьСообщения = Истина;

    Обработчик = Новый ОписаниеОповещения("ВыполнитьСерверныйМетодОбработкиЗавершение", ЭтотОбъект);
    ДлительныеОперацииКлиент.ОжидатьЗавершение(Задание, Обработчик, НастройкиОжидания);
    
КонецПроцедуры