Имя: Пароль:
1C
1С v8
УТ 10.3 Универсальный отчет.Свойства и категории.
0 kn
 
14.10.11
12:39
Подскажите почему в отчете на основе универсального могут не показываться названия свойств и категорий(показывает так ДоговорКонтрагентаСвойство2b9cd830f56011e08b2e001349ab324cЗначение,
КонтрагентСвойство23efd7a38b2e11e0a150001b21886c28Значение и т.п)

Процедура УстановитьНачальныеНастройки(ДополнительныеПараметры = Неопределено) Экспорт
   
   УниверсальныйОтчет.мНазваниеОтчета = СокрЛП(ЭтотОбъект.Метаданные().Синоним);
   
   УниверсальныйОтчет.мВыбиратьИмяРегистра = Ложь;
   УниверсальныйОтчет.мВыбиратьИспользованиеСвойств = Истина;
   УниверсальныйОтчет.ВыводитьДетальныеЗаписи = Истина;
   
   ТекстЗапроса = "ВЫБРАТЬ
                  |    ДоговорыКонтрагентов.Ссылка КАК ДоговорКонтрагента,
                  |    ДоговорыКонтрагентов.Владелец КАК Контрагент
                  |    //ПОЛЯ_СВОЙСТВА
                  |    //ПОЛЯ_КАТЕГОРИИ
                  |{ВЫБРАТЬ
                  |    ДоговорКонтрагента.*,
                  |    Контрагент.*
                  |    //ПСЕВДОНИМЫ_СВОЙСТВА
                  |    //ПСЕВДОНИМЫ_КАТЕГОРИИ
                  |}
                  |ИЗ
                  |    Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
                  |//СОЕДИНЕНИЯ      
                  |{ГДЕ
                  |    ДоговорыКонтрагентов.Ссылка.* КАК ДоговорКонтрагента,
                  |    ДоговорыКонтрагентов.Владелец.* КАК Контрагент
                  | //УСЛОВИЯ_СВОЙСТВА
                  | //УСЛОВИЯ_КАТЕГОРИИ
                  |}
                  |{УПОРЯДОЧИТЬ ПО
                  |    ДоговорКонтрагента.*,
                  |    Контрагент.*
                  |    //ПСЕВДОНИМЫ_СВОЙСТВА
                  |    //ПСЕВДОНИМЫ_КАТЕГОРИИ
                  |}
                  |{ИТОГИ ПО
                  |    ДоговорКонтрагента.*,
                  |    Контрагент.*
                  |    //ПСЕВДОНИМЫ_СВОЙСТВА
                  |    //ПСЕВДОНИМЫ_КАТЕГОРИИ
                  |}";
                 
   Если УниверсальныйОтчет.ИспользоватьСвойстваИКатегории Тогда
     УниверсальныйОтчет.ДобавитьСвойстваИКатегорииДляПоля("ДоговорыКонтрагентов.Владелец", "Контрагент", "Контрагент", ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_Контрагенты);
     УниверсальныйОтчет.ДобавитьСвойстваИКатегорииДляПоля("ДоговорыКонтрагентов.Ссылка", "ДоговорКонтрагента", "Договор контрагента", ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_ДоговорыКонтрагентов);
     УниверсальныйОтчет.ДобавитьВТекстЗапросаСвойстваИКатегории(ТекстЗапроса);
   КонецЕсли;
   
   УниверсальныйОтчет.ПостроительОтчета.Текст = ТекстЗапроса;
   
   УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ДоговорКонтрагента", "Договор контрагента");
   
   УниверсальныйОтчет.УстановитьНачальныеНастройки(Ложь);
   
   УниверсальныйОтчет.ДобавитьОтбор("ДоговорКонтрагента");
   УниверсальныйОтчет.ДобавитьОтбор("Контрагент");
   
   УниверсальныйОтчет.ДобавитьДополнительноеПоле("ДоговорКонтрагента");
   УниверсальныйОтчет.ДобавитьДополнительноеПоле("Контрагент");
КонецПроцедуры // УстановитьНачальныеНастройки()
1 kn
 
14.10.11
13:16
^
2 kn
 
14.10.11
14:28
Решилось добавлением
УниверсальныйОтчет.УстановитьПредставленияПолей(УниверсальныйОтчет.мСтруктураПредставлениеПолей, УниверсальныйОтчет.ПостроительОтчета);
УниверсальныйОтчет.УстановитьТипыЗначенийСвойствДляОтбора();
3 FreeArcher
 
02.11.11
11:47
А можно ли и как включить по умолчанию вывод конкретного свойства в отчет?
4 John83
 
02.11.11
14:00
(3) ну разве что через УИД извращаться...