Помогите, пожалуйста!

Надо вытащить спецификации проданных номенклатур, которые были основными на дату продажи.
Запрос следующий

ВЫБРАТЬ
   ПродажиОбороты.Номенклатура КАК Номенклатура,
   ПродажиОбороты.КоличествоОборот КАК Количество,
   ПродажиОбороты.СтоимостьОборот КАК Стоимость,
   ПродажиОбороты.ДокументПродажи.Дата
ИЗ
   РегистрНакопления.Продажи.Обороты КАК ПродажиОбороты
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ОсновныеСпецификацииНоменклатуры.СрезПоследних(&Дата) КАК ОсновныеСпецификацииНоменклатурыСрезПоследних
       ПО ПродажиОбороты.Номенклатура = ОсновныеСпецификацииНоменклатурыСрезПоследних.Номенклатура


Как мне вместо параметра &Дата указать дату продажи?
Если ставлю СрезПоследних(ПродажиОбороты.ДокументПродажи.Дата)  - дает ошибку

(0) бегом в КЗ, читать классическую "Срез последних на каждую дату"

уже там

(1) хотя для СКД есть прием передачи периода в связанный набор через параметр:
http://1cskd.ru/2010/10/srez-poslednix-na-kazhduyu-datu-v-skd/

спасибо, кажется то что надо

возник еще один вопрос.  
Получился пакетный запрос из 5 запросов
Все, вроде как, работает, но почему-то исчезают записи для которых не найдена цена продажи, хотя везде стоит левое соединение (это последние два запроса в пакете)
Где ошибка , помогите найти

ВЫБРАТЬ
   ПродажиОбороты.Период КАК ДатаПродажи,
   ПродажиОбороты.Номенклатура КАК Номенклатура,
   СУММА(ПродажиОбороты.КоличествоОборот) КАК Количество,
   СУММА(ПродажиОбороты.СтоимостьОборот) КАК Стоимость
ПОМЕСТИТЬ втБезСпецификации
ИЗ
   РегистрНакопления.Продажи.Обороты(&НачалоПериода, &КонецПериода, День, ) КАК ПродажиОбороты
ГДЕ
   НЕ ПродажиОбороты.Номенклатура В ИЕРАРХИИ (&НоменклатураГруппы)

СГРУППИРОВАТЬ ПО
   ПродажиОбороты.Период,
   ПродажиОбороты.Номенклатура

ИНДЕКСИРОВАТЬ ПО
   Номенклатура,
   ДатаПродажи
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   втБезСпецификации.ДатаПродажи КАК ДатаПродажи,
   втБезСпецификации.Номенклатура КАК Номенклатура,
   втБезСпецификации.Количество,
   втБезСпецификации.Стоимость,
   МАКСИМУМ(СпецификацииНоменклатуры.Период) КАК Период
ПОМЕСТИТЬ втМаксПериод
ИЗ
   втБезСпецификации КАК втБезСпецификации
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ОсновныеСпецификацииНоменклатуры КАК СпецификацииНоменклатуры
       ПО втБезСпецификации.Номенклатура = СпецификацииНоменклатуры.Номенклатура
           И втБезСпецификации.ДатаПродажи >= СпецификацииНоменклатуры.Период

СГРУППИРОВАТЬ ПО
   втБезСпецификации.ДатаПродажи,
   втБезСпецификации.Номенклатура,
   втБезСпецификации.Количество,
   втБезСпецификации.Стоимость

ИНДЕКСИРОВАТЬ ПО
   Номенклатура,
   ДатаПродажи,
   Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   втМаксПериод.ДатаПродажи КАК ДатаПродажи,
//    втМаксПериод.Номенклатура КАК Комплект,
   втМаксПериод.Количество* СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК Количество,
//    СпецификацииНоменклатуры.СпецификацияНоменклатуры КАК СпецификацииНоменклатуры,
   ВЫРАЗИТЬ(СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура как Справочник.Номенклатура) КАК Номенклатура
ПОМЕСТИТЬ втБезЦены    
ИЗ
   втМаксПериод КАК втМаксПериод
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ОсновныеСпецификацииНоменклатуры КАК СпецификацииНоменклатуры
           ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
           ПО СпецификацииНоменклатуры.СпецификацияНоменклатуры = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка
       ПО втМаксПериод.Номенклатура = СпецификацииНоменклатуры.Номенклатура
           И втМаксПериод.Период = СпецификацииНоменклатуры.Период
           
ГДЕ
   СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура В ИЕРАРХИИ(&НоменклатураГруппы)
СГРУППИРОВАТЬ ПО
   втМаксПериод.ДатаПродажи,
//    втМаксПериод.Номенклатура,
//    СпецификацииНоменклатуры.СпецификацияНоменклатуры,
   ВЫРАЗИТЬ(СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура как Справочник.Номенклатура),
   втМаксПериод.Количество* СпецификацииНоменклатурыИсходныеКомплектующие.Количество

ИНДЕКСИРОВАТЬ ПО
   Номенклатура,
   ДатаПродажи    
;

////////////////////////////////////////////////////////////////////////////////
   


ВЫБРАТЬ
   втБезЦены.ДатаПродажи КАК ДатаПродажи,
   втБезЦены.Номенклатура КАК Номенклатура,
   втБезЦены.Количество,
   МАКСИМУМ(ЦеныНоменклатуры.Период) КАК Период
ПОМЕСТИТЬ втМаксПериодЦен
ИЗ
   втБезЦены КАК втБезЦены
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
       ПО втБезЦены.Номенклатура = ЦеныНоменклатуры.Номенклатура
           И втБезЦены.ДатаПродажи >= ЦеныНоменклатуры.Период

СГРУППИРОВАТЬ ПО
   втБезЦены.ДатаПродажи,
   втБезЦены.Номенклатура,
   втБезЦены.Количество
   
ИНДЕКСИРОВАТЬ ПО
   Номенклатура,
   ДатаПродажи,
   Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   втМаксПериодЦен.ДатаПродажи,
   втМаксПериодЦен.Номенклатура,
   втМаксПериодЦен.Количество,
   ЦеныНоменклатуры.Цена
ИЗ
   втМаксПериодЦен КАК втМаксПериодЦен
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
       ПО втМаксПериодЦен.Номенклатура = ЦеныНоменклатуры.Номенклатура
           И втМаксПериодЦен.Период = ЦеныНоменклатуры.Период
ГДЕ
   ЦеныНоменклатуры.ТипЦен = &ТипЦен

(5)ГДЕ
   ЦеныНоменклатуры.ТипЦен = &ТипЦен

спасибо