Добрый день!

Комплексная автоматизация 2.5.14.74 (платформа 8.3.23.1912):
есть типовой документ Реализация товаров и услуг, нужно с помощью Расширения конфигурации добавить движение по регистру бухгалтерии (основной конфигурации):
90.04/68.03
Добавила новый общий модуль в расширение

&После("ОбработкаПроведения")
Процедура МояОбработкаПроведения(Отказ, РежимПроведения)

написала текст:

НаборЗаписей = РегистрыБухгалтерии.Хозрасчетный.СоздатьНаборЗаписей();
        НаборЗаписей.Отбор.Регистратор.Установить(Ссылка);
        НаборЗаписей.Прочитать();
        
        Для Каждого Стр Из Товары Цикл
            
    
            
            
            Движение = НаборЗаписей.Добавить();
            
                        
            Движение.Регистратор = Ссылка;
            Движение.Активность = Истина;
            Движение.Период = Дата;
            
                      
            Движение.СчетДт = ПланыСчетов.Хозрасчетный.НайтиПоКоду("90.04");
            Движение.СчетКт = ПланыСчетов.Хозрасчетный.НайтиПоКоду("68.03");

            
            Движение.Организация = Организация;
            Движение.СубконтоДт[ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы] = Стр.Номенклатура.ГруппаФинансовогоУчета;
            Движение.СубконтоКт[ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ВидыПлатежейВГосБюджет] = Перечисления.ВидыПлатежейВГосБюджет.Налог;
            
            Движение.Сумма = Сумма;  
КонецЦикла;

НаборЗаписей.Записывать = Истина;


через "Сообщить" - все заполяется, все верно, но после Отражения в регл учете движений по регистру бухгалтерии нет...

Что-то нужно еще настроить?

изменила:

НаборЗаписей.Записать(Ложь);

вместо

НаборЗаписей.Записывать = Истина;

проводки появились, но они до Отражения в регл учете, а после Отражения в регл учете - моя проводка исчезает. как быть? как сделать, чтобы моя проводка добавлялась при  Отражении документа в регл учете?

(0) нужно переместить код в модуль РегистрыБухгалтерии.Хозрасчетный и окаймить проверкой регистратора

нашла еще обработка Отражение в регл учете. Может здесь? Надо разбираться
(2) вы дорабатывали так?

(3) 30% в модуле регистра, 70%  в менеджере документа

Все это не надо. Смотрите и расширяйте РеализацияТоваровУслугЛокализация.ТекстОтраженияВРеглУчете()
Там нужно "расширить" соответствующий запрос. Все остальное за вас сделают штатные механизмы.

(5) да. смотрю как раз уже этот модуль. мне как-то форма запроса не совсем подходит. попробую

Общий механизм такой: При отражении в рег. выполняется запрос возвращаемый этой функцией. Результат выполнения этого запроса таблица, которая содержит в себе все данные для проводок. Потом просто записываются проводки в регистр "Хозрасчетный". И такие функции есть у всех документов которые должны отражаться в рег. учете.
В модуле менеджера документа это выглядит как:
// Функция возвращает текст запроса для отражения документа в регламентированном учете.
//
// Возвращаемое значение:
//    Строка - Текст запроса
//
Функция ТекстОтраженияВРеглУчете() Экспорт

    Возврат РеализацияТоваровУслугЛокализация.ТекстОтраженияВРеглУчете();

КонецФункции

(7) да, видела. думаю, как свою обработку проведения под их текст запроса (структуру) сделать... там получается нужно соблюсти такую же структуру, но мне надо еще из регистра сведений взять свои данные...

В общем модуле "РеализацияТоваровУслугЛокализация" :

