ВЫБРАТЬ
   ВложенныйЗапрос.Номенклатура,
   ВложенныйЗапрос.Количество
ИЗ
   (ВЫБРАТЬ
       ВложенныйЗапрос.Номенклатура КАК Номенклатура,
       ЕСТЬNULL(ТоварыНаСкладахОстатки.КоличествоОстаток, 0) КАК Количество
   ИЗ
       (ВЫБРАТЬ
           Номенклатура.Ссылка КАК Номенклатура
       ИЗ
           Справочник.Номенклатура КАК Номенклатура
       ГДЕ
           (НЕ Номенклатура.ПометкаУдаления)
           И (НЕ Номенклатура.ЭтоГруппа)
           И Номенклатура.Ссылка В ИЕРАРХИИ(&Группа)) КАК ВложенныйЗапрос
           ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки(&Дата, Склад = &Склад) КАК ТоварыНаСкладахОстатки
           ПО ВложенныйЗапрос.Номенклатура = ТоварыНаСкладахОстатки.Номенклатура) КАК ВложенныйЗапрос
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Обороты(&Дата1, &Дата2, , Склад = &Склад) КАК ТоварыНаСкладахОбороты
       ПО ВложенныйЗапрос.Номенклатура = ТоварыНаСкладахОбороты.Номенклатура

Выполняется около минуты за годовой период.

Посоветуйте пожалуйста как оптимизировать?

написан красиво по буквам, но г по исполнению - очевидно

Временные таблицы, индексы, пакетный запрос. И будет тебе счастье.

при выборке каждой записи делать рекурсивную выбору всех записей, а потом еще одну - это питерка, без базара

ппц а не запрос :)

слушай, может ты лучше скажешь, что ты хотел получить?

(0) Вложенные запросы это зло. Используй временные таблицы.

я думаю автор счас собереться и поступит как мужчина, т.е. внятно и искренне опишет постановку задачи, чо ото стесняцца - самое страшное позади - мелом уже посыпали, будем искать оптиму

ВЫБРАТЬ
   Номенклатура.Ссылка КАК Номенклатура
ПОМЕСТИТЬ СпрНоменклатура
ИЗ
   Справочник.Номенклатура КАК Номенклатура
ГДЕ
   (НЕ Номенклатура.ПометкаУдаления)
   И (НЕ Номенклатура.ЭтоГруппа)
   И Номенклатура.Ссылка В ИЕРАРХИИ(&Группа)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ТоварыНаСкладахОстатки.Номенклатура,
   ТоварыНаСкладахОстатки.КоличествоОстаток,
   ТоварыНаСкладахОбороты.КоличествоПриход,
   ТоварыНаСкладахОбороты.КоличествоРасход
ИЗ
   РегистрНакопления.ТоварыНаСкладах.Остатки(
           &Дата,
           Склад = &Склад
               И Номенклатура В
                   (ВЫБРАТЬ
                       СпрНоменклтура.Номенклатура
                   ИЗ
                       СпрНоменклтура)) КАК ТоварыНаСкладахОстатки
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Обороты(
               &Дата1,
               &Дата2,
               ,
               Склад = &Склад
                   И Номенклатура В
                       (ВЫБРАТЬ
                           СпрНоменклтура.Номенклатура
                       ИЗ
                           СпрНоменклтура)) КАК ТоварыНаСкладахОбороты
       ПО ТоварыНаСкладахОстатки.Номенклатура = ТоварыНаСкладахОбороты.Номенклатура

+(8) Это я исхожу из того, что реально нужен остаток на Одну &Дата, а оборот за друго

(0)
Дело не во вложенных запросах - в них ничего плохого не вижу.
А вот конкретно данный запрос неоптимален по следующей причине.
Я так понимаю, надо выбрать остатки из РН по заданному критерию. Зачем в памяти соединять всю таблицу остатков с номенклатурой, а потом отбирать нужные записи по условиям.
Можно выполнить единственную выборку из виртуальной таблицы остатков с параметрами. Тогда с сервера вернется уже отфильтрованная таблица.

й период &Дата1 и &Дата2
Нужны данные только по тем товарам, которые имеют и остаток и оборот.

(10) Можно выполнить единственную выборку из виртуальной таблицы остатков с параметрами. Тогда с сервера вернется уже отфильтрованная таблица.

тут немного подробнее если можно.

(8) на производительности не сказалось - примерно то же время.

(13) Если ты смотршь на 10 номенклатурах и на базе с 100 документов, то ты и не заметишь разницы :)

(7) задача - заполнить документ товаром, который двигался по определенному складу, в течении заданного периода, и заполнить остатком этого товара на сегодняшний день.

(15) Зачем тогда отбор по группе номенклатуры? А если остаток имеет помеченный на удаление товар?
Вообще же, с этой точки зрения запрос из (8) оптимален. Разве что поля оборота можно убрать, если они не нужны.

