создаю себе справочник фотографий. реквизит один - Фото - типа ХЗ. Но никак не могу показать на форме. Что делаю не так?

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
   об=РеквизитФормыВЗначение("Объект");
   ЭтаФорма.Фото=Новый Картинка(об.Фото.Получить());
   Элементы.ПолеФото.КартинкаЗначений=Новый Картинка(об.Фото.Получить());
КонецПроцедуры


Фото - реквизит формы типа картинка. Последняя строка вообще не отрабатывает: Недопустимое значение. Хотя слева и справа картинки. об.Фото.Получить() в отладчике показывает некие двоичные данные. Что делаю не так?

+(0) вроде с декорацией то же выходит..

ты открой демо-конфу "УП" - там всё на пальцах

(2) УТ11 открывал. пришёл к выводу, что для добавления фото номенклатуры, его нужно предварительно в справочник файлов засунуть. а там как-то не очень прозрачно. плюнул и пошёл спать ;)
УП - это что?

демо-конфа "Управляемое приложение". если украли, могу свой вариант выложить

(4) на ИТСе есть? вчера искал что-то демо, но эту не нашёл

ясно, короче. это не из демки, это мой тестовый пример

у справочника есть реквизит "Изображение1" типа ХЗ (не путать с х.з. ;-) )
на форме два текстовых реквизита: ИмяФайлаКартинки и Картинка
в Поле картинки устанавливаем ПутьКДанным="Каринка"\

код:

&НаСервере
Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)
   
   Если ЭтоАдресВременногоХранилища(Картинка) Тогда
       //изменяли картинку, надо сохранить
       ХЗ=Новый ХранилищеЗначения(ПолучитьИзВременногоХранилища(Картинка));
       ТекущийОбъект.Изображение1=ХЗ;
   КонецЕсли;
КонецПроцедуры

&НаСервере
Функция ЭтоАдресХран(АдресХран)
   Возврат ЭтоАдресВременногоХранилища(АдресХран);
КонецФункции
   
&НаКлиенте
Процедура ПолеКартинкиНажатие(Элемент, СтандартнаяОбработка)
   
   СтандартнаяОбработка = Ложь;
   
   Если Не ЗначениеЗаполнено(Объект.Ссылка) Тогда
       ТекстВопроса = НСтр("ru='Для выбора изображения необходимо записать объект. Записать?'");
       Ответ = Вопрос(ТекстВопроса, РежимДиалогаВопрос.ДаНет);
       Если Ответ = КодВозвратаДиалога.Да Тогда
           Записать();
       Иначе
           Возврат
       КонецЕсли;
   КонецЕсли;
   
   Если ЗначениеЗаполнено(Объект.Ссылка) Тогда
       ИдентификаторФайла = Новый УникальныйИдентификатор;
       Фильтр = НСтр("ru = 'Все картинки (*.bmp;*.gif;*.png;*.jpeg;*.dib;*.rle;*.tif;*.jpg;*.ico;*.wmf;*.emf)|*.bmp;*.gif;*.png;*.jpeg;*.dib;*.rle;*.tif;*.jpg;*.ico;*.wmf;*.emf"
                                   + "|Все файлы(*.*)|*.*"
                                   + "|Формат bmp(*.bmp*;*.dib;*.rle)|*.bmp;*.dib;*.rle"
                                   + "|Формат GIF(*.gif*)|*.gif"
                                   + "|Формат JPEG(*.jpeg;*.jpg)|*.jpeg;*.jpg"
                                   + "|Формат PNG(*.png*)|*.png"
                                   + "|Формат TIFF(*.tif)|*.tif"
                                   + "|Формат icon(*.ico)|*.ico"
                                   + "|Формат метафайл(*.wmf;*.emf)|*.wmf;*.emf'");
       Если ПодключитьРасширениеРаботыСФайлами() Тогда
           ВыборФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
           ВыборФайла.МножественныйВыбор = Ложь;
           ВыборФайла.Заголовок = НСтр("ru = 'Выбор файла'");
           ВыборФайла.Фильтр = Фильтр;
           Если ЗначениеЗаполнено(ИмяФайлаКартинки) Тогда
               ВыборФайла.ПолноеИмяФайла=ИмяФайлаКартинки;
           КонецЕсли;
       
           РезВыбора=ВыборФайла.Выбрать();
           Если РезВыбора Тогда
               ИмяФайлаКартинки=ВыборФайла.ПолноеИмяФайла;
               Если ЭтоАдресХран(Картинка) Тогда
                   АдресХран=Картинка;
               Иначе
                   АдресХран="";
               КонецЕсли;
               АдресХран="";
               ПоместитьФайл(АдресХран,ИмяФайлаКартинки,,Ложь,ЭтаФорма.УникальныйИдентификатор);
               Картинка=АдресХран;
               ЭтаФорма.Элементы.ПолеКартинки.Обновить();
               ЭтаФорма.Модифицированность=1;
           КонецЕсли;
       КонецЕсли;
   КонецЕсли;
   