Функция ТекстОтраженияВРеглУчете() Экспорт
    
    Результат = "";
    //++ Локализация
    
    ТекстыОтражения = Новый Массив;
    ТекстыОтражения.Добавить(ТекстПередачаНаКомиссию());
    ТекстыОтражения.Добавить(ТекстПередачаНаСубкомиссию());
    ТекстыОтражения.Добавить(ТекстРеализацияБезПереходаПраваСобственности());
    ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииКомиссионногоТовара());
    ТекстыОтражения.Добавить(ТекстПродажаКомиссионногоТовара());
    ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииСобственногоТовара());
    ТекстыОтражения.Добавить(ТекстВыручкаОтРеализацииРаботУслуг());
    ТекстыОтражения.Добавить(ТекстСебестоимостьОтгруженногоТовара());
    ТекстыОтражения.Добавить(ТекстСебестоимостьРеализованногоТовара());
    ТекстыОтражения.Добавить(ТекстСебестоимостьРеализованныхРабот());
    ТекстыОтражения.Добавить(ТекстНДССРеализации());
    ТекстыОтражения.Добавить(ТекстНДССРеализацииРаботыУслуги());
    ТекстыОтражения.Добавить(ТекстНДССОтгрузкиБезПереходаПраваСобственности());
    ТекстыОтражения.Добавить(ТекстНДССРеализацииПриПереходеПраваСобственности());
    ТекстыОтражения.Добавить(ТекстНДССОтгрузкиБезПереходаПраваСобственностиРаботыУслуги());
    ТекстыОтражения.Добавить(ТекстНДССРеализацииПриПереходеПраваСобственностиРаботыУслуги());
    ТекстыОтражения.Добавить(ТекстНулеваяСтавкаНДСОтклонена());
    ТекстыОтражения.Добавить(ТекстЗалоговаяСтоимостьПереданнойТары());
    ТекстыОтражения.Добавить(ТекстВключениеИсключениеНДСВСтоимость());
    ТекстыОтражения.Добавить(ТекстОтклонениеВСтоимостиРасходы());
    ТекстыОтражения.Добавить(ТекстОтклонениеВСтоимостиДоходы());
    ТекстыОтражения.Добавить(ТекстПродажаАгентскихУслуг());

///
ТекстыОтражения.Добавить(МойТекст());
///
    
    Результат = СтрСоединить(ТекстыОтражения, ОбщегоНазначенияУТ.РазделительЗапросовВОбъединении());
    
    //-- Локализация
    Возврат Результат
    
КонецФункции

а нельзя не в виде запросов сделать?

(10) можно, см (2)

(4) не могу понять куда там запихать свои строчки проведения. проведение по этим строкам работает до отражения в регл учете.

не могу понять, куда мне в Модуле менеджера вставить свои строки проведения, между чем и чем...

(11) куда?

(13) если кодом - в модуль регистра
если запросом - в модуль менеджера

(14) мне надо кодом. модуль регистра? это модуль набора записей?

(15) угу, перед записью

сделала через общий модуль "РеализацияТоваровУслугЛокализация", но вопрос, как в этих Текстах запросов сделать Левое соединение с регистром сведений, дату среза как задать? там же параметры свои предопределенные.... пока поставила число в расчетную формулу суммы, а мне надо из регистра сведений значение тарифа

(17) дату документа возьми соединением с ДокументыКОтражению

(18)+
    |ИЗ
    |    ДокументыКОтражению КАК ДокументыКОтражению
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК Операция
    |        ПО ДокументыКОтражению.Ссылка = Операция.Ссылка
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг.Товары КАК СтрокиТовары
    |        ПО (СтрокиТовары.Ссылка = Операция.Ссылка)
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаНоменклатуры КАК Аналитика
    |        ПО (СтрокиТовары.АналитикаУчетаНоменклатуры = Аналитика.КлючАналитики)
    |        ЛЕВОЕ СОЕДИНЕНИЕ КурсыВалют КАК КурсВалютыУпрУчета
    |        ПО (КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета)
    |            И (КурсВалютыУпрУчета.Дата = НАЧАЛОПЕРИОДА(Операция.Дата, ДЕНЬ))
    |        ЛЕВОЕ СОЕДИНЕНИЕ преф_ВТНастройкиУчетаАкциза КАК НастройкиУчетаАкциза
    |        ПО (НастройкиУчетаАкциза.Организация = Операция.Организация)
    |            И (НастройкиУчетаАкциза.ДатаДокумента = Операция.Дата)

(19) спасибо! попробую
(5) получилось! спасибо!
(14) спасибо!

(19) не получилось. в регистре сведений нет Дата, есть Период, у меня срез последних на дату документа. как сделать? не получается...

(16) можно кусочек кода? если не через запрос, а через код, то как там в Модуле набора записей в проц ПередЗаписью связать движения документа...немного непонятно

Попробовала третьим способом (не получается срез последних по регистру сведений получить из-за отсутствия параметров) сделать:
подписка на событие в расширении для Регистра бухгалтерии - Хозрасчетный:

Источник - РегистрБухгалтерииНаборЗаписей.Хозрасчетный
Событие  - ПередЗаписью
Обработчик - _допОбщийМодуль.ПроведениеРТУПередЗаписью

тоже никаких движений не лает, вернее он их формирует, но после Отражения в регл учете  - затирает.

Так что понять не могу , как можно с помощью кода,а не через типовой механизм через тексты запросов решить этот момент...
Поскажите, пожалуйста, может я зациклилась...

