Доброго дня всем. Не совсем понимаю процесс подключения новых отчетов к уже созданным документам в БСП... все усложняют жизнь разрабам и проведение документов в общие модуля выносят...
В общем по привычке начал читать статьи и не нашел объяснения как это работает. Ведь где-то да прописываются отчеты которые должны отобразиться в доке.. Подскажите люди добрые - где?

(0) Читай на ИТС документацию по БСП. Там все разжевано, сюда передирать смысла не вижу.

(0) речь про внешний отчет?

(2)Да

(1) Понял, покопаюсь и там

Похоже внешние отчеты можно добавить только в дополнительные отчеты?

"отчеты которые должны отобразиться в доке" - Речь про отчеты или печатные формы документа?

(5) Это к вопросу - для чего дополнительные отчеты и обработки надо делать через расширения, а не через механизм внешних отчетов и обработок, который оставлен только для совместимости и по сути является морально устаревшим.

(5) а чем вас не устраивает вкладка дополнительных отчетов на панели отчетов в документе?

(8) разве что 1 лишний клик мышкой, зато разграничение типовых отчетов от дополнительных в документе

(9) Меня вообще все устраивает) Но руководитель поставил задачу и я пытаюсь ее реализовать, понымаиишь

(10) тогда используя расширение сделайте ему, как он хочет. Только предварительно обрисуйте, сколько это времени займет и что есть вариант, с типовым функционалом дополнительных отчетов в документе, который займет у вас пару минут.

(11) Через доп отчеты уже реализовано, в документ просят перенести)
а куда копать чтобы вывести отчет из конфигурации? В БСП же это через подключаемые команды все делается, но я не смог найти где прописывается в типовой базе что в документе допустим "продажа" нужно отобразить отчеты допустим "количество товаров" и "стоимость товаров".
Гле-то же в новой БСП хранится эта инфа.., раньше в модуле менеджера вроде как было, а сейчас не нашел

(12) так доп отчеты и находятся в документе! https://yadi.sk/i/g5qszlxV-XR8Iw

(13) а как ты туда их поместил? в доп отчетах есть возможность разместить только в подсистемах жи

(14) плохо смотрели вы возможности доп отчетов)
Функция СведенияОВнешнейОбработке() Экспорт
    НаименованиеОтчета="Бла бла бла";
    
    ПараметрыРегистрации = Новый Структура;
    МассивНазначений = Новый Массив();
    МассивНазначений.Добавить("Документ.Нужный документ");
    ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);
    ПараметрыРегистрации.Вставить("Вид", "Отчет");

    ПараметрыРегистрации.Вставить("Наименование", НаименованиеОтчета);
    ПараметрыРегистрации.Вставить("Версия", "1.0");
    ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
    ПараметрыРегистрации.Вставить("Информация", НаименованиеОтчета);
    ТаблицаКоманд = ПолучитьТаблицуКоманд();
    ДобавитьКоманду(ТаблицаКоманд,
    НаименованиеОтчета,
    "1",
    "ОткрытиеФормы",
    Ложь,"");
    ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
    Возврат ПараметрыРегистрации;
    
КонецФункции

(15) Понял принял, сейчас погуглю что надо дописать

(15) Функция СведенияОВнешнейОбработке() Экспорт
    
    ИмяОтчёта = "Запросы в снабжение в работе";
    ПараметрыРегистрации = Новый Структура;    
    МассивНазначений = Новый Массив();
    МассивНазначений.Добавить("ДокументСсылка.ЗапросНАБелеерду");
    ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);
    ПараметрыРегистрации.Вставить("Вид", "ДополнительныйОтчет");
    ПараметрыРегистрации.Вставить("Наименование", ИмяОтчёта);
    ПараметрыРегистрации.Вставить("Версия", "1.0"); //"1.0"
    ПараметрыРегистрации.Вставить("БезопасныйРежим", Ложь); //Варианты: Истина, Ложь
    ПараметрыРегистрации.Вставить("Информация", ИмяОтчёта);
    
    ТаблицаКоманд = ПолучитьТаблицуКоманд();
    
    ДобавитьКоманду(ТаблицаКоманд,
    ИмяОтчёта,
    ИмяОтчёта,
    "ОткрытиеФормы", //Использование. Варианты: "ОткрытиеФормы", "ВызовКлиентскогоМетода", "ВызовСерверногоМетода"
    Ложь,//Показывать оповещение. Варианты Истина, Ложь
    "");//Модификатор
    
    ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
    
    Возврат ПараметрыРегистрации;
    
КонецФункции



не сработало

(15) не сработало

(17) зачем вы написали МассивНазначений.Добавить("ДокументСсылка.ЗапросНАБелеерду");?
Я же вам написал как надо:  МассивНазначений.Добавить("Документ.Нужный документ");, например Документ.РеализацияТоваровУслуг

