Всем привет.
Столкнулся с такой задачей.
Есть рабочая конфигурация. В ней ведется учет продаж с нескольких складов. Нужно ДЛЯ КАЖДОГО склада вывести 3 таких дня, когда оборот (сумма продаж) были максимальные.
Вроде тривиально до ужаса, но я уже полчаса сижу и не могу построить запрос...

Я совсем тупой?

(1) это провокация?

на каждый день оборот можешь получить? упорядочить по сумме тоже можешь? взять первые три сумеешь?

каким образом группировать периоды по три дня?

можно согласиться =)

(3)
Ты рассказываешь как получить первые 3 для одного склада, а если их 20?
Пример можешь показать?

(4)Да поодному сгруппируй, а потом отсортируПервый 3

*отсортируй по убыванию

(7)
Как? Не могу понять? Мне для кадого склада подзапрос рисовать?
Так в подзапросе к тому же нельзя упорядочивать

(9)Медитируй.

http://www.google.ru/search?as_sitesearch=forum.mista.ru&q=итоги+на+каждый+день&sei=wNpzUPOrErTb4QScuICQCw&gbv=2

(0) 3 подряд.... или любые 3 ?

(10)
Не врубаюсь нафиг мне это надо

(11)
3 максимальные для каждого склада.

То есть если складов 15, то вывод отчета должен быть длиной в 45 строк

(12)Ну уж если ты не врубаешься нафиг оно тебе, что про остальных то говорить:-)

Бросай все, езжай на Карибы

Я бы делала примерно так: Выбрать все обороты по всем складам на каждый день, упорядочить по сумме, сделать итоги по каждому складу. Обходить результат запроса по группировкам и во вложенном цикле выводить первые 3 строки, а потом этот цикл прерывать.

Задача из цикла срез последних руками

(1)[Я совсем тупой?]
угу

или динамически строящийся запрос (по количеству складов) состоящий из подзапросов по очередному складу, объединенных через "Объединить все"

Компоновка умеет выводить первые N записей

это задача ранжирования

(17) Ты так заявлешь, буд-то у тебя есть решение.

Запрос в цикле!!! По каждому складу находим максимум, исключаем, находим максимум, исключаем и т.п. Все выводим в табличку.

Выгрузить запрос в ТЗ, свернуть ТЗ по складам, отсортировать ТЗ по сумме, выбрать первые 3 значения.

Короче, накатал от нечего делать

ВЫБРАТЬ
   ПродажиОбороты.Склад,
   ПродажиОбороты.СтоимостьОборот,
   ПродажиОбороты.Период
ПОМЕСТИТЬ ПродажиВсе
ИЗ
   РегистрНакопления.Продажи.Обороты(&Дата1, &Дата2, День, ) КАК ПродажиОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ПродажиВсе.Склад,
   МАКСИМУМ(ПродажиВсе.СтоимостьОборот) КАК СтоимостьОборот
ПОМЕСТИТЬ Максимум1День
ИЗ
   ПродажиВсе КАК ПродажиВсе

СГРУППИРОВАТЬ ПО
   ПродажиВсе.Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ПродажиВсе.Склад,
   МАКСИМУМ(ПродажиВсе.СтоимостьОборот) КАК СтоимостьОборот
ПОМЕСТИТЬ Максимум2День
ИЗ
   ПродажиВсе КАК ПродажиВсе
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Максимум1День КАК Максимум1День
       ПО (Максимум1День.Склад = ПродажиВсе.Склад)
           И (Максимум1День.СтоимостьОборот > ПродажиВсе.СтоимостьОборот)

СГРУППИРОВАТЬ ПО
   ПродажиВсе.Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ПродажиВсе.Склад,
   МАКСИМУМ(ПродажиВсе.СтоимостьОборот) КАК СтоимостьОборот
ПОМЕСТИТЬ Максимум3День
ИЗ
   ПродажиВсе КАК ПродажиВсе
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Максимум2День КАК Максимум2День
       ПО (Максимум2День.Склад = ПродажиВсе.Склад)
           И (Максимум2День.СтоимостьОборот > ПродажиВсе.СтоимостьОборот)

