Ошибка vbs скрипта административной установки

Тему уже успешно поднимали: v8: проблема с установкой 1с v8.2 через скрипт logon

Скрипт с ИТС в студию:

Option Explicit

' изменять интерфейс пользователя
Const msiUILevelNoChange = 0
'Использовать интерфейс пользователя, заданный по умолчанию
Const msiUILevelDefault = 1
'Не отображать интерфейс пользователя (молчаливая установка)
Const msiUILevelNone = 2
'Только индикатор прогресса и отображение ошибок
Const msiUILevelBasic = 3
'Интерфейс пользователя без диалоговых сообщений
Const msiUILevelReduced = 4
'Полный интерфейс пользователя
Const msiUILevelFull = 5
'Если используется с msiUILevelBasic, то отображается индикатор
'прогресса без кнопки Cancel
Const msiUILevelHideCancel = 32
'Если используется с msiUILevelBasic, то отображается индикатор
'прогресса без тображения любых диалогов, в т.ч. и ошибок.
Const msiUILevelProgressOnly = 64
'Если используется с любым из перечисленных значений, инсталлятор
'выводит сообщение в конце установки о конечном результате.
Const msiUILevelEndDialog = 128

'***** Необходимо изменить на реальный каталог установки
Const DistrFolder="\\Server\1CDistr\"

Const shortcutName = "Запуск 1C Предприятия"
Dim shortcutTarget : shortcutTarget = DistrFolder & "1cestart.exe"

'Константы для определения действия
' требуется установка
Const requiredInstall = 1
' требуется удаление
Const requiredUninstall = 0

'Значение параметра ProductCode из файла setup.ini ...
'... для удаляемой версии
Const unInstallUID="{9173B91C-FF56-4F25-82D1-7F68244044CD}"
'... для устанавливаемой версии
Const InstallUID="{0BC98727-04AD-470F-9EEE-0162C543833F}"

'процедура установки или удаления указанной версии продукта
Sub installOrUninstall (ByVal productCode, ByVal msiPackage, ByVal mstTransform, ByVal requiredAction)
'productCode — Информация о коде продукта. Находится в файле
' setup.ini, ключ ProductCode
'msiPackage — Установочный пакет 1CEnterprise
'mstTransform — файл языкового преобразования для инсталлятора
'requiredAction — требуемое действие requiredInstall или
' requiredUninstall

'Переменная, для формирования дополнительных
' параметров инсталлятору
Dim cmdLine

On Error Resume Next

Dim installer, session

Set installer = Nothing
Set session = Nothing
Set installer = Wscript.CreateObject("WindowsInstaller.Installer") : processError
installer.UILevel = msiUILevelBasic 'msiUILevelNone 'или укажите другой вариант интерфейса пользователя
'проверка установки продукта
Set session = installer.OpenProduct(productCode)

If session Is Nothing AND requiredAction = requiredInstall Then
'продукт не установлен и требуется его установка
cmdLine = "TRANSFORMS=adminstallrelogon.mst;"
If Not mstTransform Is Empty Then
'добавим указание инсталлятору разговаривать на указанном языке
cmdLine = cmdLine & mstTransform
'можно дополнительно указать, какие компоненты нужно установить
'cmdLine = cmdLine & " DESIGNERALLCLIENTS=1 THINCLIENT=1 WEBSERVEREXT=0 SERVER=0 CONFREPOSSERVER=0 CONVERTER77=0 SERVERCLIENT=1 LANGUAGES=RU"
End If
'установим платформу
Set session = installer.InstallProduct(msiPackage, cmdLine) : processError
'создадим ярлык на рабочем столе
createShurtcut()

ElseIf Not session Is Nothing AND requiredAction = requiredUninstall Then
'платформа уже установлена и требуется ее удаление
'обьект session может быть только один!
Set session = Nothing
'укажем, что нужно удалить с компьютера пользователя эту версию
cmdLine = "REMOVE=ALL"
'удалим
Set session = installer.InstallProduct(msiPackage, cmdLine) : processError
End If

Set session = Nothing
Set installer = Nothing

End Sub

'обработка ошибок
Sub processError
Dim msg
If Err = 0 Then Exit Sub
msg = Err.Source & " " & Hex(Err) & ": " & Err.Description
Wscript.Echo msg
Wscript.Quit 2
End Sub

'создание ярлыка
Sub createShurtcut
Dim WshShell, oShellLink
Set WshShell = WScript.CreateObject("WScript.Shell")
Dim strDesktop : strDesktop = WshShell.SpecialFolders("Desktop")
Set oShellLink = WshShell.CreateShortcut(strDesktop & "\" & shortcutName & ".lnk")
oShellLink.TargetPath = shortcutTarget
oShellLink.WindowStyle = 1
oShellLink.Description = shortcutName
oShellLink.Save
Set oShellLink = Nothing
Set WshShell = Nothing
End Sub

'удалим версию 260
installOrUninstall unInstallUID, DistrFolder + "8.2.9.260\setup\1CEnterprise 8.2.msi", "1049.mst", requiredUninstall
'установим версию 356
installOrUninstall InstallUID, DistrFolder + "8.2.9.356\setup\1CEnterprise 8.2.msi", "1049.mst", requiredInstall