КонецПроцедуры

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
   Картинка=ПолучитьНавигационнуюСсылку(Объект.Ссылка,"Изображение1");
КонецПроцедуры



короче, разбирайся, я, есличо - сваливаю, у меня по графику - велопробег

(6) >Поле картинки устанавливаем ПутьКДанным
кажется, здесь ответ. спасибо, читаю

разобрался, но не до конца. в частности, открываю форму существующего элемента, гружу новое изображение (изменение поля картинки видны), сразу пытаюсь сохранить - сохраняется "прошлая" картинка. и это несмотря на то, что объект предварительно записываю. что я недоучёл?


&НаКлиенте
Процедура Загрузить(Команда)
   Перем Адрес, Имя;
   
   Диалог=Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
   Диалог.МножественныйВыбор=Ложь;
   Диалог.Фильтр=ПолучитьФильтрИзображений();
   Если Диалог.Выбрать() Тогда
       ПоместитьФайл(Адрес, Диалог.ПолноеИмяФайла, , Ложь, УникальныйИдентификатор);
       Картинка=Адрес;
       Если ПустаяСтрока(Объект.Наименование) Тогда
           Объект.Наименование=ИзвлечьИмяБезРасширения(Диалог.ПолноеИмяФайла);
       КонецЕсли;
       Модифицированность=Истина;
   КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура Сохранить(Команда)
   //Если Вопрос("Перед действием объект необходимо записать. Продолжить?", РежимДиалогаВопрос.ДаНет)=КодВозвратаДиалога.Да Тогда
   Если Истина Тогда
       ЗаписатьОбъект();
       Диалог=Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);
       Диалог.Фильтр=ПолучитьФильтрИзображений();
       Если Диалог.Выбрать() Тогда
           Адрес=СохранитьСрв();
           ПолученнаяКартинка=Новый Картинка(ПолучитьИзВременногоХранилища(Адрес));
           //ПолученнаяКартинка=Элементы.ПолеФото.КартинкаЗначений;
           ПолученнаяКартинка.Записать(Диалог.ПолноеИмяФайла);
       КонецЕсли;
   КонецЕсли;
КонецПроцедуры

&НаСервере
Процедура ЗаписатьОбъект()
   об=РеквизитФормыВЗначение("Объект");
   об.Записать();
   ЗначениеВРеквизитФормы(об, "Объект");
КонецПроцедуры

&НаСервере
Функция СохранитьСрв()
   Возврат ПоместитьВоВременноеХранилище(РеквизитФормыВЗначение("Объект").Фото.Получить(), УникальныйИдентификатор);
КонецФункции

&НаСервере
Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)
   Если ЭтоАдресВременногоХранилища(Картинка) Тогда
       ТекущийОбъект.Фото=Новый ХранилищеЗначения(ПолучитьИзВременногоХранилища(Картинка));
   КонецЕсли;
КонецПроцедуры


а вот если вместо ЗаписатьОбъект(); записать по кнопке (стандартной), всё отрабатывает, как нужно. как так я не так записываю?

есть МГ от гилева как работать с картинками, кинь письмо мне на мыло, кину ссылку

(11) кинул.

у меня как-то запись объекта не отрабатывает имхо:
&НаСервере
Процедура ЗаписатьОбъект()
   об=РеквизитФормыВЗначение("Объект");
   об.Записать();
   ЗначениеВРеквизитФормы(об, "Объект");
КонецПроцедуры

(9) в (6) абсолютно работающий готовый код. можно тупо скопипастить, и всё

(12) для чего этот код?

(13) у тебя там загрузка, загрузку я победил, я "выдернуть" не могу. точнее, если последовательность действий, при котором вытаскивается не то.
(14) это я сохраняю то, что есть в памяти (в объекте) в базу с тем, чтобы потом из объекта вытащить картинку, отдать клиенту и сохранить на его диске.

спасибо Web00001, файл принял, буду изучать

(15) а, ясно, я в "сразу пытаюсь сохранить " интерпретировал "сохранить" как "записать элемент"

(15) " это я сохраняю то, что есть в памяти (в объекте) в базу с тем, чтобы потом из объекта вытащить картинку"

нахрена?  если ты её только что качнул - она у тебя в ВХ, бери её прямо оттуда, зачем огород городить? да и запись элемента при _извлечении_ картинки - это моветон, имхо

я, кстати, вообще не стал заморачиваться с кнопкой сохранения картинки - а нафига, если есть штатное ПКМ\сохранить как?

а я понял, наверное, в чём твоя проблема - ты про Обновить() забыл

(17) согласен про моветон, это у меня уже танцы с бубном. она у меня не всегда во ВХ - сразу после открытия её туда никто не положил.
(18) гыгы, не видел. тогда является особенностью интерфейса, кнопку сохранить себе шлём лесом ;)
(19) да вроде нет

с учётом (18) объявляю форму работающей, займусь изучением ХЗ, картинков и иже с ними. всем спасибо