Доброго времени суток!
Собственно сабж:

Подскажите как выбрать всю Номенклатуру из справочника, которая ни разу не использовалась(не выбиралась) в документах(не важно, проведен или нет) ПоступлениеТоваровУслуг и РеализацияТоваровУслуг.

Заранее спасибо!

Глобальный контекст (Global context)
НайтиПоСсылкам (FindByRef)
Синтаксис:

НайтиПоСсылкам(<СписокСсылок>)
Параметры:

<СписокСсылок> (обязательный)

Тип: Массив. Массив со списком ссылок на объекты, ссылки на которые нужно найти.
Возвращаемое значение:

Тип: ТаблицаЗначений. Возвращает ссылки на найденные объекты в виде ТаблицаЗначений, состоящей из колонок с индексами: 0 - искомая ссылка; 1 - ссылка на объект, если найдена ссылка в объектной таблице; ключ записи, если ссылка найдена в независимом регистре сведений; ссылка на документ-регистратор для всех остальных необъектных таблиц; 2 - объект метаданных, которому соответствуют данные из колонки 1.
Описание:

Осуществляет поиск ссылок на объекты, переданные в параметре <СписокСсылок>.

Доступность:

Сервер, толстый клиент, внешнее соединение.
Пример:

Ссылки = НайтиПомеченныеНаУдаление();
ТабСсылок = НайтиПоСсылкам(Ссылки);
Для Каждого Ссылка из ТабСсылок Цикл
   Сообщить ("" + СокрЛП(Ссылка[0]) + "  " + СокрЛП(Ссылка[1]));
КонецЦикла;

Прошу прощения, что не было указано ранее - нужно сделать запросом.

Пыталась исключить из Справочника найденную Номенклатуру из Документов, но что-то никак не получается - все равно выводит все данные из Справочника.

(2) где запрос-то?


ВЫБРАТЬ РАЗЛИЧНЫЕ
   ПоступлениеТоваровУслугТовары.Номенклатура
ПОМЕСТИТЬ ВПоступлениях
ИЗ
   Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
   РеализацияТоваровУслугТовары.Номенклатура
ПОМЕСТИТЬ ВРелизациях
ИЗ
   Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   СпрНоменклатура.Ссылка
ИЗ
   Справочник.Номенклатура КАК СпрНоменклатура
       ЛЕВОЕ СОЕДИНЕНИЕ ВПоступлениях КАК ВПоступлениях
       ПО СпрНоменклатура.Ссылка = ВПоступлениях.Номенклатура
       ЛЕВОЕ СОЕДИНЕНИЕ ВРелизациях КАК ВРелизациях
       ПО СпрНоменклатура.Ссылка = ВРелизациях.Номенклатура
ГДЕ
   ВПоступлениях.Номенклатура ЕСТЬ NULL
   И ВРелизациях.Номенклатура ЕСТЬ NULL
   И (НЕ СпрНоменклатура.ЭтоГруппа)


+ (4) только нужно еще добавить табл части Услуги и возвратная тара (если они есть)

или так

ВЫБРАТЬ
   СпрНоменклатура.Ссылка
ИЗ
   Справочник.Номенклатура КАК СпрНоменклатура
       ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ РАЗЛИЧНЫЕ
           ПоступлениеТоваровУслугТовары.Номенклатура КАК Номенклатура
       ИЗ
           Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
       
       ОБЪЕДИНИТЬ
       
       ВЫБРАТЬ РАЗЛИЧНЫЕ
           РеализацияТоваровУслугТовары.Номенклатура
       ИЗ
           Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары) КАК ВДокументах
       ПО СпрНоменклатура.Ссылка = ВДокументах.Номенклатура
ГДЕ
   ВДокументах.Номенклатура ЕСТЬ NULL
   И (НЕ СпрНоменклатура.ЭтоГруппа)


(6) офигеть запросец хДДД

было так:
[code]ВЫБРАТЬ РАЗЛИЧНЫЕ
   СпрНоменклатура.Ссылка КАК Ссылка
ИЗ
   Справочник.Номенклатура КАК СпрНоменклатура
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ (ВЫБРАТЬ РАЗЛИЧНЫЕ
           ПоступлениеТоваровУслугТовары.Номенклатура КАК Номенклатура
       ИЗ
           Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
       
       ОБЪЕДИНИТЬ ВСЕ
       
       ВЫБРАТЬ РАЗЛИЧНЫЕ
           РеализацияТоваровУслугТовары.Номенклатура
       ИЗ
           Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары) КАК ВложенныйЗапрос
       ПО (ВложенныйЗапрос.Номенклатура <> СпрНоменклатура.Ссылка)
ГДЕ
   СпрНоменклатура.ЭтоГруппа = ЛОЖЬ
   
УПОРЯДОЧИТЬ ПО
   Ссылка[/code]
Reset - Спасибо большое!

ВЫБРАТЬ
   Номенклатура.Ссылка
ИЗ
   Справочник.Номенклатура КАК Номенклатура
ГДЕ
   Номенклатура.Ссылка НЕ В
           (ВЫБРАТЬ
               ПоступлениеТоваровУслугТовары.Номенклатура
           ИЗ
               Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары)

(9) только добавить еще реализации объединением