Добрый!

Как сделать код "ЕслиЕстьРеквизит" без попытки?:

Попытка
   ЧтотоТамСделать(ЧтотоТут.КонтактноеЛицо); // Если есть реквизит КонтактноеЛицо
Исключение
   ЧтотоТамСделатьЕслиЕстьРеквизит(ЧтотоТут); // Если нет реквизита КонтактноеЛицо
КонецПопытки;

Спасибо!

(0) через Метаданные

https://helpf.pro/faq83/view/1698

Сложна! Попроще бы

В БСП есть метод.
Ну или такое - по мотивам:


Функция ЕстьРеквизитОбъекта(Переменная, Знач ИмяРеквизита) Экспорт
    Перем проверка, контроль;
    контроль = Новый УникальныйИдентификатор;
    Попытка
        проверка = Новый Структура(ИмяРеквизита, контроль);
    Исключение
        // в имя реквизита передали какую-то дичь
        Возврат Ложь;
    КонецПопытки;
    Если проверка.Количество() > 1 Тогда
        // в имя реквизита передали строку со списком. такое не проверяем
        Возврат Ложь;
    КонецЕсли;
    ЗаполнитьЗначенияСвойств(проверка, Переменная);
    
    Возврат проверка[ИмяРеквизита] <> контроль;
КонецФункции

Точно! Прям так и называется же! Спасибо!!

(5) А там всего 1 строчка) НЕ (МетаданныеОбъекта.Реквизиты.Найти(ИмяРеквизита) = Неопределено)

Блин, да... Стандартные реквизиты не смотрит тоже

УИ = Новый УникальныйИдентификатор();
СтруктураДляПроверки = Новый структура("ИмяРеквизита", УИ);
ЗаполнитьЗначенияСвойств(СтруктураДляПроверки, ПроверяемыйОбъект);
ЕстьРеквизит = СтруктураДляПроверки.ИмяРеквизита <> УИ;

(7) Ну так свою напиши.

(8) кстати, хороший лайфхак.

(8) (10) Я бы рассматривал метод Свойство()

(10) да я уже после увидел, что в (4) он же, но с обработкой мусора на входе

(11) ну и где у "СправочникОбъект" этот метод?

(13) а где сказано в (0), что речь про СправочникОбъект?)
Для ДанныеФормыСтруктура вполне себе работает.

(14) а где в (0) про ДанныеФормыСтруктура?

(8) Только если Реквизит не с типом УникальныйИдентификатор вдруг)
Спасибо!!

(15) Разница лишь в том, что я не утверждаю, что метод не рабочий. Из задачи, не понятно, где и как будет это использоваться, поэтому (11) имеет место быть.
(16) Новый УникальныйИдентификатор()<>Новый УникальныйИдентификатор(). Так, что не переживайте)

(17) До кучи - это же будет получение всех реквизитов объекта... Вот где собака порылась!

(18) А в ЗаполнитьЗначенияСвойств думаете не будет получения всех реквизитов объекта?

(19) Я об этом и написал жэ...

(18) В общем, если работаете с формой и хотите проверить есть или нет у объекта реквизит, то можете воспользоваться методом Свойство(), без контекста формы, можете использовать метод БСП с метаданными, или же (8) как вариант.

(20) значит я вас не так понял.

(18) от справочникОбъект - не будет (уже и так есть). От СправочникСсылка - будет, причем при попытке и получении через точку - тоже будет.

Да, только через Метаданные, похоже, вариант. Если не Форма, где Свойство, возможно, спасает

(21) но реквизит формы можно создать программно, это не значит что у объекта есть этот реквизит

В общем, написал такое, не очень-то проверял, правда..

Функция ЕстьРеквизит(ПроверяемыйОбъект, ИмяРеквизита, РазделМетаданных= "Реквизиты") Экспорт
    Возврат НЕ ПроверяемыйОбъект.Метаданные()[РазделМетаданных].Найти(ИмяРеквизита) = Неопределено;
КонецФункции

Действительно - одна строка)
Реквизиты, ТабличныеЧасти, а вот со СтандартныеРеквизиты не работает..

(26) добавь в свою функцию

ОбщегоНазначения.ЭтоСтандартныйРеквизит(ПроверяемыйОбъект.Метаданные().СтандартныеРеквизиты, ИмяРеквизита)

Функция общего модуля ЕРП (из БСП видимо):

// Возвращает признак того, что реквизит входит в подмножество стандартных реквизитов.
//
// Параметры:
//  СтандартныеРеквизиты - ОписанияСтандартныхРеквизитов - тип и значение, описывающие коллекцию настроек различных
//                                                         стандартных реквизитов;
//  ИмяРеквизита         - Строка - реквизит, который необходимо проверить на принадлежность множеству стандартных
//                                  реквизитов.
//
// Возвращаемое значение:
//   Булево - Истина, если реквизит входит в подмножество стандартных реквизитов.
//
Функция ЭтоСтандартныйРеквизит(СтандартныеРеквизиты, ИмяРеквизита) Экспорт
    
    Для Каждого Реквизит Из СтандартныеРеквизиты Цикл
        Если Реквизит.Имя = ИмяРеквизита Тогда
            Возврат Истина;
        КонецЕсли;
    КонецЦикла;
    Возврат Ложь;
    
КонецФункции

Способ через ЗаполнитьЗначенияСвойств() довольно долгий. В частом коде его применять не выгодно. Намного быстрее обычная Попытка.

(28) в общем случае "довольно долгий" или даже на структуре, состоящей всего из одного поля?

(29) Да, грубо раз в 10 дольше чем попытка.

Я про (8)

код в (8) есть в типовой функции УТ. так что свою можно не писать.

(30) вроде бы вопрос альтернативный...