Добрый день, добавляю программно доп реквизит, но он почему-то не используется в предприятии, пока его не перезаписать.. что я упустил?

    Если ЭлементПВХ_Ссылка = Неопределено ИЛИ ЭлементПВХ_Ссылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.ПустаяСсылка() Тогда
        ЭлементПВХ_Нов = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.СоздатьЭлемент();
        ЭлементПВХ_Нов.Заголовок = ИмяРеквизита;
        ЭлементПВХ_Нов.Имя = ИмяРеквизита;
        ЭлементПВХ_Нов.НаборСвойств = НаборСвойствРеквизита;     
        ЭлементПВХ_Нов.Наименование = ЭлементПВХ_Нов.Заголовок+" ("+ЭлементПВХ_Нов.НаборСвойств+")";
        ЭлементПВХ_Нов.ТипЗначения = Новый ОписаниеТипов("Строка",,,,Новый КвалификаторыСтроки(ДлинаСтроки)); // ?        
        Попытка
            ЭлементПВХ_Нов.Записать();
            ЭлементПВХ_Ссылка = ЭлементПВХ_Нов.Ссылка;
        Исключение
            Сообщить("Не удалось создать свойство " + ИмяРеквизита);
        КонецПопытки;    
    КонецЕсли;

Наверное так понятнее будет:

Функция ПолучитьСвойство(ИмяРеквизита, НаборСвойствРеквизита, ДлинаСтроки=0)
    
    ЭлементПВХ_Ссылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Заголовок", ИмяРеквизита);    
    Если ЭлементПВХ_Ссылка = Неопределено ИЛИ ЭлементПВХ_Ссылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.ПустаяСсылка() Тогда
        ЭлементПВХ_Нов = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.СоздатьЭлемент();
        ЭлементПВХ_Нов.Заголовок = ИмяРеквизита;
        ЭлементПВХ_Нов.Имя = ИмяРеквизита;
        ЭлементПВХ_Нов.НаборСвойств = НаборСвойствРеквизита;     
        ЭлементПВХ_Нов.Наименование = ЭлементПВХ_Нов.Заголовок+" ("+ЭлементПВХ_Нов.НаборСвойств+")";
        ЭлементПВХ_Нов.ТипЗначения = Новый ОписаниеТипов("Строка",,,,Новый КвалификаторыСтроки(ДлинаСтроки)); // ?        
        Попытка
            ЭлементПВХ_Нов.Записать();
            ЭлементПВХ_Ссылка = ЭлементПВХ_Нов.Ссылка;
        Исключение
            Сообщить("Не удалось создать свойство " + ИмяРеквизита);
        КонецПопытки;    
    КонецЕсли;

    Возврат ЭлементПВХ_Ссылка;
КонецФункции

(1) Нет, не будет.
Попробуйте использовать простой шаблон для задавания вопросов
1. Что вы делаете
2. Что ожидаете получить
3. Что получаете

(2)
1. Проверяю наличие доп. реквизита по имени, если его нет, то программно создаю
2. Ожидаю, либо найти доп. реквизит, либо создать
3. Если реквизит есть, возвращаю его из функции, если реквизита нет, записываю его, но в предприятии я его не вижу в справочнике, он будто не активен, но если зайти в пвх функции тех. специалиста, то он там есть, и если нажать в нем команду записать, то он появляется в справочнике. Он будто не используется до момента "проведения".

(3) Создайте элемент ПВХ с помощью вашей функции и посмотрите какие поля в нем не заполнены по сравнению с другими элементами ПВХ

(4) Сравнивал, все идентично

(5) В конфигураторе ищите по ссылкам где используется ПВХ и сравнивайте там

(6) Да я по ходу решил сделать по другому, в отладчике в момент отработки строки ЭлементПВХ_Нов.Записать(); проверил какие реквизиты еще доступные для изменения, нашел реквизит типа булево: ЭлементПВХ_Нов.Доступен, сейчас его проверю

(7) Так вы неправильным инструментом пользуетесь. Для сравнения надо брать такой, который показывает все реквизиты, а не тот, что разработчики вам дают

(8) В "рабочем" свойстве пвх реквизит доступен также "ложь", брр
Я пользуюсь возможностями конфигуратора, а что еще есть?

Есть же общий модуль УправлениеСвойствами который сделает всю эту работу за вас, зачем городить своё?

(10) Затем, что иногда "что-то идет не так"

(9) Ищи по ссылкам. Наверняка в какой-нибудь регистр сведений запихнули

Решил. Его еще нужно в наборе записать...

Функция ПолучитьСвойство(ИмяРеквизита, НаборСвойств_Ссылка, ДлинаСтроки=0)
    
    ЭлементПВХ_Ссылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Заголовок", ИмяРеквизита);    
    Если ЭлементПВХ_Ссылка = Неопределено ИЛИ ЭлементПВХ_Ссылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.ПустаяСсылка() Тогда
        ЭлементПВХ_Нов = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.СоздатьЭлемент();
        ЭлементПВХ_Нов.Заголовок = ИмяРеквизита;
        ЭлементПВХ_Нов.Имя = ИмяРеквизита;
        ЭлементПВХ_Нов.НаборСвойств = НаборСвойств_Ссылка;     
        ЭлементПВХ_Нов.Наименование = ЭлементПВХ_Нов.Заголовок+" ("+ЭлементПВХ_Нов.НаборСвойств+")";    
        ЭлементПВХ_Нов.ТипЗначения = Новый ОписаниеТипов("Строка",,,,Новый КвалификаторыСтроки(ДлинаСтроки));
                
        Попытка
            ЭлементПВХ_Нов.Записать();
            ЭлементПВХ_Ссылка = ЭлементПВХ_Нов.Ссылка;
        Исключение
            Сообщить("Не удалось создать свойство " + ИмяРеквизита);
        КонецПопытки;    
    КонецЕсли;    
    
        // Добавим наш реквизит в набор дополнительных реквизитов справочника.
        НаборСвойств_Объект = НаборСвойств_Ссылка.ПолучитьОбъект();        
        Если НаборСвойств_Объект.ДополнительныеРеквизиты.Найти(ЭлементПВХ_Ссылка, "Свойство") = Неопределено Тогда
            
            ЭлементНС_Нов = НаборСвойств_Объект.ДополнительныеРеквизиты.Добавить();
            ЭлементНС_Нов.Свойство = ЭлементПВХ_Ссылка;
            НаборСвойств_Объект.Записать();
        КонецЕсли;
            
    Возврат ЭлементПВХ_Ссылка;
КонецФункции

(14) Я бы использовал в первой строке
ЭлементПВХ_Ссылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Имя", ИмяРеквизита);

(15) не всегда пойдет. в типовых же, если интерактивно создаешь элемент пвх имя генерируется с идентификатором
можно использовать, наверное:
1. заведомо поменять имя
2. знать имя заранее (с идентификатором)

http://prntscr.com/u4rXIhzt6Nad

(0)Что значит "не используется в предприятии"?

(15) Разве эти функции отличатся по скорости отработки?

(19) Дело не в скорости, а уникальности дополнительного реквизита. Не просто так этот реквизит придуман. Но..дело вкуса.

(20) Понял, согласен

(15) если не программно создавать, а ручками, то имя пустое будет. ( по крайней мере, в рознице 2.2.5.23, так )