Всем привет.
Утро пасмурное, тормоз ужасный... :)

Есть Иерархический справочник Подразделений.
Выбрано подразделение фиг знает какой вложенности.

Мне нужно вернуть Родителя выбранного подразделения самого верхнего
уровня у которого реквизит Родитель пустой.

Дайте идею, как это сделать?

есть кусок кода некошерного с запросом в цикле :)

получить 0 уровень (у котороко родитель пустой) и соеденить со списком выбраных по условию в иерархие

Функция ВернутьРодителя(Элемент)
   Если Элемент.Родитель.Пустая() Тогда
       Возврат Элемент;
   Иначе
       Возврат ВернутьРодителя(Элемент.Родитель);
   КонецЕсли;
КонецФункции

ВерхнийУровеньРодитель = Ссылка;
Пока ЗначениеЗаполнено(ВерхнийУровеньРодитель .Родитель) Цикл
ВерхнийУровеньРодитель = ВерхнийУровеньРодитель .Родитель;
КонецЦикла;

Функция ПолучитьДепартамент(Подразделение) Экспорт
   
   Запрос = Новый Запрос;
   Запрос.Текст = "ВЫБРАТЬ
   |    ПодразделенияОрганизаций.Ссылка
   |ИЗ
   |    Справочник.ПодразделенияОрганизаций КАК ПодразделенияОрганизаций
   |ГДЕ
   |    ПодразделенияОрганизаций.Родитель = &ПустойРодитель";
   
   Запрос.УстановитьПараметр("ПустойРодитель", Справочники.ПодразделенияОрганизаций.ПустаяСсылка());
   
   Результат = Запрос.Выполнить();
   Выборка = Результат.Выбрать();
   
   Пока Выборка.Следующий() Цикл
       
       Запрос = Новый Запрос;
       Запрос.Текст = "ВЫБРАТЬ
       |    ПодразделенияОрганизаций.Ссылка
       |ИЗ
       |    Справочник.ПодразделенияОрганизаций КАК ПодразделенияОрганизаций
       |ГДЕ
       |    ПодразделенияОрганизаций.Ссылка В ИЕРАРХИИ(&Родитель)
       |    И ПодразделенияОрганизаций.Ссылка = &Подразделение";
       
       Запрос.УстановитьПараметр("Подразделение", Подразделение);
       Запрос.УстановитьПараметр("Родитель", Выборка.Ссылка);
       
       Результат = Запрос.Выполнить();
       Выборка1 = Результат.Выбрать();
       
       Если Выборка1.Следующий() Тогда
           возврат Выборка.Ссылка;
       КонецЕсли;    
       
   КонецЦикла;
   
   Возврат Справочники.ПодразделенияОрганизаций.ПустаяСсылка();
   
   
КонецФункции

А если одним запросом?
(3)(4)
Или этот код базу дергать не будет,
как запрос (5).

(5) поубивал-бы за такое, одним запросом делается за 2 минуты

(7) как?

(7) согласен, делается

(7)(9) Как будет выглядеть запрос?

вот я так делал:


Тег_CodeGroup1C = РаботаСШинамиИДисками.ПолучитьВерхнийУровеньГруппы(Выборка.Номенклатура).Код;


//Получить верхний уровень группы переданной ссылки справочника
//
Функция ПолучитьВерхнийУровеньГруппы (ГруппаИерархии, ВерхняяГруппа=Неопределено) Экспорт

   Если ГруппаИерархии.Уровень() <> 0 Тогда
       
       ВерхняяГруппа = ПолучитьВерхнийУровеньГруппы(ГруппаИерархии.Родитель);
       
       Если ВерхняяГруппа.Уровень() = 0 Тогда
       
           Возврат ВерхняяГруппа;
       
       КонецЕсли;
       
   Иначе
       
       Возврат ГруппаИерархии;
       
   КонецЕсли;    
   
КонецФункции

(10) например, так:

ВЫБРАТЬ
   Контрагенты.Ссылка КАК Ссылка,
   Контрагенты.Представление
ИЗ
   Справочник.Контрагенты КАК Контрагенты
ГДЕ
   Контрагенты.Ссылка = &Ссылка
ИТОГИ ПО
   Ссылка ТОЛЬКО ИЕРАРХИЯ

из результата берем только 1 строку

(12)+ Представление не нужно, это конструктор добавил

Негламурное решение с фиксированной максимальной глубиной иерархии

ВЫБРАТЬ
   Номенклатура.Ссылка,
   ВЫБОР
       КОГДА Номенклатура.Родитель = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
           ТОГДА Номенклатура.Ссылка
       КОГДА Номенклатура.Родитель.Родитель = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
           ТОГДА Номенклатура.Родитель
       КОГДА Номенклатура.Родитель.Родитель.Родитель = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
           ТОГДА Номенклатура.Родитель.Родитель
       ИНАЧЕ Номенклатура.Родитель.Родитель.Родитель
   КОНЕЦ КАК РодительВерхнегоУровня
ИЗ
   Справочник.Номенклатура КАК Номенклатура
ГДЕ
   Номенклатура.Ссылка В (&СписокНоменклатуры)

(10) +1 можно и так )))

(14) - это ООооочень тупо

(16) Ты не поверишь - но именно так в результает и сделаешь ;-)

(17) да нет же, есть более гламурные решения:
(11)
(12) + 1))) ЗЫ. я не там поставил я за 10 взял в (15) посте

ВЫБРАТЬ
   Подразделения.Ссылка
ИЗ
   Справочник.Подразделения КАК Подразделения
ГДЕ
   Подразделения.Ссылка = &Ссылка
   И Подразделения.Ссылка В ИЕРАРХИИ
           (ВЫБРАТЬ
               Подразделения.Ссылка КАК СсылкаНаВерхнего
           ИЗ
               Справочник.Подразделения КАК Подразделения
           ГДЕ
               Подразделения.Ссылка В
                   (ВЫБРАТЬ
                       Подразделения.Ссылка КАК Ссылка
                   ИЗ
                       Справочник.Подразделения КАК Подразделения
                   ГДЕ
                       Подразделения.Родитель = ЗНАЧЕНИЕ(справочник.подразделения.пустаяссылка)))

Функция РодительВерхнегоУровня(Ссылка) Экспорт
   
   ВыбПодразделение = Ссылка.ТекущееПодразделениеОрганизации;
   Если ВыбПодразделение.Уровень() = 0 Тогда
       Департамент = ВыбПодразделение;
   Иначе
       Департамент = Справочники.ПодразделенияОрганизаций.НайтиПоКоду(Лев(ВыбПодразделение.ПолныйКод(), Найти(ВыбПодразделение.ПолныйКод(),"/")-1)).Ссылка;
   КонецЕсли;
   
   Возврат Департамент;
   
КонецФункции


по мне то самое изящное решение указано в (12)

(21) Это изящное решение имеет существенный минус - итоги не получится использовать во вложенных запросах.
Имхо решение в (19) гораздо интереснее

(12) Класс !!!

Спасибо всем.

(22) решение (19) конечно интереснее, только оно неправильное

Родитель самого верхнего уровня = пустой ссылке

(0) у меня нумерация подразделений построена по принципу многоуровневого списка.
0100
-0101
--0101-01

Получить верхний уровень - никакого труда не составляет.

(24) Жаль, так перспективно выглядело :(

(24) да, лоханулся не туда :)