Механизм отражения в рег. учете действует следующим образом (если упрощенно):
Проведение документа не делает проводок.
Обработка "отражение в рег учете" дописывает движения по регистру "Хозрасчетный" и снимает признак "К отражению" который реализован регистром сведений.
Повторное проведение очищает движения по регистру "Хозрасчетный" и снова ставит признак к отражению.
Следовательно бесполезно писать проводки при проведении, нужно расширять штатный механизм. Это правильно. Не надо изобретать велосипед. Нужно правильно изменить запрос в ТекстОтраженияВРеглУчете(). Если необходимы дополнительные параметры для запроса, нужно расширить процедуру которая устанавливает эти параметры.

(24) спасибо за ответ! я сделала через штатный механизм, только он сделал верные проводки. искала, где устанавливаются все изначальные параметры, не нашла... не подскажите, где их можно вставить, очень нужно... но дело в том, что этот параметр - это дата проводимого документа, вроде  все есть, но у меня с Регистром сведений (срез последних) на дату проводимого документа проблема, не могу задать никак этот параметр. Регистр сведений элементарный - периодический в пределах дня, измерение - организация, ресурс - число (тариф).

вот такой вариант не работает:
  |        ПО (КурсВалютыУпрУчета.Валюта = &ВалютаУпрУчета)
    |            И (КурсВалютыУпрУчета.Дата = НАЧАЛОПЕРИОДА(Операция.Дата, ДЕНЬ))

так, например, тариф установлен с 01.01.2023, и период в регистре не равен дате проводимого документа. как для курса валют не подходит, так как значение валюты каждый день есть. а здесь меняется значение может раз в год. как быть?

РеглУчетПроведениеСервер.УстановитьПараметрыЗапросаДанных(ЗапросДанных, ИмяДокумента, ВыборкаДокументов, ДетализацияПроводок)
Сюда попадает уже сформированный запрос. В этой процедуре собирается структура параметров, и в  конце вызывается процедура
ЗаполнениеПараметровЗапросаИПрочихФункциональныхОпций(ЗапросДанных, СтруктураПараметров, ПараметрыДанных);
которая непосредственно из структуры заполняет найденные параметры запроса.
Можно расширить ее (УстановитьПараметрыЗапросаДанных) например

(25) Регистр сведений элементарный - периодический в пределах дня, измерение - организация, ресурс - число (тариф)

Слишком короткий РС. А где акцизная группа? И по памяти ещё там есть налоговые параметры в НК РФ для тарифов.

Гляньте как люди сделали для ЕРП:
https://infostart.ru/1c/articles/1455914/

(25) Через ВТ же
ТекстЗапросаВТОтраженияВРеглУчете()

изучи как там строятся временные таблицы по периодическим РС
аналогично строишь через МАКСИМУМ и Период <= Операция.Дата

(27) Для разных видов акцизов там по разному
Для табака например сильно сложно, для ГСМ попроще а некоторые акцизы там нет групп

(27) И не факт что у ТС именно акцизы

+(26) Важно не забывать, что данный запрос выполняется для массива (выборки) документов. Поэтому совет: посмотреть где и как формируется временная таблица "КурсВалютыУпрУчета" и сделать по аналогии. Что бы для ваших проводок была своя временная таблица "ПрефиксРасширения_ИмяВашегоРегистра" и тогда вариант из (25) будет работать.

(30) Факт. В 1С проводка Дт 90.04 - Кт 68.03 именно что акциз. Табак и алкоголь реализовано, а вот нефтянка оставлена на прокорм франчайзи )

(32) ну у меня счета в настройках прописываются аналитиками я уже и забыл что 68.03 акциз

акцизы на табак кстати в типовых нихрена не реализованы
самый изврат будет когда надо будет печформы с-ф выводить с заполнением колонки акциз

(31) вариант из (25) не будет работать. написала выше. регистр сведений по курсам валют имеет ежедневно значение. вот их и проверяют на дату документа. у меня бы тоже работал без всяких параметров

(32) в КА 2.5.14.74 для сахаросодержащих напитков не реализовано

(27) нам пока достаточно

(28) не нашла, очень все сложно, но надо разобраться. может уже кто-то разбирался и делал соединение с Регистром сведений, вы куда параметры прописывали? подскажите  функцию/процедуру? что жалко? я если найду, то поделюсь

(37)

