Как соединить две таблицы запросом по полям Статья Контрагент таким образом чтобы нужные контрагенты встали на свои места, а те которые не вошли сгруппировались в Прочие контрагенты. Пример с двумя исходными таблицами и нужным результатом здесь: https://telegra.ph/kak-soedinit-tablicy-06-15

возможно Вам надо ОБЪЕДИНИТЬ ВСЕ

примерно так получилось:

ВЫБРАТЬ
    План.Статья КАК Статья,
    План.Контрагент КАК Контрагент,
    План.СуммаПлан КАК СуммаПлан,
    Факт.Статья КАК СтатьяФакт,
    Факт.Контрагент КАК КонтрагентФакт,
    Факт.СуммаФакт КАК СуммаФакт
ПОМЕСТИТЬ Найденные
ИЗ
    РегистрСведений.План КАК План
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.Факт КАК Факт
        ПО (План.Статья = Факт.Статья)
            И (План.Контрагент = Факт.Контрагент)
ГДЕ
    НЕ Факт.СуммаФакт ЕСТЬ NULL
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Факт.Статья КАК Статья,
    Факт.Контрагент КАК Контрагент,
    Факт.СуммаФакт КАК СуммаФакт,
    Найденные.СтатьяФакт КАК СтатьяФакт,
    Найденные.КонтрагентФакт КАК КонтрагентФакт,
    Найденные.СуммаФакт КАК Сумма
ПОМЕСТИТЬ НайденныеФакт
ИЗ
    РегистрСведений.Факт КАК Факт
        ЛЕВОЕ СОЕДИНЕНИЕ Найденные КАК Найденные
        ПО Факт.Статья = Найденные.СтатьяФакт
            И Факт.Контрагент = Найденные.КонтрагентФакт
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СУММА(НайденныеФакт.СуммаФакт) КАК Сумма
ПОМЕСТИТЬ СуммаФактПрочие
ИЗ
    НайденныеФакт КАК НайденныеФакт
ГДЕ
    НайденныеФакт.Сумма ЕСТЬ NULL
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Статьи.Ссылка КАК Статья,
    Контрагенты.Ссылка КАК Контрагент,
    СуммаФактПрочие.Сумма КАК СуммаФакт
ПОМЕСТИТЬ ПрочиеКонтрагенты
ИЗ
    Справочник.Статьи КАК Статьи,
    Справочник.Контрагенты КАК Контрагенты,
    СуммаФактПрочие КАК СуммаФактПрочие
ГДЕ
    Статьи.Наименование = "Аренда"
    И Контрагенты.Наименование = "Прочие контрагенты"
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Найденные.Статья КАК Статья,
    Найденные.Контрагент КАК Контрагент,
    Найденные.СуммаПлан КАК СуммаПлан,
    Найденные.СуммаФакт КАК СуммаФакт
ИЗ
    Найденные КАК Найденные

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    ПрочиеКонтрагенты.Статья,
    ПрочиеКонтрагенты.Контрагент,
    NULL,
    ПрочиеКонтрагенты.СуммаФакт
ИЗ
    ПрочиеКонтрагенты КАК ПрочиеКонтрагенты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    План.Статья КАК Статья,
    План.Контрагент КАК Контрагент,
    План.СуммаПлан КАК СуммаПлан,
    ЕСТЬNULL(Факт.СуммаФакт, 0) КАК СуммаФакт
ПОМЕСТИТЬ Предварительная
ИЗ
    РегистрСведений.План КАК План
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.Факт КАК Факт
        ПО План.Статья = Факт.Статья
            И План.Контрагент = Факт.Контрагент

ОБЪЕДИНИТЬ

ВЫБРАТЬ
    ПрочиеКонтрагенты.Статья,
    ПрочиеКонтрагенты.Контрагент,
    0,
    ПрочиеКонтрагенты.СуммаФакт
ИЗ
    ПрочиеКонтрагенты КАК ПрочиеКонтрагенты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Предварительная.Статья КАК Статья,
    Предварительная.Контрагент КАК Контрагент,
    СУММА(Предварительная.СуммаПлан) КАК СуммаПлан,
    СУММА(Предварительная.СуммаФакт) КАК СуммаФакт
ИЗ
    Предварительная КАК Предварительная

СГРУППИРОВАТЬ ПО
    Предварительная.Статья,
    Предварительная.Контрагент

https://telegra.ph/itog-06-15

Можно через полное соединение сделать без временных таблиц

(5) Что дальше?
https://telegra.ph/chto-dalshe-06-15

(6)
ЕСТЬNULL(План.Контрагент,&ПрочийКонтрагент) КАК Контрагент,
ЕСТЬNULL(План.Статья,Факт.Статья) КАК Статья,

(6) естьnull(факт.контрагент, &ПрочийКонтрагент) как контрагент

(7) только не из плана, там и так прочий

(9) как раз из плана

(10) да, я перепутал

получилось, спасибо вам большое

ВЫБРАТЬ
    ЕСТЬNULL(План.Статья, Факт.Статья) КАК Статья,
    ЕСТЬNULL(План.Контрагент, &ПрочийКонтрагент) КАК Контрагент,
    СУММА(План.СуммаПлан) КАК СуммаПлан,
    СУММА(Факт.СуммаФакт) КАК СуммаФакт
ПОМЕСТИТЬ ПолноеОбъединение
ИЗ
    РегистрСведений.План КАК План
        ПОЛНОЕ СОЕДИНЕНИЕ РегистрСведений.Факт КАК Факт
        ПО (План.Статья = Факт.Статья)
            И (План.Контрагент = Факт.Контрагент)

СГРУППИРОВАТЬ ПО
    ЕСТЬNULL(План.Статья, Факт.Статья),
    ЕСТЬNULL(План.Контрагент, &ПрочийКонтрагент)

https://telegra.ph/itog-06-15-2

Редкий случай, когда полное пригодилось

Проблема:
Как соединить таблицы "План" и "Факт" с полями Контрагент, Статья таким образом, чтобы план сопоставился с фактом, а не найденные сгруппировались в "Прочие контрагенты".

Решение:
Используйте ПОЛНОЕ ВНЕШНЕЕ СОЕДИНЕНИЕ и функцию ЕСТЬNULL()
Пример запроса в (13)

(16) отличный робот!