Подскажите как в 1С пределить с чего начинается строка с цифры или буквы, есть ли такая функция?

код символа определи для начала

нет, но можно написать

(0) Число() не предлагать?

а функции такой нет

Функция называется "Лев", а что считать цифрой или буквой - это твое дело

(3) навеяло..
Если СтрДлина(Строка(ч))=1 Тогда //проверка на <10

(6) это я вчера китайский код изучал. термин такой в смысле

(6) Реально было на мисте - Найти(Число,"-")>0 - проверка на отрицательность

(3) спасибо, должно взлететь!

(8) реально было пару дней назад. ресурсы у регистра: Размер42, Размер44...

(10) матьь

(9) то есть, автор всё-таки выбрал китайский путь...

(9) одна беда, через попытку нужно делать.

(8)
А че, нормально

Симв = Лев(Стр,1);
ЭтоБуква = (НРег(Симв)<>ВРег(Симв));

+(10) а, не, не пару. наверное, в писькомерной ветке отметилась. v8: Запрос. Упорядочивание по артикулу

(15) интересный вариант ;)

ну или Найти("0123456789", Лев(Стр,1) = 0

(15) не прокатит для знаков препинания и т.п. правда

Ну знак препинания он и не буква :)

лев() + КодСимвола >= 48 И КодСимвола <= 57

(19) это только для букв
правад слышал, что в грузинском прописных букв нет

(21) алилуйя!

+(1)

(22) есть ;) но в других языках, возможно нет.

(15) Сам бы до такого не додумался))) очень интересный вариант

(21) а можно немного расшифровать? что за 48, 57? КодСимвола?

(21) Настоящий 1С-ник соорудит конструкцию Если (Лев(Стр,1)="0") Или (Лев(Стр,1)="1")... И т.д. :))

(27) цифры

код цифер

(27) от 0 до 9 цифры, видимо ;)

(28) настоящий индус)

ы, цифЕр

(32) китаец. различай понятия

+(34) http://lurkmore.to/Индусский_код#K.D0.B8.D1.82.D0.B0.D0.B9.D1.81.D0.BA.D0.B8.D0.B9_.D0.BA.D0.BE.D0.B4

Функция НачинаетсяСЦифры(Парам)

   Запрос = Новый Запрос("ВЫБРАТЬ 1 ГДЕ &Парам ПОДОБНО ""[0-9]%""");
   Запрос.УстановитьПараметр("Парам", Парам);
   
   Возврат НЕ Запрос.Выполнить().Пустой();

КонецФункции // НачинаетсяСЦифры()

(36) понеслось...

Ребята вообщем написал по первому символу по коду (15), но это не фонтан, т.к. есть один косяк!!!

Если строка имеет такое значение "315Матрац", то по логике кода - это тоже будет цифра)))) а надо отмониторить, чтобы всё в строке были цифрами... сейчас имею след код:

Если КодСимвола(СтрПолучитьСтроку(строка, 2), 1) >= 48 И КодСимвола(СтрПолучитьСтроку(строка, 2), 1) <= 57 Тогда
           НоваяСтрока.Серия = "Цифра!"    
           КонецЕсли;

используй китайскую(по классификации чуть выше) методику:

Если КодСимвола(СтрПолучитьСтроку(строка, 2), 2) >= 48 И КодСимвола(СтрПолучитьСтроку(строка, 2), 2) <= 57 Тогда
           НоваяСтрока.Серия = "Цифра!"    
           КонецЕсли;

Если КодСимвола(СтрПолучитьСтроку(строка, 2), 3) >= 48 И КодСимвола(СтрПолучитьСтроку(строка, 2), 2) <= 57 Тогда
           НоваяСтрока.Серия = "Цифра!"    
           КонецЕсли;
Если КодСимвола(СтрПолучитьСтроку(строка, 2), 3) >= 48 И КодСимвола(СтрПолучитьСтроку(строка, 2), 1) <= 57 Тогда
           НоваяСтрока.Серия = "Цифра!"    
           КонецЕсли;