СГРУППИРОВАТЬ ПО
   ПродажиВсе.Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Максимум1День.Склад КАК Склад,
   Максимум1День.СтоимостьОборот КАК Сумма,
   МАКСИМУМ(ПродажиВсе.Период) КАК Период
ИЗ
   Максимум1День КАК Максимум1День
       ЛЕВОЕ СОЕДИНЕНИЕ ПродажиВсе КАК ПродажиВсе
       ПО (ПродажиВсе.Склад = Максимум1День.Склад)
           И (ПродажиВсе.СтоимостьОборот = Максимум1День.СтоимостьОборот)

СГРУППИРОВАТЬ ПО
   Максимум1День.Склад,
   Максимум1День.СтоимостьОборот

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   Максимум2День.Склад,
   Максимум2День.СтоимостьОборот,
   МАКСИМУМ(ПродажиВсе.Период)
ИЗ
   Максимум2День КАК Максимум2День
       ЛЕВОЕ СОЕДИНЕНИЕ ПродажиВсе КАК ПродажиВсе
       ПО (ПродажиВсе.Склад = Максимум2День.Склад)
           И (ПродажиВсе.СтоимостьОборот = Максимум2День.СтоимостьОборот)

СГРУППИРОВАТЬ ПО
   Максимум2День.Склад,
   Максимум2День.СтоимостьОборот

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   Максимум3День.Склад,
   Максимум3День.СтоимостьОборот,
   МАКСИМУМ(ПродажиВсе.Период)
ИЗ
   Максимум3День КАК Максимум3День
       ЛЕВОЕ СОЕДИНЕНИЕ ПродажиВсе КАК ПродажиВсе
       ПО (ПродажиВсе.Склад = Максимум3День.Склад)
           И (ПродажиВсе.СтоимостьОборот = Максимум3День.СтоимостьОборот)

СГРУППИРОВАТЬ ПО
   Максимум3День.Склад,
   Максимум3День.СтоимостьОборот

УПОРЯДОЧИТЬ ПО
   Сумма УБЫВ
ИТОГИ ПО
   Склад

вот, держите:


ВЫБРАТЬ
   "А" КАК Склад,
   1 КАК Период,
   3 КАК Сумма
ПОМЕСТИТЬ Данные

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "А",
   2,
   7

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "А",
   3,
   4

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "А",
   4,
   5

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "А",
   5,
   6
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Данные.Склад,
   Данные.Период,
   Данные.Сумма
ПОМЕСТИТЬ ДанныеА
ИЗ
   Данные КАК Данные
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Данные.Склад,
   Данные.Период,
   Данные.Сумма
ИЗ
   Данные КАК Данные
ГДЕ
   Данные.Период В
           (ВЫБРАТЬ ПЕРВЫЕ 2
               ДанныеА.Период
           ИЗ
               ДанныеА КАК ДанныеА
           ГДЕ
               ДанныеА.Склад = Данные.Склад
           УПОРЯДОЧИТЬ ПО
               ДанныеА.Сумма УБЫВ)


единственное - передачу количества первых записей не сделать руками

(26)+ вернее сделать, но это надо нумеровать таблицу по периодам в разрезе складов в порядке увеличения суммы, что долго

ну и промежуточная таблица не нужна

(25) Прикольно :)
С такиими условиями во вложенных запросах еще не работал

(22) Запрос в цикле - ай-яй-яй, зачем людей плохому учите?

Ну что получилось?

(31) конечно, (25) же работает

Я вот такую вещь предлагаю, просто вместо склада - организация(для простоты). Можно и под склад переделать.

<code>
ВЫБРАТЬ
   ПродажиОбороты.Организация КАК Организация,
   ПродажиОбороты.СтоимостьОборот,
   ПродажиОбороты.Период КАК Период