(14) :).. несколько больше.. раз в 100..

(17) 1000 номенклатуры м 10000 документов? Тоже не так много. увеличь ещё в 10-100 раз, тогда увидишь разницу :)

(16) отбор по группе нужен. Если помечен - то не попадет в документ. Не спорю.. Оборот нельзя убирать - нужны именно те позиции которые участвовали в обороте.

(18) может с базой какой косяк.. но твой запрос все еще выполняется..

(15) "двигался по определённому складу" - подойдёт абсолютно любое движение? Может быть имеет смысл использовать не вирутальную таблицу оборотов, а реальную таблицу регистра. Даст ещё прирост производительности.

(21) спасибо за идею попробую

(12)
Что-то типа вот этого:
ВЫБРАТЬ
  Таб....
ИЗ РегистрНакопления.ТоварыНаСкладах.Остатки(&Дата, Склад = &Склад и НЕ Номенклатура.ПометкаУдаления и ......) как Таб

ВЫБРАТЬ
   Номенклатура.Ссылка КАК Номенклатура
ПОМЕСТИТЬ СпрНоменклатура
ИЗ
   Справочник.Номенклатура КАК Номенклатура
ГДЕ
   (НЕ Номенклатура.ПометкаУдаления)
   И (НЕ Номенклатура.ЭтоГруппа)
   И Номенклатура.Ссылка В ИЕРАРХИИ(&Группа)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ТоварыНаСкладахОстатки.Номенклатура,
   ТоварыНаСкладахОстатки.КоличествоОстаток
ИЗ
   РегистрНакопления.ТоварыНаСкладах.Остатки(
           &Дата,
           Склад = &Склад
               И Номенклатура В
                   (ВЫБРАТЬ
                       СпрНоменклтура.Номенклатура
                   ИЗ
                       СпрНоменклтура)) КАК ТоварыНаСкладахОстатки
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
           ТоварыНаСкладах.Номенклатура КАК Номенклатура
       ИЗ
           РегистрНакопления.ТоварыНаСкладах КАК ТоварыНаСкладах
       ГДЕ
           ТоварыНаСкладах.Период МЕЖДУ &Дата1 И &Дата2
           И ТоварыНаСкладах.Склад = &Склад
           И ТоварыНаСкладах.Номенклатура В
                   (ВЫБРАТЬ
                       СпрНоменклатура.Номенклатура
                   ИЗ
                       СпрНоменклатура)) КАК ДвиженияТоваров
       ПО ТоварыНаСкладахОстатки.Номенклатура = ДвиженияТоваров.Номенклатура

(2) Временные таблицы, индексы, пакетный запрос. И будет тебе счастье.

А куда в (8) можно воткнуть индекс?

(0) нет

(26) :) зачетный пост

(25) В первом запросе, где получается СпрНоменклатура можно проиндексировать по "Номенклатура". Если номенклатур много, должен дать хороший выигрыш.

вложенные запросы - это гомнокод

(0) А чем не катит таблица ОстаткиИОбороты?

(30) правая граница периода оборота и дата среза остатка разные

(31) И какой в этом смысл?

(24) вообще махом отработало - только дубли.. попытка применить "РАЗЛИЧНЫЕ" к вложенному запросу привела опять к зависону

(29) +100 Но лучше выразить вежливее "Вложенные запросы проходилось применять до появления временных таблиц"

(32) показывает человеку товар, который он раньше продавал (ну или хотя бы возил с места на место) а сейчас этого товара нет

(23) Где-то слышал что соединение работает быстрее чем отбор

(29) вложенные запросы воще не надо использовать? или есть иногда смысл?

(33) Ну попробуй так... В порядке бреда:

ВЫБРАТЬ
   ТоварыНаСкладахОстатки.Номенклатура,
   ТоварыНаСкладахОстатки.КоличествоОстаток
ИЗ
   РегистрНакопления.ТоварыНаСкладах.Остатки(
           &Дата,
           Склад = &Склад
               И Номенклатура В
                   (ВЫБРАТЬ
                       ТоварыНаСкладах.Номенклатура КАК Номенклатура
                   ИЗ
                       РегистрНакопления.ТоварыНаСкладах КАК ТоварыНаСкладах
                   ГДЕ
                       ТоварыНаСкладах.Период МЕЖДУ &Дата1 И &Дата2
                       И ТоварыНаСкладах.Склад = &Склад
                       И ТоварыНаСкладах.Номенклатура В
                           (ВЫБРАТЬ
                               Номенклатура.Ссылка
                           ИЗ
                               Справочник.Номенклатура КАК Номенклатура
                           ГДЕ
                               (НЕ Номенклатура.ПометкаУдаления)
                               И (НЕ Номенклатура.ЭтоГруппа)
                               И Номенклатура.Ссылка В ИЕРАРХИИ (&Группа)))) КАК ТоварыНаСкладахОстатки