И тд

в последнем копипасте ошибка :(

и во втором. ну идея понятна

и в первом
да блин, как я умудрился

ЭтоЧисло = Ложь;
НомерСимвола = 1;
Пока Не ЭтоЧисло Цикл
   Если КодСимвола(Строка, НомерСимвола) > =48 и КодСимвола(Строка, НомерСимвола) <= 57 Тогда
       ЭтоЧисло = Истина;
   Иначе
       Прервать;
   КонецЕсли;
   НомерСимвола = НомерСимвола + 1;
КонецЦикла;

ДлинаСтроки = СтрДлина(Строка);
Для НомерСимвола = 1 По ДлинаСтроки Цикл
   Если КодСимвола(Строка, НомерСимвола) > =48 и КодСимвола(Строка, НомерСимвола) <= 57 Тогда
       // Что там тебе нужно сделать ;)
   КонецЕсли;
КонецЦикла;

Общий модуль ОбщегоНазначения

Функция ЕстьНеЦифрыВСтроке(Знач СтрокаПроверки) Экспорт
   
   Для а = 1 По СтрДлина(СтрокаПроверки) Цикл
       КодСимвола = КодСимвола(Сред(СтрокаПроверки, а, 1));
       Если НЕ (КодСимвола >= 48 И КодСимвола <= 57) Тогда
           Возврат Истина;
       КонецЕсли;
   КонецЦикла;

   Возврат Ложь;
   
КонецФункции


(45) Писатели общего модуля не читают СП на предмет параметров КодСимвола!

Функция ТолькоЦифры(Парам)

   RegExp = Новый COMОбъект("VBScript.RegExp");
   RegExp.Pattern = "^[0-9]+$";
   
   Возврат RegExp.test(Парам);

КонецФункции // ТолькоЦифры()

СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Число,"0",""),"1",""),"2",""),"3",""),"4",""),"5",""),"6",""),"7",""),"8",""),"9","") = ""

(48) охтвоюжмать :D

(48) в цикле для по будет красивее :Р

(48) и еще, косяк.. ведь надо убирать только первые цифры, а не в середине или где-то еще ;)

(51)
Читай (38)

(46) этточно
(47) клёвый подход, уважаю =)

(52) ну фиг знает, я понял что только первые, тут нас рассудит только ТС :)

Спасибо ребята)) информации предостаточно)

кушойте не обляпуйтесь - все рабочее

мини-лексический анализатор на 1С вчера напсало для просморта ВТ, удаления ВТ из Пакетов, и пр., хотя ему по фик с чем работать и мне плевать на вопли "можно красивше"

а на фига красивше?


//
// Add_ComM_ОтчетыКС.СтрокаБукв_Ru();
//
Функция СтрокаБукв_Ru() Экспорт
   Возврат "АБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЫЬЪЭЮЯ";
КонецФункции
//
// Add_ComM_ОтчетыКС.Буква_Ru(С);
//
Функция Буква_Ru(С) Экспорт
   Возврат Найти(СтрокаБукв_Ru(), ВРег(С)) <> 0;
КонецФункции

//
// Add_ComM_ОтчетыКС.СтрокаБукв_En();
//
Функция СтрокаБукв_En() Экспорт
   Возврат "ABCDEFGHIJKLMNOPQRSTUVWXYZ";
КонецФункции
//
//Add_ComM_ОтчетыКС.Буква_En(С);
//
Функция Буква_En(С) Экспорт
   Возврат Найти(СтрокаБукв_En(), ВРег(С)) <> 0;    
КонецФункции

//
// Add_ComM_ОтчетыКС.СтрокаЦифр();
//
Функция СтрокаЦифр() Экспорт
   Возврат "0123456789";
КонецФункции
//
//Add_ComM_ОтчетыКС.Цифра(С);
//
Функция Цифра(С) Экспорт
  Возврат Найти(СтрокаЦифр(), ВРег(С)) <> 0;
КонецФункции

