v7: Класс ВыделениеЦветом на вин 2019

Смотрю на 10 (обробока из 5 себя также ведет. вроде все работает не на что не ругается, но цвет черный.
Я правильно думаю что достаточно в классе. 2 процедуры на формЕх переписать а не лазить по всей конфе или заблуждаюсь?
цвета там вроде везде жестко прописаны.
//=======================================================================================
Процедура УстановитьЦвет() Экспорт
    Перем лоОбъект;

    //извлечем текущий шаблон цветовой раскраски из реквизита-контейнера объекта
    Если ТипЗначенияСтр(моТЗ)="ТаблицаЗначений" Тогда
        лсШаблон = моТЗ.ПолучитьЗначение(моТЗ.ТекущаяСтрока(), мсКонтейнерЦвета);
    Иначе
        лсШаблон = мКонт.ПолучитьАтрибут(мсКонтейнерЦвета);
    КонецЕсли;
    //-
    Если ПустоеЗначение(лсШаблон)=1 Тогда
        //сформируем шаблон цветовой раскраски по системным цветам
        лсШаблон = "FONT["+_ЦветИзРеестра("WindowText")
        +"]BRUSH["+_ЦветИзРеестра("Window")
        +"]FONT_S["+_ЦветИзРеестра("WindowText")
        +"]BRUSH_S["+_ЦветИзРеестра("Window")+"]";//COUNT[NONE]INDENT[1]FONTSET[NONE]FONTSET_S[NONE]";
    КонецЕсли;
    //установим выбранный цвет в строке шаблона цветовой раскраски
    Если ВРег(ТекстФон)="ТЕКСТ" Тогда
        лсШаблон = "FONT["+эуЦвет.Объект.CurrColor
                    +"]BRUSH["+_ПолучитьЦветПоШаблону(лсШаблон, "BRUSH")
                    +"]FONT_S["+эуЦвет.Объект.CurrColor
                    +"BRUSH_S["+_ПолучитьЦветПоШаблону(лсШаблон, "BRUSH_S")
                    +"]";//COUNT[NONE]INDENT[1]FONTSET[NONE]FONTSET_S[NONE]";
    ИначеЕсли ВРег(ТекстФон)="ФОН" Тогда
        лсШаблон = "FONT["+_ПолучитьЦветПоШаблону(лсШаблон, "FONT")
                    +"]BRUSH["+эуЦвет.Объект.CurrColor
                    +"]FONT_S["+_ПолучитьЦветПоШаблону(лсШаблон, "FONT")
                    +"]BRUSH_S["+эуЦвет.Объект.CurrColor
                    +"]";//COUNT[NONE]INDENT[1]FONTSET[NONE]FONTSET_S[NONE]";
    КонецЕсли;
    //запишем выбранный цвет в атрибут класса
    ТекущийЦвет = эуЦвет.Объект.CurrColor;
    //-
    Если ТипЗначенияСтр(моТЗ)="ТаблицаЗначений" Тогда
        //выделение цветом проводится в ТЗ:
        //запишем шаблон в нужную колонку
        моТЗ.УстановитьЗначение(моТЗ.ТекущаяСтрока(), мсКонтейнерЦвета, лсШаблон);
        мКонт.Форма.Обновить();
        //передаем фокус таблице значений
        мКонт.Активизировать(моТЗ.ТекущаяКолонка());
    ИначеЕсли Лев(мсТипВызФормы, 8)= "Документ" Тогда
        //выделение цветом проводится в форме документа
        мКонт.УстановитьАтрибут(мсКонтейнерЦвета, лсШаблон);
        мКонт.Форма.Обновить();
        //передаем фокус многострочной части
        мКонт.Активизировать(мКонт.Форма.ТекущаяКолонка(), 0);
    Иначе
        Если Лев(мсТипВызФормы, 10) = "Справочник" Тогда
            //выделение цветом проводится в списке справочника
            Если ПустоеЗначение(САМ(Контекст).ПолучитьКонтекстОкружения().ТекущийЭлемент())=1 Тогда
                Предупреждение("Не выбран объект для выделения цветом в вызывающей форме! ");
                Возврат;
            КонецЕсли;
            //-
            лоОбъект = СоздатьОбъект("Справочник."+мКонт.ТекущийЭлемент().Вид());
            лоОбъект.НайтиЭлемент(мКонт.ТекущийЭлемент());
            Если лоОбъект.Блокировка(1)=0 Тогда
                Предупреждение("Элемент справочника заблокирован (открыт).
                |Установка цвета невозможна! ");
                Возврат;
            КонецЕсли;
        ИначеЕсли Лев(мсТипВызФормы, 6) = "Журнал" Тогда
            //выделение цветом проводится в журнале документов
            Если ПустоеЗначение(мКонт.ТекущийДокумент)=1 Тогда
                Предупреждение("Не выбран объект для выделения цветом в вызывающей форме! ");
                Возврат;
            КонецЕсли;
            //-
            лоОбъект = СоздатьОбъект("Документ."+мКонт.ТекущийДокумент.Вид());
            лоОбъект.НайтиДокумент(мКонт.ТекущийДокумент);
            Если лоОбъект.Блокировка(1)=0 Тогда
                Предупреждение("Документ заблокирован (открыт).
                |Установка цвета невозможна! ");
                Возврат;
            КонецЕсли;
        КонецЕсли;
        //подставляем макрокоманду цвета в текущий объект формы списка справочника
        //или журнала документов и попытаемся ее записать в объект
        лоОбъект.УстановитьАтрибут(мсКонтейнерЦвета, лсШаблон);
        Попытка
            лоОбъект.Записать();
        Исключение
            Предупреждение("Не удалось записать установку цвета! ");
        КонецПопытки;
        //передаем фокус многострочной части
        мКонт.Активизировать(мКонт.Форма.ТекущаяКолонка(), 0);
    КонецЕсли;
КонецПроцедуры
//=======================================================================================
Процедура Инициализация(псТекстФон, псТекстоваяМетка, псКонтейнер, пчПомнитьПоследнийЦвет, поТЗ) Экспорт
    Перем лсВерсия;

    //считываем параметры
    ТекстФон               = псТекстФон;
    мсКонтейнерЦвета       = псКонтейнер;
    мчПомнитьПоследнийЦвет = пчПомнитьПоследнийЦвет;
    моТЗ                   = поТЗ;
    //в зависимости от версии FormEx создаем на исходной форме ЭУ для раскраски строк
    лоСервис = СоздатьОбъект("Сервис");
    лоСервис.ВерсияFormEx(лсВерсия);
    Если лсВерсия >= "2.0.5" Тогда
        //версии FormEx и 1С++ раздельные
        эуЦвет  = СоздатьОбъект("АктивИкс");
        лоФорма = СоздатьОбъект("Форма");
        лоФорма.СоздатьЭлементУправленияНаФорме(мКонт.Форма, эуЦвет, псТекстоваяМетка);
    Иначе
        эуЦвет   = СоздатьОбъект("АктивИкс");
        АтрФормы = СоздатьОбъект("АтрибутФормы");
        АтрФормы.УстановитьАтрибут(мКонт.Форма, псТекстоваяМетка);
        АтрФормы.СоздатьЭлементУправления(эуЦвет); // СоздатьЭУ
    КонецЕсли;
    эуЦвет.СоздатьЭУ("VCOLORPICKER.VColorPickerCtrl.1");
    //предустановим значения некоторых атрибутов класса и ЭУ
    САМ(Контекст).ЗаголовокКнопки         = ТекстФон;
    САМ(Контекст).ЗаголовокАвтоЦвета      = "Системный";
    САМ(Контекст).ЗаголовокТекущегоЦвета  = "Выбрать цвет...";
    САМ(Контекст).ЦветТекстаКнопки        = _ЦветИзРеестра("WindowText");
    САМ(Контекст).ЦветФонаКнопки          = _ЦветИзРеестра("Menu");
    САМ(Контекст).АвтоЦвет                = _ПредустановкаЦвета("Авто");
    САМ(Контекст).ТекущийЦвет             = _ПредустановкаЦвета("Текущий");
    //скопируем значения оставшихся атрибутов ЭУ в атрибуты класса
    ВыравниваниеПоГоризонтали = эуЦвет.Объект.HorzAlign;
    ВыравниваниеПоВертикали   = эуЦвет.Объект.VertAlign;
    МногострочныйЗаголовок    = эуЦвет.Объект.Multiline;
    НевидимаяКнопка           = эуЦвет.Объект.HyperLook;
    ПлоскаяКнопка             = эуЦвет.Объект.TrackLook;
    ДоступностьКнопки         = эуЦвет.Объект.Enabled;
    ПлавающееОкноВыбораЦвета  = эуЦвет.Объект.FloatingPopup;
КонецПроцедуры

//=======================================================================================