(17)     "ОткрытиеФормы",//Использование. Варианты: "ОткрытиеФормы", "ВызовКлиентскогоМетода", "ВызовСерверногоМетода"

    Ложь//Показывать оповещение. Варианты Истина, Ложь

    "")//Модификатор
Вы это как так комментарии воткнули в процедуру ДобавитьКоманду?)

держите уже:
Функция СведенияОВнешнейОбработке() Экспорт
    НаименованиеОтчета="Запросы в снабжение в работе";
    
    ПараметрыРегистрации = Новый Структура;
    МассивНазначений = Новый Массив();
    МассивНазначений.Добавить("Документ.ЗапросНАБелеерду"); //Если у вас реально так документ называется))
    ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);
    ПараметрыРегистрации.Вставить("Вид", "Отчет");

    ПараметрыРегистрации.Вставить("Наименование", НаименованиеОтчета);
    ПараметрыРегистрации.Вставить("Версия", "1.0");
    ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
    ПараметрыРегистрации.Вставить("Информация", НаименованиеОтчета);
    ТаблицаКоманд = ПолучитьТаблицуКоманд();
    ДобавитьКоманду(ТаблицаКоманд,
    НаименованиеОтчета,
    "1",
    "ОткрытиеФормы",
    Ложь,"");
    ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
    Возврат ПараметрыРегистрации;
    
КонецФункции


Функция ПолучитьТаблицуКоманд()
    Команды = Новый ТаблицаЗначений;
    Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
    Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
    Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
    Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
    Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
    Возврат Команды;
КонецФункции


Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
    НоваяКоманда = ТаблицаКоманд.Добавить();
    НоваяКоманда.Представление = Представление;
    НоваяКоманда.Идентификатор = Идентификатор;
    НоваяКоманда.Использование = Использование;
    НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
    НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры

Так же, если документ не типовой, то нужно будет скорее всего, как с печатными формами, добавить его в общем модуле в массив доступных для внешних обработок, или как то так

интересно почему не сделали доп отчеты в том же подменю, а не по кнопке

(23) а если их будет штук 20? Тогда будет большая портянка вперемешку с типовыми отчетами, которая не всем нужна. В отчетах в разделах можно опционально отключать, которые не нужны, причем это в разрезе пользователя настройка. Тут либо надо создать подобный функционал, либо просто все доп отчеты пихнуть в отдельную менюшку и забить.

(22) Документ не типовой, но я так понимаю для вывода печатных форма и отчетов нужны подключаемые процедуры и папки для расположения отчетов и печатных форм

(25) правильно понимаете, нужно объяснить БСП, что появился новый объект в виде документа, а формам документа - что нужно использовать возможности БСП)

(24) спасибо, замучил наверное уже)
у нас вид отличается.. там отчет должен быть??)
ПараметрыРегистрации.Вставить("Вид", "Отчет");

(27) Именно, если хотите, чтобы в документе отображался, а не в разделе Сервис- дополнительные отчеты

(28) Я понял, спасибо большое

(28) Большущее, а то обычно токсичные люди попадаются)
Приятно удивлен))

(30) вообще-то должна быть обработка, а не отчет. Чтобы в документ засовывать.

(31) с чего вы взяли? Нормально внешний отчет встраивается через справочник ДополнительныеОтчетыИОбработки, главное правильно СведенияОВнешнейОбработке заполнить

Можно и отчет и обработку

(32) Дошел до компа) все завелось, все отлично. С новым видом можно выбирать и документы.. Вот только есть несколько моментов, хотел уточнить.
Во-первых, автоматом документ который проставлен в настройках отчета в конфигураторе не появился в базе после заргузке. Но можно выбрать вручную - пойдет.
Во-вторых, после выбора документа во внешней обработке отчет отобразился, но чтобы его открыть нужно раскрыть вкладку отчеты, дальше нажать на дополнительные отчеты и появится то же самое окно как и в доп. отчетах, а потом уже выбрать свой отчет. То есть он как не родной сел)
Есть идеи почему так произошло?

(34) это фича такая

(35) то есть как родной никак не посадить? Печаль бедаа

(36) я об этом писал выше, что он будет в дополнительных отчетах. Один лишний клик получается

(37) Я тогда не понял о чем ты) Спасибо всем огромное

Ребят, новый вопрос. Выше мы обсуждали как встроить внешний отчет в документ. Теперь то же самое нужно проделать со встроенным отчетом (в конфе или в расширении без разницы). Думаю логично в конфе сделать (если есть что сказать по этому поводу буду благодарен). Подскажите как это сделать? Как вывести встроенный отчет в определенный документ (скорее всего через подключаемые команды)

(39) в модуль менеджера какого-нить типового документа с отчетами зайдите и поищите ДобавитьКомандыОтчетов

(40) Спасибо