ПОМЕСТИТЬ ПерваяПродажи
ИЗ
   РегистрНакопления.Продажи.Обороты(&ДатаНач, &ДатаКонца, День, ) КАК ПродажиОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ПерваяПродажи.Организация,
   МАКСИМУМ(ПерваяПродажи.СтоимостьОборот) КАК СтоимостьОборот
ПОМЕСТИТЬ ПерваяВыборкаБезДат
ИЗ
   ПерваяПродажи КАК ПерваяПродажи

СГРУППИРОВАТЬ ПО
   ПерваяПродажи.Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ПерваяПродажи.Организация,
   ПерваяПродажи.СтоимостьОборот
ПОМЕСТИТЬ ВтораяБезОбработки
ИЗ
   ПерваяПродажи КАК ПерваяПродажи
ГДЕ
   НЕ ПерваяПродажи.СтоимостьОборот В
               (ВЫБРАТЬ
                   ПерваяВыборкаБезДат.СтоимостьОборот
               ИЗ
                   ПерваяВыборкаБезДат КАК ПерваяВыборкаБезДат)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВтораяБезОбработки.Организация,
   МАКСИМУМ(ВтораяБезОбработки.СтоимостьОборот) КАК СтоимостьОборот
ПОМЕСТИТЬ ВтораяВыборкаБезДат
ИЗ
   ВтораяБезОбработки КАК ВтораяБезОбработки

СГРУППИРОВАТЬ ПО
   ВтораяБезОбработки.Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ПерваяВыборкаБезДат.Организация КАК Организация,
   ПерваяВыборкаБезДат.СтоимостьОборот
ПОМЕСТИТЬ ПерваяИВтораяБезДат
ИЗ
   ПерваяВыборкаБезДат КАК ПерваяВыборкаБезДат

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   ВтораяВыборкаБезДат.Организация,
   ВтораяВыборкаБезДат.СтоимостьОборот
ИЗ
   ВтораяВыборкаБезДат КАК ВтораяВыборкаБезДат
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ПерваяПродажи.Организация,
   ПерваяПродажи.СтоимостьОборот
ПОМЕСТИТЬ ТретьяБезОбработки
ИЗ
   ПерваяПродажи КАК ПерваяПродажи
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ТретьяБезОбработки.Организация,
   МАКСИМУМ(ТретьяБезОбработки.СтоимостьОборот) КАК СтоимостьОборот
ПОМЕСТИТЬ ТретьяВыборкаБезДат
ИЗ
   ТретьяБезОбработки КАК ТретьяБезОбработки
ГДЕ
   НЕ ТретьяБезОбработки.СтоимостьОборот В
               (ВЫБРАТЬ
                   ПерваяИВтораяБезДат.СтоимостьОборот
               ИЗ
                   ПерваяИВтораяБезДат КАК ПерваяИВтораяБезДат)

СГРУППИРОВАТЬ ПО
   ТретьяБезОбработки.Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ПерваяИВтораяБезДат.Организация КАК Организация,
   ПерваяИВтораяБезДат.СтоимостьОборот
ПОМЕСТИТЬ Предпоследняя
ИЗ
   ПерваяИВтораяБезДат КАК ПерваяИВтораяБезДат

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   ТретьяВыборкаБезДат.Организация,
   ТретьяВыборкаБезДат.СтоимостьОборот
ИЗ
   ТретьяВыборкаБезДат КАК ТретьяВыборкаБезДат
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Предпоследняя.Организация КАК Организация,
   Предпоследняя.СтоимостьОборот КАК СтоимостьОборот,
   ПерваяПродажи.Период
ИЗ
   ПерваяПродажи КАК ПерваяПродажи
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Предпоследняя КАК Предпоследняя
       ПО ПерваяПродажи.Организация = Предпоследняя.Организация
           И ПерваяПродажи.СтоимостьОборот = Предпоследняя.СтоимостьОборот

УПОРЯДОЧИТЬ ПО
   Организация,
   СтоимостьОборот УБЫВ
</code>

(33) жесть

