Задачка: сгенерировать семь РАЗЛИЧНЫХ случайных чисел в диапазоне от 1 до 50.
Если использовать стандартный ГенераторСлучайныхЧисел() в цикле, то как проще и эффективнее проверять уникальность полученных чисел?

(0) Например, добавлять их в массив.

Хранишь массив сгенерированных чисел, пока он не станет равен 7 генерируешь числа и добавляешь в массив если уникальные.

(0) Не надо в цикле ГенераторСлучайныхЧисел использовать, он должен быть перед циклом. В цикле только ГенераторСлучайныхЧисел.СлучайноеЧисло.
Иначе выдаст 7 одинаковых чисел.

(3) это понятно.
самый простой код такой

ГСЧ = Новый ГенераторСлучайныхЧисел();
Для Счетчик = 1 По 7 Цикл
    Рэндом = ГСЧ.СлучайноеЧисло(1, 50);
    Сообщить(Рэндом);
КонецЦикла;    

в этом случае выборка может быть не уникальна, итерации то независимы и числа могут повторяться

(2) вот чёт не соображу как в массиве это организовать

(5) Как создать массив не знаете, или как добавить в него число, или как проверить, а есть ли такое значение в массиве? Что именно сообразить не можете? Или вы не знаете как цикл организовать? Ведь помимо цикла Для, Для каждого, есть еще и Пока...

Пока Массив..Количество() < 7
Если НайтиВМассиве тогда продолжить
...

ГСЧ = Новый ГенераторСлучайныхЧисел();
СемьСлучайных = Новый Соответствие;
    
Пока СемьСлучайных.Количество() < 7 Цикл
    Рэндом = ГСЧ.СлучайноеЧисло(1, 50);
    СемьСлучайных.Вставить(ЧислоПрописью(Рэндом),Рэндом);
КонецЦикла;    
    
Для Каждого КлючЗнач из СемьСлучайных Цикл
    Сообщить(КлючЗнач.Значение);
КонецЦикла;

Создаете массив на 50 элементов, заполненный числами от 1 до 50
На каждой итерации:
1. Получаете случайное число от 0 до верхнего индекса массива. Находим элемент с этим индексом
2. Добавляете этот элемент в результат
3. Удаляете элемент с этим индексом

За 14 лет стажа в 1с подобные задачки, имхо, в уме должны решаться

(8) Забыл проверить на уникальность.

Сувай числа в ключ соответствия. Дергай ГСЧ пока в соответствии не будет 7 элементов. При инициализации пихай в ГСЧ число, полученное из ТекущаяУниверсальнаяДатаВМиллисекундах(). Так последовательность чисел будет всегда разная

(12) инициализация без параметра от тек даты выполняется

+к(8) ЧислоПрописью можно выкинуть. соотв мягче чем структура относится к ключам
(11) не забыл. их просто не станет больше, когда будет добавлен повторный ключ.

(11) а лишняя проверка - отъем ресурсов.

(14) Хм, да. Ступил :)

(8) (9) (12) Зачем соответствие то? Для чего 2 цикла, когда можно одним управиться? Байтите блин...

    МассивУникальныхЧисел=Новый Массив;
    ГСЧ = Новый ГенераторСлучайныхЧисел();
    Пока МассивУникальныхЧисел.Количество()<7 Цикл
        СлучайноеЧисло = ГСЧ.СлучайноеЧисло(1, 50);
        Если МассивУникальныхЧисел.Найти(СлучайноеЧисло)=Неопределено Тогда
            МассивУникальныхЧисел.Добавить(СлучайноеЧисло);
            Сообщить(СлучайноеЧисло);
        КонецЕсли;
    КонецЦикла;

(17) что бы кто-нибудь (8) скопировал в продакшен...

(17) Зачем соответствие то? - поиск и вставка в одно движение. быстрее, легче, меньше кода.
второй цикл - можно и без второго, живите теперь с соответствием.

(19) ЧислоПрописью то зачем?

(20) можно выкинуть. отписал в (14)

соот.Вставить(Число, Истина) - все.

(13) раньше такого не было. Без начального числа последовательность СЧ всегда одинаковой получалась

(10) дык яж админю, 1С так постольку поскольку.
(17) спасибо, изящно и понятно

всем спасибо, всё свободны)

(17) соответствие лучше заточено для многократного поиска

(25) да я понял уже эту идею, только в контексте данной задачи это имхо излишне.

(24) когда количество ключей дорастёт до сотен, а заходы до тысяч, изящное Массив.Найти - превратиться в черную дыру для процессорного времени.

(27) маловероятно, очень узкая конкретная задача, выбрать из списка семь неудачников для холодного обзвона. Кол-во строк в списке не превышает 50

(24) (17) где там изящность-то увидел? как раз чтобы не искать в массиве соответствие и используют

(29) изящно в том смысле, что всё в одном цикле, для моей конкретной задачи этого более чем достаточно

+ 1.

(8) лучше чем (17)

уговорили) через соответствие, так через соответствие. Глядишь, если кто нить из спецов увидит эту поделку, то не будет сильно ругаться на "говнокод"

(32) в любом случае говнокод, попробуй этим же алгоритмом выбрать 45 из 50, или 190 из 200

п-сссст. через ком цепляем vbs и через rnd получаем число, чуть допиливаем напильником до целого и вуаля)

(33) Можно попробовать бить на отрезки, тогда числа повторяться числа не будут и 45 из 50 норм отработает

(33) такие крайние случаи надо обрабатывать перед и инвертировать смысл генерации. 45 из 50 - надо убрать 5 разных. 190 из 200 - убрать 10 разных.

Если речь об холодном обзвоне, то можно попробовать разбить на равные доли предложить такой вариант. В данном случае будут 7/14/21/28../49 - 7 уникальных чисел.

а самих клиентов для обзвона отсортировать по дате например. Тогда и старички и новые в равной степени попадут в обзвон. Рандомайз этого гарантировать не может

Спамеры.

Выборка с изъятием:

маИсх = новый Массив;
Для ном = 1 по 50 Цикл
    маИсх.Добавить(ном);
КонецЦикла;

ГСЧ = Новый ГенераторСлучайныхЧисел();
маРез = новый Массив;
Для ном = 1 по 7 Цикл
    индекс = ГСЧ.СлучайноеЧисло(0, маИсх.Количество()-1);
    маРез.Добавить(маИсх.Получить(индекс));
    маИсх.Удалить(индекс);
конецЦикла;

Для каждого рез из маРез Цикл
    сообщить(рез);
КонецЦикла;

Спамеры.

(38) это выборка за день
(39) да, есть такое. Но, с другой стороны, если раньше всем клиентом, кто прошел регистрацию, рассылали СМС, то теперь решили обзванивать семь случайных за день.