//
//Add_ComM_ОтчетыКС.Буква_Ru_ИлиБуква_En(С);
//
Функция Буква_Ru_ИлиБуква_En(С) Экспорт
   Возврат Найти(СтрокаБукв_Ru()+СтрокаБукв_En(), ВРег(С)) <> 0;
КонецФункции

//
//Add_ComM_ОтчетыКС.Буква_Ru_ИлиБуква_En_ИлиЦифра(С);
//
Функция Буква_Ru_ИлиБуква_En_ИлиЦифра(С) Экспорт
   Возврат Найти(СтрокаБукв_Ru()+СтрокаБукв_En()+СтрокаЦифр(), ВРег(С)) <> 0;
КонецФункции
 

//
//Add_ComM_ОтчетыКС.ПолучитьДлинуИдВСтрокеСПозиции(СтрокаСимволов, НачПозИд);
//
Функция ПолучитьДлинуИдВСтрокеСПозиции(СтрокаСимволов, НачПозИд, ШаблонПоиска) Экспорт

   ИсходнаяНачПоз = НачПозИд;
   Если ИсходнаяНачПоз <= СтрДлина(СтрокаСимволов) Тогда
       ПредшествующийСимвол = Сред(СтрокаСимволов, ИсходнаяНачПоз-1, 1);
       ПредшествующийСимволБуква_Ru_ИлиБуква_En_Или_ = (Буква_Ru_ИлиБуква_En(ПредшествующийСимвол) ИЛИ ПредшествующийСимвол = "_");
   Иначе    
       ПредшествующийСимволБуква_Ru_ИлиБуква_En_Или_ = Ложь;
   КонецЕсли;
   
   Ид           = "";
   СтрокаДлина  = СтрДлина(СтрокаСимволов);
   
   Для ТекущаяПозиция = НачПозИд По СтрокаДлина Цикл
       
       ИдДлина  = СтрДлина(Ид);
       ТкСимвол = Сред(СтрокаСимволов, ТекущаяПозиция, 1);
       
       Если Найти(ШаблонПоиска, ВРег(ТкСимвол)) Тогда
           
           Если ИдДлина Тогда
               Ид = Ид + ТкСимвол;
           Иначе
               
               Если ПредшествующийСимволБуква_Ru_ИлиБуква_En_Или_ И ИсходнаяНачПоз = ТекущаяПозиция Тогда
                   Прервать;  // С первого же символа Ид происходит слияние со словом, которое содержит терм - это не Ид.
               КонецЕсли;
               
               Если Буква_Ru_ИлиБуква_En(ТкСимвол) ИЛИ ТкСимвол = "_" Тогда
                   НачПозИд = ТекущаяПозиция;    // Смещаем НачПозИд для первого сивола Ид, вероятно перед ней были пробелы
                   Ид = Ид + ТкСимвол;
               Иначе    
                   Прервать;  // В первом же символе Ид цифра - это ошибка написания идентификатора
               КонецЕсли;
           КонецЕсли;
           
       Иначе
           
           Если ИдДлина Тогда
               Прервать;      // Ид уже содержит символы и текущий символ не в шаблоне, значит это конец Ид.          
           КонецЕсли;
           
       КонецЕсли;
       
   КонецЦикла;
   
   Возврат СтрДлина(Ид);
   
КонецФункции
 
