Добрый день. Есть база, хотим часть пользователей пересадить на такси. Можно ли как-то программно это сделать? Нашел только ключик для параметров запуска базы.

Лучше вручную

(0) можно в конфигурации поменять, без всяких ключиков, но всех

в ут от бсп есть процедура
    ОбщегоНазначенияУТ.УстановитьРежимКомандногоИнтерфейса(ВариантИнтерфейса);
правда это в версии 11_2_3

https://i.ibb.co/41BHwnh/2024-07-29-09-27-24.png

(0) о какой конфигурации речь?
а то вдруг УТ 10.3...

(0) да, программно это сделать можно.
Например, таким образом
Процедура УстановитьНачальныеНастройкиСВыборомВариантаИнтферфейса(Знач ИмяПользователя,Такси) Экспорт
    
    НастройкиКлиента = Новый НастройкиКлиентскогоПриложения;
    НастройкиКлиента.ОтображатьПанелиНавигацииИДействий = Ложь;
    НастройкиКлиента.ОтображатьПанельРазделов = Истина;
    
    
    НастройкиИнтерфейса  = Новый НастройкиИнтерфейсаКлиентскогоПриложения;
    
    Если Такси Тогда                                                
        НастройкиКлиента.ВариантИнтерфейсаКлиентскогоПриложения = ВариантИнтерфейсаКлиентскогоПриложения.Такси;
        
        НастройкиСостава = НастройкиИнтерфейса.ПолучитьСостав();
        НастройкиСостава.Верх.Очистить();
        НастройкиСостава.Лево.Очистить();
        НастройкиСостава.Право.Очистить();
        НастройкиСостава.Низ.Очистить();
        
        ПанельРазделов = Новый ГруппаНастройкиСоставаИнтерфейсаКлиентскогоПриложения;
        ПанельРазделов.Добавить(Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельРазделов"));
        
        ПанельОткрытых = Новый ГруппаНастройкиСоставаИнтерфейсаКлиентскогоПриложения;
        ПанельОткрытых.Добавить(Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельОткрытых"));
        
        НастройкиСостава.Верх.Добавить(ПанельРазделов);
        НастройкиСостава.Верх.Добавить(ПанельОткрытых);
            
        НастройкиИнтерфейса.УстановитьСостав(НастройкиСостава);
        
    Иначе
        НастройкиКлиента.ВариантИнтерфейсаКлиентскогоПриложения = ВариантИнтерфейсаКлиентскогоПриложения.Версия8_2;
        НастройкиКлиента.РежимОткрытияФормПриложения = РежимОткрытияФормПриложения.ОтдельныеОкна;
    КонецЕсли;
    
    НачальныеНастройки = Новый Структура;
    НачальныеНастройки.Вставить("НастройкиКлиента",    НастройкиКлиента);
    НачальныеНастройки.Вставить("НастройкиИнтерфейса", НастройкиИнтерфейса);
    
        
    ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиКлиентскогоПриложения","" ,
    НачальныеНастройки.НастройкиКлиента, , ИмяПользователя);
    
    ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения","" ,
    НачальныеНастройки.НастройкиИнтерфейса,,  ИмяПользователя);
    
        
КонецПроцедуры

(6) И что, разве получится для ОДНОЙ открытой базы у разных пользователей такси/не такси?
Это ж не пользовательский интерфейс, а внешний вид предприятия. Как причёска в армии единая для всех.
Нет?

(7) при условии, что в свойствах конфигурации включить "Разрешить такси", возможно для одной базы и разных пользователей сделать различный интерфейс. Кому такси, кому-то закладки.

(8) Ну, не знаю... значит, что-то новое... запомним. Спасибо.

(7) Возможно. Разным юзверям разные варианты интерфейса.