Функция ТекстЗапросаВТОтраженияВРеглУчете() Экспорт
    
    ТекстыЗапроса = Новый Массив;
    
    //++ Локализация
    
    // преф_ВТАкцизы
    ТекстЗапроса =
    "ВЫБРАТЬ
    |    Товары.Ссылка КАК Ссылка,
    |    Товары.АналитикаУчетаНоменклатуры КАК АналитикаУчетаНоменклатуры,
    |    СУММА(Товары.преф_СуммаАкциза) КАК преф_СуммаАкциза
    |ПОМЕСТИТЬ преф_ВТАкцизы
    |ИЗ
    |    ДокументыКОтражению КАК ДокументыКОтражению
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг.Товары КАК Товары
    |        ПО ДокументыКОтражению.Ссылка = Товары.Ссылка
    |ГДЕ
    |    Товары.Номенклатура.ПодакцизныйТовар = ИСТИНА
    |
    |СГРУППИРОВАТЬ ПО
    |    Товары.Ссылка,
    |    Товары.АналитикаУчетаНоменклатуры";
    ТекстыЗапроса.Добавить(ТекстЗапроса);
    
    // преф_ВТНастройкиУчетаАкциза
    ТекстЗапроса =
    "ВЫБРАТЬ
    |    Операция.Дата КАК ДатаДокумента,
    |    Операция.Организация КАК Организация,
    |    МАКСИМУМ(НастройкиУчетаАкциза.Период) КАК ДатаНастройкиАкциза
    |ПОМЕСТИТЬ преф_ВТНастройкиУчетаАкцизаВрем
    |ИЗ
    |    ДокументыКОтражению КАК ДокументыКОтражению
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК Операция
    |        ПО ДокументыКОтражению.Ссылка = Операция.Ссылка
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.преф_НастройкиУчетаАкциза КАК НастройкиУчетаАкциза
    |        ПО (НастройкиУчетаАкциза.Период <= Операция.Дата)
    |ГДЕ
    |    НастройкиУчетаАкциза.Организация = Операция.Организация
    |    И НастройкиУчетаАкциза.Плательщик = ИСТИНА
    |
    |СГРУППИРОВАТЬ ПО
    |    Операция.Дата,
    |    Операция.Организация
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    НастройкиУчетаАкцизаВрем.ДатаДокумента КАК ДатаДокумента,
    |    НастройкиУчетаАкцизаВрем.Организация КАК Организация,
    |    НастройкиУчетаАкциза.Период КАК ДатаНастройкиАкциза,
    |    НастройкиУчетаАкциза.Плательщик КАК Плательщик,
    |    НастройкиУчетаАкциза.СчетУчетаАкцизаПриОтгрузке КАК СчетУчетаАкцизаПриОтгрузке
    |ПОМЕСТИТЬ преф_ВТНастройкиУчетаАкциза
    |ИЗ
    |    преф_ВТНастройкиУчетаАкцизаВрем КАК НастройкиУчетаАкцизаВрем
    |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.преф_НастройкиУчетаАкциза КАК НастройкиУчетаАкциза
    |        ПО (НастройкиУчетаАкциза.Период = НастройкиУчетаАкцизаВрем.ДатаНастройкиАкциза)
    |            И (НастройкиУчетаАкциза.Организация = НастройкиУчетаАкцизаВрем.Организация)
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |УНИЧТОЖИТЬ преф_ВТНастройкиУчетаАкцизаВрем";
    ТекстыЗапроса.Добавить(ТекстЗапроса);

// ...

    // Добавим пустой запрос, для того чтобы последний запрос тоже заканчивался на разделитель пакета запросов:
    ТекстыЗапроса.Добавить("");
    
    //-- Локализация
    
    ТекстЗапроса = СтрСоединить(ТекстыЗапроса, ОбщегоНазначения.РазделительПакетаЗапросов());
    Возврат ТекстЗапроса;
    
КонецФункции



Кстати кроме реализаций есть еще возвраты и корректировки (исправительная и по согласованию)
И вот там будет весело - с учетом что акцизы могут между реализацией и возвратом/корректировкой меняться ))

Реализовать в ERP/КА/УТ полноценный учет акцизов - это как подсистему учета НДС сваять
И да чисто технически НДС это вид акцизов!

Сахар же простой. И вообще акцизы индексируются раз в год, ну пусть с запасом месяц. Сто пудов не нужна тут подённая периодичность для тарифа сахара. Да и РС не нужен, можно в константе вести.
В любом случае, может быть легче будет написать код для месячной периодичности?

(41) Не раз в год
И причем тут месячная если акциз вводится (или меняется) с определенного дня, обычно с 1-го числа месяца

(42)+ Совершенно не факт что с 1-го числа всегда будут менять ))

