Сделал элементарную обработку фильтрации, но на больших таблицах работает не достаточно быстро. Как ускорить?

Функция глФильтрПоТаблицеЗначений(ТаблицаЗначений, Колонка, Значение) Экспорт
   
   ТекКол = ТаблицаЗначений.ПолучитьПараметрыКолонки(Колонка);
   Если ПустоеЗначение(ТекКол) = 1 Тогда
       Возврат ТаблицаЗначений;
   КонецЕсли;
   
   тзФильтр = СоздатьОбъект("ТаблицаЗначений");
   ТаблицаЗначений.Выгрузить(тзФильтр);
   
   Всего = тзФильтр.КоличествоСтрок();
   Для Сч = 1 По Всего Цикл
       ТекНом = Всего - Сч + 1;
       ТекЗнач = тзФильтр.ПолучитьЗначение(ТекНом, ТекКол);
       
       Удовлетворяет = 0;
       Если ТипЗначенияСтр(Значение) = "СписокЗначений" Тогда
           Удовлетворяет = Значение.Принадлежит(ТекЗнач);
       Иначе
           Удовлетворяет = ?(Значение = ТекЗнач, 1, 0);
       КонецЕсли;
       
       Если Удовлетворяет = 0 Тогда
           тзФильтр.УдалитьСтроку(ТекНом);
       КонецЕсли;
       
   КонецЦикла;
   
   Возврат тзФильтр;
   
КонецФункции // глФильтрПоТаблицеЗначений




много в ТЗ СписокЗначений ?

Метод рупора чем не устроил?

А, дошел смысл функции. Если надо быстро, то индексированная таблица тут рулит во всех отношениях: включитьфильтр, пересечение, разность

принадлежит() очень тормозной.


отсортировать и методом вилки.

если вызовов много отсортировать перед

если нужно сохранить порядок строк то

перед сортировкой заполнить 1..N


если тз больше 300 строк
быстрее заполнить СЗ   и загрузить в колонку.

Удаление строк ТЗ

(1) 40 тыщ
(3) Ага гляну, пасиб.
(5) Да, с сортировкой интересно, не надо перебирать всё подряд.

А может кто пользовался 1sqlite - УложитьТЗ и потом SELECT выбрать, какие впечатления?

Сделал на индексированных таблицах, по замерам работает почти в 6 раз быстрее - 6110 (перебор в ТаблицеЗначений) 1231 (Фильтрация и объединение индексированных таблиц).

Функция глФильтрПоТаблицеЗначений(ТаблицаЗначений, Колонка, Значение) Экспорт
   
   ТекКол = ТаблицаЗначений.ПолучитьПараметрыКолонки(Колонка);
   Если ПустоеЗначение(ТекКол) = 1 Тогда
       Возврат ТаблицаЗначений;
   КонецЕсли;
   
   тзФильтр = СоздатьОбъект("ИндексированнаяТаблица");
   тзФильтр.Загрузить(ТаблицаЗначений);
   
   Если ТипЗначенияСтр(Значение) = "СписокЗначений" Тогда
       СписокФильтров = Значение;
   Иначе
       СписокФильтров = СоздатьОбъект("СписокЗначений");    
       СписокФильтров.ДобавитьЗначение(Значение);
   КонецЕсли;
   
   Если ТипЗначения(Колонка) = 2 Тогда
       НаименованиеКолонки = Колонка;
   Иначе
       НаименованиеКолонки = ТекКол;
   КонецЕсли;
   
   тзФильтр.ДобавитьИндекс("ФильтрОтбора", "*" + НаименованиеКолонки);
   тзРезультат = СоздатьОбъект("ИндексированнаяТаблица");
   тзИтоговая = СоздатьОбъект("ИндексированнаяТаблица");
   Для Сч = 1 По СписокФильтров.РазмерСписка() Цикл
       ТекЗнач = СписокФильтров.ПолучитьЗначение(Сч);
       тзФильтр.УстановитьФильтр(ТекЗнач, ТекЗнач, "ФильтрОтбора");
       
       Если тзИтоговая.КоличествоСтрок() = 0 Тогда
           тзФильтр.Выгрузить(тзИтоговая, "ФильтрОтбора");
       Иначе
           тзИтоговая.Объединить(тзФильтр, "ФильтрОтбора");
       КонецЕсли;
       
       тзФильтр.ВыключитьФильтр("ФильтрОтбора");
       
   КонецЦикла;
   
   тзФильтр = СоздатьОбъект("ТаблицаЗначений");
   тзИтоговая.Выгрузить(тзФильтр);
   
   Возврат тзФильтр;
   
КонецФункции // глФильтрПоТаблицеЗначений