Блин, и не ожидал такого нетривиального решения)

(35) мой вариант попробовал?

(36)
Да не, я уже дома.
Открыл мисту и офигел)

(0) Получить обороты по дням, отсортировать их по убыванию, потом ВЫБРАТЬ ПЕРВЫЕ 3

Иль не то?

(38)
ПО КАЖДОМУ СКЛАДУ
не то

Предлагаю так. При данном подходе можно указать количество дат с максимальными продажами для каждого склада. Вместо суммы продаж использовано КоличествоРасход.

<code>
ВЫБРАТЬ
   ТоварыНаСкладахОбороты.КоличествоРасход,
   ТоварыНаСкладахОбороты.Период,
   ТоварыНаСкладахОбороты.Склад
ПОМЕСТИТЬ ВТОборотыНесортированные
ИЗ
   РегистрНакопления.ТоварыНаСкладах.Обороты(, , День, {(Номенклатура).* КАК Номенклатура}) КАК ТоварыНаСкладахОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТОборотыНесортированные1.Склад,
   ВТОборотыНесортированные1.КоличествоРасход,
   ВТОборотыНесортированные.Период
ПОМЕСТИТЬ ВТОборотыСоединение
ИЗ
   ВТОборотыНесортированные КАК ВТОборотыНесортированные
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТОборотыНесортированные КАК ВТОборотыНесортированные1
       ПО ВТОборотыНесортированные.Склад = ВТОборотыНесортированные1.Склад
           И ВТОборотыНесортированные.КоличествоРасход <= ВТОборотыНесортированные1.КоличествоРасход
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТОборотыСоединение.Склад,
   ВТОборотыСоединение.КоличествоРасход,
   КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ВТОборотыСоединение.Период) КАК ПорядокСуммы
ПОМЕСТИТЬ ВТОборотыСПорядкамиСумм
ИЗ
   ВТОборотыСоединение КАК ВТОборотыСоединение

СГРУППИРОВАТЬ ПО
   ВТОборотыСоединение.Склад,
   ВТОборотыСоединение.КоличествоРасход
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТОборотыСПорядкамиСумм.Склад,
   МАКСИМУМ(ВТОборотыСПорядкамиСумм.ПорядокСуммы) КАК ПорядокСуммы
ПОМЕСТИТЬ ВТОборотыСМаксимальнымПорядкомДляКаждогоСклада
ИЗ
   ВТОборотыСПорядкамиСумм КАК ВТОборотыСПорядкамиСумм

СГРУППИРОВАТЬ ПО
   ВТОборотыСПорядкамиСумм.Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТОборотыСПорядкамиСумм.Склад,
   ВТОборотыСПорядкамиСумм.КоличествоРасход
ПОМЕСТИТЬ ВТОборотыНужныеСуммы
ИЗ
   ВТОборотыСПорядкамиСумм КАК ВТОборотыСПорядкамиСумм
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТОборотыСМаксимальнымПорядкомДляКаждогоСклада КАК ВТОборотыСМаксимальнымПорядкомДляКаждогоСклада
       ПО ВТОборотыСПорядкамиСумм.Склад = ВТОборотыСМаксимальнымПорядкомДляКаждогоСклада.Склад
ГДЕ
   ВТОборотыСМаксимальнымПорядкомДляКаждогоСклада.ПорядокСуммы - ВТОборотыСПорядкамиСумм.ПорядокСуммы < 3
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТОборотыНужныеСуммы.Склад,
   ВТОборотыНужныеСуммы.КоличествоРасход,
   ВТОборотыНесортированные.Период
ИЗ
   ВТОборотыНужныеСуммы КАК ВТОборотыНужныеСуммы
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТОборотыНесортированные КАК ВТОборотыНесортированные
       ПО ВТОборотыНужныеСуммы.Склад = ВТОборотыНесортированные.Склад
           И ВТОборотыНужныеСуммы.КоличествоРасход = ВТОборотыНесортированные.КоличествоРасход
</code>