(37) имхо вообще не стоит

(35) Ну а остатки-то зачем? Там ведь левое соединение, так что выйдет вся номенклатура (она слева) вне зависимости от того, есть остатки по ней или нет.

запрос из РегистрНакопления.ТоварыНаСкладах во временную таблицу + различные
А потом внутреннее соединение с остатками

попробуй нормально отладить запрос со вложенными

(37) Вот тут много высказались про вложенные запросы. однако вариант (24), используя вложенные запросы показал наивысшую производительность
+ применил совет (28) - вообще взлетело все!

(0) Дурдом на колесах )))
Зачем там остатки, потом остатки и обороты, почему не взять только из оборотов, условие на номенклатуру тоже можно засунуть в параметры виртуальной таблицы.
А здесь горе от ума какое-то:
Две таблицы Номенклатура и ОстаткиИОбороты и будет счастье...

В ИТОГЕ (Отрабатывает за пару секунд):

ВЫБРАТЬ
   Номенклатура.Ссылка КАК Номенклатура
ПОМЕСТИТЬ СпрНоменклатура
ИЗ
   Справочник.Номенклатура КАК Номенклатура
ГДЕ
   (НЕ Номенклатура.ПометкаУдаления)
   И (НЕ Номенклатура.ЭтоГруппа)
   И Номенклатура.Ссылка В ИЕРАРХИИ(&Группа)

ИНДЕКСИРОВАТЬ ПО
   Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
   ТоварыНаСкладахОстатки.Номенклатура,
   ТоварыНаСкладахОстатки.КоличествоОстаток
ИЗ
   РегистрНакопления.ТоварыНаСкладах.Остатки(
           &Дата,
           Склад = &Склад
               И Номенклатура В
                   (ВЫБРАТЬ
                       СпрНоменклатура.Номенклатура
                   ИЗ
                       СпрНоменклатура)) КАК ТоварыНаСкладахОстатки
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
           ТоварыНаСкладах.Номенклатура КАК Номенклатура
       ИЗ
           РегистрНакопления.ТоварыНаСкладах КАК ТоварыНаСкладах
       ГДЕ
           ТоварыНаСкладах.Период МЕЖДУ &Дата1 И &Дата2
           И ТоварыНаСкладах.Склад = &Склад
           И ТоварыНаСкладах.Номенклатура В
                   (ВЫБРАТЬ
                       СпрНоменклатура.Номенклатура
                   ИЗ
                       СпрНоменклатура)) КАК ДвиженияТоваров
       ПО ТоварыНаСкладахОстатки.Номенклатура = ДвиженияТоваров.Номенклатура

(39) почему? если нужно просто сделать несколько преобразований текущих данныхперед дальнейшим соединением, это можно сделать в одной временной таблицы с вложенными запросами, а в другой соединиться

(45) Ну а если на &Дата остатков нужного товара нет, а обороты по нему есть?

(39) Обоснуй. (42) - за обоснование не катит. Консоль запросов в зубы и вперёд.

(48) +100500, пофиг как что отлаживать. Конструктором редко пользуюсь

(49) А на коструктор ты зря. Пользуюсь всегда. Даже если что-то редактирую руками, апосля конструктором форматирую.

можно во временную сразу затащить данные из РегистрНакопления.ТоварыНаСкладах КАК ТоварыНаСкладах
должно еще пошустрее быть

Может я крамольную мысль скажу, но я всегда считал, что Временная таблица нужна в том случае, если её результат я собираюсь использовать несколько раз (более одного). В остальных случаях она не лучше и не хуже обычного вложенного запроса. Я не прав?

(48) Временные таблицы фирма 1С сделала именно для замены вложенных запросов. Причин несколько. Навскидку:

1. Гораздо менее требовательны к ресурсам (уход от вылетов из-за нехватки памяти, например).

2. Позволяет выполнять оптимизацию (врем. таб. можно индексировать, например).

3. Код становится "плоским". Т.е. видно - вот этот запрос выполняет отдельное действие и помещает в врем. таблицу. И из-за этого потом переделывать весь запрос становится легче. Читать его легче. Это и называется "легче отлаживать".

Я, конечно, понимаю - есть люди, к-рые скажут : "А я уже миллион лет пользуюсь вл. зап. и так навострился это делать"... Но это ущербная логика. Вот я когда-то был очень не хилым спецов по Clipper, и что теперь ? Всю жизнь на нем писать ?

(52) Я свидетель - имел вылеты по памяти, когда вложенный запрос использовался ровно один раз. После перехода на ВТ вылеты пропали и возросла скорость...

(52) не прав. Вложенные таблицы не содержат индекса. При соединении может быть не оптимально выбран план выполнения запроса. Плюс есть тема, что оптимизатор не считает количество записей во вложенной таблице, что тоже сказывается на план выполнения запроса

(53) Вообще от вложенных таблиц в принципе можно отказаться...