Например для табака пришлось в ТЧ Товары добавлять кроме  суммы акциза еще дату ставки акциза и сами ставки (там по табаку все сложно со ставками и расчетом суммы акциза)
При вводе строк документа ставки подтягиваются на выбранную дату ставки акциза из РС и в дальнейшем используются в движениях/проводках

(42) А это и есть начало месяца.
(43) Факт. В НК РФ прописано, что все изменения ставок начинают действовать как минимум только с начала следующего налогового периода, а для акцизов это месяц.
Не мудрите. Выкидывайте подённый учёт напрочь и недрожащей рукой.

(45) Кто мешает поменять налоговый период? :)

Нет смысла учитывай поденный
Потому что датой (ДД.ММ.ГГГГ) очень удобно задавать периоды в отличие от двух месяц + год

(47) *нет смысла выкидывать поденный

(47)+ Например у меня если выбрать дату не точно начала действия ставки то она меняется на дату начала из РС ближайшую перед выбранной датой (датой документа)

(49)+ А фактически дата документа в (38) это для того чтобы получить для документа (с учетом Организация и Дата) надо ли использовать учет акцизов или не надо

(50) Мы здесь сахар рассматриваем. Ну какая на фиг организация, если тариф един для всей РФ и равен 7 рублям.
Или Вы 13% НДФЛ, к примеру, тоже по организациям смотрите?

(51) В одной базе может быть несколько организаций
Одна учитывает акцизы "на сахар" а другая нет

А еще есть экспорт
И там начинаются чудеса а акцизами

Чушь. Ведение/неведение акцизов можно задавать в учётной политике.

(51) >Или Вы 13% НДФЛ, к примеру, тоже по организациям смотрите?

Подумай зачем выделены модули "..Локализация"

(54) Неудобно еще из других мест настройки получать

"Акциз в отношении сахаросодержащих напитков будет уплачиваться с 1 июля 2023 года по ставке 7 рублей за литр (пп. 40 п. 1 ст. 193 НК РФ). Для субъектов малого предпринимательства предусмотрено освобождение от обложения акцизом реализации и передачи произведенных сахаросодержащих напитков в налоговых периодах по акцизу, дата начала которых приходится на период с 1 июля 2023 года до 30 сентября 2023 года включительно."
https://www.nalog.gov.ru/rn38/taxation/taxes/13413797/

"не малые" с 01.07.2023
"малые" с 01.10.2023

(57)+ Если организация (когда в базе их несколько) не реализует дальше сахаросодержащие (чисто покупает для себя) то по ней нет смысла учитывать акцизы

(57) И что? Константа всё равно с 01.07.2023, а включение акцизности в учётке с 01.10.2023.
Несерьёзно и нелепо вести тариф по организациям.

А впрочем чего это я? Делайте как хотите...

(59) Вести не акциз а настройки учета акциза в целом по каждой организации
Два РС
1-й ставки акцизов по их видам
2-й настройки учета акцизов по организациям

(60) Твое решение вполне рабочее но сильно ограниченное
В базе одна организация и т.д.
Если чуть посложней то сразу упс

В любом случае отражение в рег. учете может иметь период включающий в себя дату изменения акциза, следовательно просто параметром не получится, а значит (38). И тема улетела от начальной задачи. Я не очень силен в акцизах, но если в (32) правда, что для "Табак и алкоголь реализовано" может имеет смысл покапать в сторону добавления в массив "подакцизных" аналитик еще и "сахар" и тогда никаких запросов менять не нужно?

(63) В типовых никаких акцизов не реализовано!
Кроме пустой колонки "акциз" в печатных формах с-ф, упд и укд

(64)+ А еще реготчетность есть по акцизам, которую надо ручками заполнять
Вот сделать автозаполнение реготчетности это еще ТС предстоит

(65)+ Добавить чтобы в ЕНП тоже акцизы попадали

(64) всё верно, акцизы в отраслевых решениях =)

(67) ага франчам работы привалило
а еще новые отраслевки или дополнения/расширения по акцизам на сахар начнут продавать

(68)+ как с алкоголиками и маркировками

Тогда можно рассмотреть создание регламентного документа "Начисление акциза". Там ТС хватит знаний создать нужные проводки и механизм отражения в учете не будет "мешать".

(70) Это еще более извращенный вариант
С учетом перепроводения/исправления задним числом

И замены проводок, там по акцизам не только новые проводки добавляются но и суммы типовых проводок надо уменьшать на сумму акциза

(71) Ну тогда без вариантов, осваивать и пилить типовые механизмы, со всеми остановками.