надо найти документы РТиУ в которых номенклатура принадлежит одной и групп.
а именно надо найти РТиУ в которых есть хотя бы 1 позиция из группы "ручки" и хотя бы 1 позиция из группы "карандаши", причем если есть только ручки или только карандаши то эти документы не должны попадать в отчет.
а еще сложность в том, что количество групп выбирается пользователем от 1го до 5ти.
у кого есть какие-нибудь соображения?

надо писать запрос!

напишу за 500р

блин, клоунада понеслались раньше чем обычно

ну раз ты все разгадал - я удаляюсь

По количеству выбранных пользователем групп прилепить к основной таблице документа левые джойны таблицы номенклатуры документа с условием что-то типа
<Имя_ОсновнойТаблицы>.Ссылка = <Имя_Таблицы_Номенклатуры_i>.Ссылка
И <Имя_Таблицы_Номенклатуры_i>.Номенклатура В ИЕРАРХИИ(&ВыбраннаяГруппа_i)

а дальле проверять на NULL Имя_Таблицы_Номенклатуры_i.Ссылка

(0) а что ты уже сам сделал для решения этой неимоверно сложной задачи?

Запрос в цикле по каждой из групп? Это неправильно, но работать будет

(6) я сделал вот так
ВЫБРАТЬ РАЗРЕШЕННЫЕ
   ТоварыЧека.Ссылка КАК Чек,
   ТоварыЧека.Продавец,
   ТоварыЧека.Ссылка.Магазин КАК Салон,
   СУММА(ТоварыЧека.Количество) КАК КоличествоПервойГруппы
ПОМЕСТИТЬ ЧекиСПервойГруппой
ИЗ
   Документ.ЧекККМ.Товары КАК ТоварыЧека
       ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК НоменГруппа1
       ПО ТоварыЧека.Номенклатура = НоменГруппа1.Ссылка
ГДЕ
   ТоварыЧека.Ссылка.Проведен
   И ТоварыЧека.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон
   И НоменГруппа1.НоменклатурнаяГруппа = &НоменклатурнаяГруппаПервая

СГРУППИРОВАТЬ ПО
   ТоварыЧека.Ссылка,
   ТоварыЧека.Продавец,
   ТоварыЧека.Ссылка.Магазин
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
   ТоварыЧека.Ссылка КАК Чек,
   ТоварыЧека.Продавец,
   ТоварыЧека.Ссылка.Магазин КАК Салон,
   СУММА(ТоварыЧека.Количество) КАК КоличествоВторойГруппы
ПОМЕСТИТЬ ЧекиСоВторойГруппой
ИЗ
   Документ.ЧекККМ.Товары КАК ТоварыЧека
       ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК НоменГруппа2
       ПО ТоварыЧека.Номенклатура = НоменГруппа2.Ссылка
ГДЕ
   ТоварыЧека.Ссылка.Проведен
   И ТоварыЧека.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон
   И НоменГруппа2.НоменклатурнаяГруппа = &НоменклатурнаяГруппаВторая

СГРУППИРОВАТЬ ПО
   ТоварыЧека.Ссылка,
   ТоварыЧека.Продавец,
   ТоварыЧека.Ссылка.Магазин
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
   ЧекиСоВторойГруппой.Чек КАК КоличествоЧеков,
   ЧекиСоВторойГруппой.Продавец,
   ЧекиСоВторойГруппой.Салон
ИЗ
   ЧекиСоВторойГруппой КАК ЧекиСоВторойГруппой
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ЧекиСПервойГруппой КАК ЧекиСПервойГруппой
       ПО ЧекиСоВторойГруппой.Чек = ЧекиСПервойГруппой.Чек


но оказалось что групп может быть несколько

а меня еще клоуном называл, двоечник

(5) сказано, что если в документе есть только "карандаши" то этот док выводить не нужно.
(9) прости, готов выслушать твоё решение задачи

+9 открой для себя В ИЕРАРХИИ и параметр - список значений к примеру

+11 или просто В (&Список)

(11) если я в списке укажу 2 группы, то в результат получу док в котором может быть только 1 номенклатура из 1ой группы, а мне надо только из 2х, 3х и т.д.

(13) построитель отчета или скд + их параметры тогда в руки

иначе - собирать текст запроса динамически

(14) у меня скд. какие параметры брать в руки?

(10) сказано, а дальле проверять на NULL Имя_Таблицы_Номенклатуры_i.Ссылка и в зависимости от результата включать/исключать строки из результата запроса. делается с помощью ГДЕ

а теперь я подумал - а ведь запрос динамически придется собирать )
ибо даже построитель будет сравнивать со всем списком ))

(17) если ты про это
ВЫБРАТЬ РАЗРЕШЕННЫЕ
   ТоварыЧека.Ссылка КАК Чек,
   ТоварыЧека.Продавец,
   ТоварыЧека.Ссылка.Магазин КАК Салон
ИЗ
   Документ.ЧекККМ.Товары КАК ТоварыЧека
       ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК НоменГруппа1
       ПО ТоварыЧека.Номенклатура = НоменГруппа1.Ссылка
       ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК НоменГруппа2
       ПО ТоварыЧека.Номенклатура = НоменГруппа2.Ссылка

ГДЕ
   ТоварыЧека.Ссылка.Проведен
   И ТоварыЧека.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон
   И НоменГруппа1.НоменклатурнаяГруппа = &НоменклатурнаяГруппаПервая
   И НоменГруппа2.НоменклатурнаяГруппа = &НоменклатурнаяГруппаВторая
то результат будет пустой.
если условие делать ИЛИ по группам, то опять попадёт не то что нужно (только карандаши из требуемых карандаши+ручки)

(18) как димамически?

(20) пока чтото там
      текстзапроса = текстзапроса + "что то здесь"

потому как надо получить типа
выбрать поместить НГ1 из номенклатура где НГ = ПараметрНГ1;
...
выбрать из документы внутреннее соединение НГ1  по
...

(22) держи пятихатку

сделал вот так
ВЫБРАТЬ РАЗРЕШЕННЫЕ
   НоменклатурныеГруппы.Ссылка КАК Группа
ПОМЕСТИТЬ Группы
ИЗ
   Справочник.НоменклатурныеГруппы КАК НоменклатурныеГруппы
ГДЕ
   НоменклатурныеГруппы.Ссылка В(&СписокГрупп)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   КОЛИЧЕСТВО(РАЗЛИЧНЫЕ Группы.Группа) КАК Количество
ПОМЕСТИТЬ КоличествоГрупп
ИЗ
   Группы КАК Группы
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
   Чеки.Ссылка,
   Группы.Группа
ПОМЕСТИТЬ ЧекиСГруппой
ИЗ
   Документ.ЧекККМ.Товары КАК Чеки
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Группы КАК Группы
       ПО Чеки.Номенклатура.НоменклатурнаяГруппа = Группы.Группа
ГДЕ
   Чеки.Ссылка.Проведен
   И Чеки.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон

СГРУППИРОВАТЬ ПО
   Группы.Группа,
   Чеки.Ссылка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
   ЧекиСГруппой.Ссылка КАК Чек
ИЗ
   ЧекиСГруппой КАК ЧекиСГруппой
       ЛЕВОЕ СОЕДИНЕНИЕ КоличествоГрупп КАК КоличествоГрупп
       ПО (ИСТИНА)

СГРУППИРОВАТЬ ПО
   ЧекиСГруппой.Ссылка,
   КоличествоГрупп.Количество

ИМЕЮЩИЕ
   КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ЧекиСГруппой.Группа) = КоличествоГрупп.Количество
вроде работает