В модуле команды документа у меня:
&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
   ПечатьАкта();
КонецПроцедуры


ПечатьАкта() расположена в модуле менеджера
Но во-первых, выдаётся ошибка, что эта процедура не определена
и во-вторых,в модуль менеджера надо передать Объект. И как это сделать?

Зачем ему целый объект? Ссылки достаточно. Это по-второму пункту.

(0) вызови серверную функицю модуля команды, а из нее Документы.ИмяДокумента.ПечатьАкта(...);

из книги по УФ если кому то пригодится
&НаСервере
Функция ПечатнаяФорма(ПараметрКоманды)
   ТабличныйДокумент = Новый ТабличныйДокумент;
   ТабличныйДокумент.ОтображатьСетку = Ложь;
   ТабличныйДокумент.Защита = Ложь;
   ТабличныйДокумент.ТолькоПросмотр = Ложь;
   ТабличныйДокумент.ОтображатьЗаголовки = Ложь;
   
   Сформирован = Ложь;
   
   Для каждого Ссылка Из ПараметрКоманды Цикл
       Документ = Ссылка.ПолучитьОбъект();
       Если НЕ Документ.Проведен Тогда
           Сообщение = Новый СообщениеПользователю();
           Сообщение.Текст = "Документ не проведен: " + Строка(Документ);
           Сообщение.КлючДанных = Ссылка;
           Сообщение.Сообщить();
           Продолжить;
       КонецЕсли;    
       Документ.ПечатнаяФорма(ТабличныйДокумент);
       Сформирован = Истина;
   КонецЦикла;    
   
   Если Сформирован Тогда
       Возврат ТабличныйДокумент;
   Иначе    
       Возврат Неопределено;
   КонецЕсли;    
   
КонецФункции

&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
   ТабличныйДокумент = ПечатнаяФорма(ПараметрКоманды);
   
   Если ТабличныйДокумент <> Неопределено Тогда
       ТабличныйДокумент.Показать();
   КонецЕсли;    
   
КонецПроцедуры