//
// Варианты вызова:
//
// Add_ComM_ОтчетыКС.ПолучитьМассивИдВСтрокеПослеТермов(ЗапросТекст, "Поместить", Истина);  // имена временных таблиц запроса
// Add_ComM_ОтчетыКС.ПолучитьМассивИдВСтрокеПослеТермов(ЗапросТекст, "ПОМЕСТИТЬ", Истина);  // ...
//
// Add_ComM_ОтчетыКС.ПолучитьМассивИдВСтрокеПослеТермов(ЗапросТекст, "Уничтожить", Истина); // имена уничтожаемых временных таблиц запроса
// Add_ComM_ОтчетыКС.ПолучитьМассивИдВСтрокеПослеТермов(ЗапросТекст, "УНИЧТОЖИТЬ", Истина); // ...
//
// Add_ComM_ОтчетыКС.ПолучитьМассивИдВСтрокеПослеТермов(ЗапросТекст, "&", Истина);          // имена параметров запроса
//
// Add_ComM_ОтчетыКС.ПолучитьМассивИдВСтрокеПослеТермов(ЗапросТекст, "Поместить", Истина, Истина);
// В этом вызове получим массив ид с термами точно так как они сформированы в строке т.е.
// "ПОМЕСТИТЬ Вт1"
// "ПОМЕСТИТЬ    Вт2"
// ...
//
Функция ПолучитьМассивИдВСтрокеПослеТермов(Знач СтрокаСимволов, СтрокаТерма, Уникальные = Истина, ВключаяТерм = Ложь) Экспорт
   
   СтрокаСимволовИсходная = СтрокаСимволов;
   мИдентификаторы        = Новый Массив;
   
   СтрокаСимволовВРег = ВРег(СтрокаСимволов);
   СтрокаТермаВРег    = ВРег(СтрокаТерма);
   СтрокаТермаДлина   = СтрДлина(СтрокаТерма);
   
   // Находим позицию первого символа терма, далее с (НачПозИд + СтрокаТермаДлина) - это позиции поиска идентификатора
   НачПозТерма = Найти(СтрокаСимволовВРег, СтрокаТермаВРег);
   Если НачПозТерма Тогда
       НачПозИд = НачПозТерма + СтрокаТермаДлина;
   Иначе
       Возврат мИдентификаторы;
   КонецЕсли;  
   
   ШаблонПоиска = СтрокаБукв_Ru() + СтрокаБукв_En() + СтрокаЦифр();
   
   Пока НачПозИд Цикл
       
       ИдДлина = ПолучитьДлинуИдВСтрокеСПозиции(СтрокаСимволовВРег, НачПозИд, ШаблонПоиска);
       
       Если ИдДлина > 0 Тогда
           Ид = Сред(СтрокаСимволовИсходная, НачПозИд, ИдДлина);
           КонПозИд = НачПозИд + ИдДлина;
           Если ВключаяТерм Тогда
               ИдВключаяТерм = Сред(СтрокаСимволовИсходная, НачПозТерма, КонПозИд-НачПозТерма);
               Если Уникальные Тогда
                   Если мИдентификаторы.Найти(ИдВключаяТерм) = Неопределено Тогда
                       мИдентификаторы.Добавить(ИдВключаяТерм);
                   КонецЕсли;
               Иначе    
                   мИдентификаторы.Добавить(ИдВключаяТерм);
               КонецЕсли;
           Иначе    
               Если Уникальные Тогда
                   Если мИдентификаторы.Найти(Ид) = Неопределено Тогда
                       мИдентификаторы.Добавить(Ид);
                   КонецЕсли;
               Иначе    
                   мИдентификаторы.Добавить(Ид);
               КонецЕсли;
           КонецЕсли;
       КонецЕсли;
       
       Если КонПозИд >= СтрДлина(СтрокаСимволовИсходная) Тогда
           Прервать;
       КонецЕсли;
       
       // Сокращаем СтрокаСимволовИсходная и СтрокаСимволовИсходнаяВРег
       СтрокаСимволовИсходная = Сред(СтрокаСимволовИсходная, КонПозИд);
       СтрокаСимволовВРег     = Сред(СтрокаСимволовВРег    , КонПозИд);
       
       // Готовим следующую итерацию поска очередного Ид по терму
       НачПозТерма = Найти(СтрокаСимволовВРег, СтрокаТермаВРег);
       Если НачПозТерма Тогда
           НачПозИд = НачПозТерма + СтрокаТермаДлина;
       Иначе
           Прервать;  // Выход итак будет по условию итерации цикла, но выходим сразу
       КонецЕсли;  
       
   КонецЦикла;
   
   Возврат мИдентификаторы;
   
КонецФункции