Добрый день!
Почему вот так не работает:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки,  СтандартнаяОбработка)
   ДокументРезультат.ФиксацияСверху = 20;
   ДокументРезультат.ФиксацияСлева = 1;
   
   
КонецПроцедуры

СтандартнаяОбработка = Ложь;

и тогда все программно надо выводить? ((

может поможет))) http://www.buh.ru/forum/thread.jsp?id=562464&print=1&sortt=m.left_ns

я делал примерно так:



Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
   
   СтандартнаяОбработка = Ложь;
   
   Настройки = КомпоновщикНастроек.Настройки;

   Для Каждого ЭлементОтбора Из Настройки.Отбор.Элементы Цикл
       
       
       ПользовательскаяНастройка = КомпоновщикНастроек.ПользовательскиеНастройки.Элементы.Найти(ЭлементОтбора.ИдентификаторПользовательскойНастройки);    
       
       Если ПользовательскаяНастройка <> Неопределено Тогда
           ЭлементОтбора.ВидСравнения   = ПользовательскаяНастройка.ВидСравнения;                
           ЭлементОтбора.ПравоеЗначение = ПользовательскаяНастройка.ПравоеЗначение;    
           ЭлементОтбора.Использование  = ПользовательскаяНастройка.Использование;                
       КонецЕсли;    
       
   КонецЦикла;
   
   Для Каждого Параметр Из Настройки.ПараметрыДанных.Элементы Цикл
       
       ПользовательскаяНастройка = КомпоновщикНастроек.ПользовательскиеНастройки.Элементы.Найти(Параметр.ИдентификаторПользовательскойНастройки);    
       
       Если ПользовательскаяНастройка <> Неопределено Тогда
           Параметр.Значение        = ПользовательскаяНастройка.Значение;                
           Параметр.Использование   = ПользовательскаяНастройка.Использование;                
       КонецЕсли;    
       
   КонецЦикла;
   
   КомпановщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
   МакетКомпоновки = КомпановщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки);
   
   ПроцессорКомпановки = Новый ПроцессорКомпоновкиДанных;
   ПроцессорКомпановки.Инициализировать(МакетКомпоновки);
   
   ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
   ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
   
   ПроцессорВывода.НачатьВывод();
   
   ВыведенаШапка = Ложь;
   
   ЭлементРезультата = ПроцессорКомпановки.Следующий();
   
   Пока Не ЭлементРезультата = Неопределено Цикл
       
       Если Не ВыведенаШапка И ЭлементРезультата.ЗначенияПараметров.Количество() > 0 Тогда
           
           ВыведенаШапка = Истина;
           ДокументРезультат.ФиксацияСверху = ДокументРезультат.ВысотаТаблицы;
           
       КонецЕсли;    
       
       ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
       ЭлементРезультата = ПроцессорКомпановки.Следующий();
       
   КонецЦикла;
   
   ДокументРезультат.ФиксацияСлева = СхемаКомпоновкиДанных.НастройкиПоУмолчанию.Структура.Количество();
   
   ПроцессорВывода.ЗакончитьВывод();
   
КонецПроцедуры

(4)расшифровка соответственно тоже должна быть описана

(4)спасибо, все получилось)

Еще вопрос. Что-то в книжке не найти никак. А как программно свернуть все группировки, чтобы при формировании отчета все плюсики скрыты были?