Добрый день уважаемые форумчане.
Я в семерке плохо шарю, но некоторые моменты знаю.
к вам такая просьба.
мне нужно сделать отчет который выводит список контрагентов у которых одинаковый ИНН или не заполненный ИНН.
Вот мои наброски
//_____________________________________________________________________________
Функция ПоискКонтрагента(пПоиск)
   спрФиз = СоздатьОбъект("Справочник.ФизЛица");
   спрЮр = СоздатьОбъект("Справочник.ЮрЛица");
   спрСвои = СоздатьОбъект("Справочник.СвоиЮрЛица");
   Если спрФиз.НайтиПоНаименованию(пПоиск,0,1)=1 Тогда
       СпрЛица = спрФиз.ИНН;
       Возврат СпрЛица;
   ИначеЕсли спрЮр.НайтиПоНаименованию(пПоиск,0,1)=1 Тогда
       СпрЛица = спрЮр.ИНН;
       Возврат СпрЛица;
   ИначеЕсли спрСвои.НайтиПоНаименованию(пПоиск,0,1)=1 Тогда
       СпрЛица = спрСвои.ИНН;
       Возврат СпрЛица;
   Иначе
       Возврат 0;
   КонецЕсли;
КонецФункции //

//*******************************************
Процедура Сформировать()
   Таб=СоздатьОбъект("Таблица");
   Таб.ВывестиСекцию("Шапка");
   Таб.ТолькоПросмотр(1);
   Спр1 = СоздатьОбъект("Справочник.Контрагенты");
   Спр1.ВыбратьЭлементы();
   Пока Спр1.ПолучитьЭлемент() = 1 Цикл
       Если (Спр1.ЭтоГруппа() = 0) и (Спр1.ПометкаУдаления() = 0) Тогда
           Спр2 = СоздатьОбъект("Справочник.Контрагенты");
           Спр2.ВыбратьЭлементы();
           СпрЛица1 = ПоискКонтрагента(Спр1.ЮрФизЛицо);
           Если СпрЛица1 = "" Тогда
               Таб.ВывестиСекцию("Строка");
           Иначе
               Пока Спр2.ПолучитьЭлемент() = 1 Цикл
                   
                   Если (Спр2.ЭтоГруппа() = 0) и (Спр2.ПометкаУдаления() = 0) Тогда
                   
                       СпрЛица2 = ПоискКонтрагента(Спр2.ЮрФизЛицо);
                       Если СпрЛица1=СпрЛица2 Тогда
                           Таб.ВывестиСекцию("Строка");
                       КонецЕсли;
                   
           
                   КонецЕсли;
                         КонецЦикла;
           КонецЕсли;
       КонецЕсли;
   КонецЦикла;
   Таб.Показать();
КонецПроцедуры

как можно упрастить данный модуль? может как нибудь через запрос можно сделать? в 8ке я бы без проблем решил бы эту задачу...

"сами мы восьмерочники, СП украли, ЖКК сгорели - помогите кодом кто каким может..."©

инн = Справочник.Контрагенты.ИНН;
контра - Справочник.Контрагенты.ТекущийЭлемент;
Группировка ИНН;
Группировка Контра;

ЗАпрос = СоздатьОбъект("Запрос");
запрос.Выполнить(стрЗАпрос);
Пока запрос.Группировка(1) = 1 ЦИкл
 сообщить("ИНН = " + запрос.ИНН);
 Пока запрос.Группировка(2) = 1 Цикл
   сообщить("" + запрос.контра);
 КонецЦикла;
КонецЦикла;

где-то так.

(0) можно смело отправить его в топку.

(2) и твой тоже, у клиентосов нет ИНН, они есть у ЮрФизЛицо в типовом ТиСе..

(4) ну или так :-)
Я эти типовые не помню уже давно

(4) А где ты видишь, что это типовой ТиС?

(2)
такой не катит

(6) только в типовом ТиС/Комплексная есть справочники

 ФизЛица,ЮрЛица,СвоиЮрЛица

(7) см (3,4)

это типовая Комплексная

(10)
ну, самое тупое - перебор справочника клиентосы + складывание в ТЗ + свертка этой ТЗ по ИНН.
Более быстрое решение - прямой запрос.

(0) Пригласи СПЕЦИАЛИСТА СЕМЕРОЧНИКА!!!

(11) понятно что более быстрое решение это прямой запрос, но как его сформировать, вообще не пойму, вот интересно если ИННы одиноковые следует ли из этого что и ЮрФизЛицо одинаковые? вот это интересно, если так то модуль упрощается

(12) их просто у нас нету)

(13) вовсе нет.
Если что, ИНН может быть одинаковым, а КПП разным

и в типовых запросто наплодить клиентосов с одинаковым ИНН\КПП и с разными ЮрЛицами..

собственно, это постоянно делают, если ИНН одинаковый, КПП разный, или ИНН/Кпп одинаковый, а адреса клиентосов разные..

Примерно так
//*******************************************
Процедура Сформировать()
     
     
     Контр=СоздатьОбъект("Справочник.Контрагенты");      
     Сп1=СоздатьОбъект("СписокЗначений");
     Сп2=СоздатьОбъект("СписокЗначений");
     
     Контр.ВыбратьЭлементы();
     Пока Контр.ПолучитьЭлемент()=1 Цикл  
         Если  (Сп1.НайтиЗначение(Контр.ИНН)=0) и (Контр.ИНН<>"") Тогда
             Сп1.ДобавитьЗначение(Контр.ИНН,);
         ИНаче                                
             Сп2.ДобавитьЗначение(Контр.ИНН,);
         КонецЕсли;
     КонецЦикла;

     Контр.ВыбратьЭлементы();
     Пока Контр.ПолучитьЭлемент()=1 Цикл  
         Если  (Сп2.НайтиЗначение(Контр.ИНН)=0)Тогда
             Сообщить(Контр);
     КонецЦИкла;
     
КонецПроцедуры

Вернее так
//*******************************************

Процедура Сформировать()
     
     
     Контр=СоздатьОбъект("Справочник.Контрагенты");      
     Сп1=СоздатьОбъект("СписокЗначений");
     Сп2=СоздатьОбъект("СписокЗначений");
     
     Контр.ВыбратьЭлементы();
     Пока Контр.ПолучитьЭлемент()=1 Цикл  
         Если  (Сп1.НайтиЗначение(Контр.ИНН)=0) и (Контр.ИНН<>"") Тогда
             Сп1.ДобавитьЗначение(Контр.ИНН,);
         ИНаче                                
             Сп2.ДобавитьЗначение(Контр.ИНН,);
         КонецЕсли;
     КонецЦикла;

     Контр.ВыбратьЭлементы();
     Пока Контр.ПолучитьЭлемент()=1 Цикл  
         Если  (Сп2.НайтиЗначение(Контр.ИНН)<>0) или (Контр.ИНН="") Тогда
             Сообщить(Контр);
КонецЕсли;
     КонецЦИкла;
     
КонецПроцедуры

(19) нельзя обратиться на прямую к инн через справочник контрагенты

ИНН у тебя реквизит чего? =)

вариант уже предложили - загнать всех контров в таблицу, создать доп. поле с 1, заполнить его, свернуть и отсортировать
---
или можно выбирать по реквизиту, и, если в выборке больше одной строки или у онтра не заполнено инн - сувать в таблицу =)

(21)ИНН реквизит справочников "Справочник.ФизЛица"; "Справочник.ЮрЛица"; "Справочник.СвоиЮрЛица";
когда заполняем реквизит ЮрФизЛицо на форму автоматический притягивается инн "ЮрФизЛицо".
ИНН это не реквизит справочника контрагентый

(20) Ну обратись через юр лиц, какая разница.

Суть в том чтобы получить двойников используя два списка.

     Если  (Сп1.НайтиЗначение(Контр.ИНН)=0) Тогда
             Сп1.ДобавитьЗначение(Контр.ИНН,);
         ИНаче                                
             Сп2.ДобавитьЗначение(Контр.ИНН,);
         КонецЕсли;

Процедура Сформировать()
   Запрос = СоздатьОбъект("Запрос");
   ТекстЗапроса =
   "//{{ЗАПРОС(СпрК)
   |Клиент = Справочник.Клиенты.ТекущийЭлемент;
   |Наименование = Справочник.Клиенты.Наименование;
   |ИНН = Справочник.Клиенты.ИНН;
   |Телефон = Справочник.Клиенты.Телефон;
   |Рук = Справочник.Клиенты.Рук;
   |Группировка Клиент;
   |"//}}ЗАПРОС
   ;
   // Если ошибка в запросе, то выход из процедуры
   Если Запрос.Выполнить(ТекстЗапроса) = 0 Тогда
       Возврат;
   КонецЕсли;
   Таб = СоздатьОбъект("Таблица");
   Таб.ИсходнаяТаблица("Таблица");
   Таб.ВывестиСекцию("Заг");
   Таб.Опции(0,0,Таб.ВысотаТаблицы());
   ТЗК = СоздатьОбъект("ТаблицаЗначений");
   Запрос.Выгрузить(ТЗК,1,0);
   ТЗК.НоваяКолонка("Колво","Число");
   ТЗК.Заполнить(1,,,"Колво");
   
   ТЗК.Сортировать("Наименование");
//-------------------------------------
   Если поИНН=1 Тогда
       ТЗК.Сортировать("ИНН");
       ТЗВ = СоздатьОбъект("ТаблицаЗначений");
       ТЗК.Выгрузить(ТЗВ);
       ТЗВ.Свернуть("ИНН","Колво");
       Шап = "Дубли по ИНН";
       Таб.ВывестиСекцию("Шап");
       ТЗВ.ВыбратьСтроки();
       Пока ТЗВ.ПолучитьСтроку() = 1 Цикл
           Если ПустоеЗначение(ТЗВ.ИНН)=1 Тогда
               Продолжить;
           КонецЕсли;
           Если Найти(ТЗВ.ИНН,"*")>0 Тогда
               Продолжить;
           КонецЕсли;
           Если Найти(ТЗВ.ИНН,"-")>0 Тогда
               Продолжить;
           КонецЕсли;
           Если Найти(ТЗВ.ИНН,"_")>0 Тогда
               Продолжить;
           КонецЕсли;
           Если ТЗВ.Колво>1 Тогда
               Рекв = ТЗВ.ИНН;
               Колво = ТЗВ.Колво;
               Таб.ВывестиСекцию("Рекв");
               Стр =0;
               Если ТЗК.НайтиЗначение(Рекв, Стр, "ИНН")>0 Тогда
                   Для х=Стр По ТЗК.КоличествоСтрок() Цикл
                       ТЗК.ПолучитьСтрокуПоНомеру(х);
                       Если ТЗК.ИНН <> Рекв Тогда
                           Прервать;
                       КонецЕсли;
                       
                       Наименование = ТЗК.Наименование;
                       ИНН = ТЗк.ИНН;
                       Телефон = ТЗК.Телефон;
                       Рук = ТЗК.Рук;
                       Таб.ВывестиСекцию("Дубль");
                       
                   КонецЦикла;
               КонецЕсли;
               
           КонецЕсли;
       КонецЦикла;
   КонецЕсли;
//------------------------
   Таб.ТолькоПросмотр(1);
   Таб.Показать("Дубли Клиентов");
   
КонецПроцедуры

Процедура ОбработкаЯчейкиТаблицы(Значение,ФСо,Табл,Адрес) //(Док, СтандартнаяОбработка, Таблица,Адрес)
   ФСо=1;
   Если Значение.Вид() = "Клиенты" Тогда
       ФСо=0;
       Стр=0;
       СЗ = СоздатьОбъект("СписокЗначений");
       СЗ.ДобавитьЗначение(Значение, Значение);
       
       ТЗ = СоздатьОбъект("ТаблицаЗначений");
       
       НайтиСсылки(СЗ, ТЗ);
       
       Табл = СоздатьОбъект("Таблица");
       Табл.ИсходнаяТаблица("Ссылки");
       Табл.ВывестиСекцию("Заг");
       
       ТЗ.ВыбратьСтроки();
       Пока ТЗ.ПолучитьСтроку() = 1 Цикл
           Табл.ВывестиСекцию("ТЗ");
       КонецЦикла;
       
       Табл.ТолькоПросмотр(1);
       Табл.Показать("КП по клиенту");
   КонецЕсли;
КонецПроцедуры

поНаименованию=1;
поТелефону=1;
поИНН=1;

Спр = СоздатьОбъект("Справочник.Контрагенты");
Спр.ВыбратьЭлементы();
Пока Спр.ПолучитьЭлемент()=1 Цикл
 Если (Спр.ПометкаУдаления()=1) Или (Спр.ЭтоГруппа()=1) Тогда
    Продолжить;
 КонецЕсли;
 Если ПустоеЗначение(Спр.ЮрФизЛицо)=1 Тогда
   Сообщить("Клиентос "+Спр+" отсутствует ЮрФизЛицо");
   Продолжить;
 КонецЕсли;
 Если ПустоеЗначение(Спр.ЮрФизЛицо.ИНН)=1 Тогда
   Сообщить("Клиентос "+Спр+" отсутствует ИНН");
   Продолжить;
 КонецЕсли;

 ТЗ.НоваяСтрока();
 ТЗ.Клиентос = Спр.ТекущийЭлемент();
 ТЗ.ИНН = Спр.ЮрФизЛицо.ИНН;
 ТЗ.Служ = 1;
КонецЦикла;
ТЗ.Выгрузить(врТЗ);
врТЗ.Свернуть("ИНН","Служ");
врТЗ.Сортировать("-Служ");

дальше сам разберешься ?
там где Служ>=2 - дубли ИНН..
обходишь ТЗ и выгребаешь только тек, где в врТЗ.Служ> -имеешь самих клиентосов.

+

ТЗ = СоздатьОбъект("ТаблицаЗначений");
ТЗ.НоваяКолонка("Клиентос")
ТЗ.НоваяКолонка("ИНН")
ТЗ.НоваяКолонка("Служ","Число")

если операция одноразовая, то regprint + Excel тебе в помощь

(28) регпринт ?!
:)))

(28) RefPrint

(26), (27) Спасибо, постараюсь это проделать

(28),(30) че за операция?

(32) Ы!

(30) не поможет - она не выводит реквизиты с ЮрФизЛицо

//*******************************************
// Процедура генерации запроса Сформировать.
//
Процедура Сформировать()
   Перем Запрос, ТекстЗапроса, Таб;
   //Создание объекта типа Запрос
   Запрос = СоздатьОбъект("Запрос");
   ТекстЗапроса =
   "//{{ЗАПРОС(Сформировать)
   |ИНН = Справочник.ФизЛица.ИНН, Справочник.ЮрЛица.ИНН;
   |ТекущийЭлемент = Справочник.ЮрЛица.ТекущийЭлемент, Справочник.ФизЛица.ТекущийЭлемент;
   |Функция Сч = Счётчик();
   |Группировка ИНН;
   |Группировка ТекущийЭлемент;
   |"//}}ЗАПРОС
   ;
   // Если ошибка в запросе, то выход из процедуры
   Если Запрос.Выполнить(ТекстЗапроса) = 0 Тогда
       Возврат;
   КонецЕсли;

   // Подготовка к заполнению выходных форм данными запроса
   Таб = СоздатьОбъект("Таблица");
   Таб.ИсходнаяТаблица("Сформировать");
   // Заполнение полей "Заголовок"
   Таб.ВывестиСекцию("Заголовок");
   Состояние("Заполнение выходной таблицы...");
   Таб.Опции(0, 0, Таб.ВысотаТаблицы(), 0);
   Пока Запрос.Группировка(1) = 1 Цикл
       Если (Запрос.Сч = 1) И (ПустоеЗначение(Запрос.ИНН)=0) тогда
           //в группе 1 запись с таким инн и инн не пустое
           Продолжить;
       КонецЕсли;    
       // Заполнение полей ИНН
       Таб.ВывестиСекцию("ИНН");
       Пока Запрос.Группировка(2) = 1 Цикл
           // Заполнение полей ТекущийЭлемент
           Таб.ВывестиСекцию("ТекущийЭлемент");
       КонецЦикла;
   КонецЦикла;
   // Заполнение полей "Итого"
   Таб.ВывестиСекцию("Итого");
   // Вывод заполненной формы
   Таб.ТолькоПросмотр(1);
   Таб.Показать("Сформировать", "");
КонецПроцедуры

(34) а что мешает запустить refprint по спр ЮрФизЛица?

(36)
1. Там 2 справочника - ЮрЛица и ФизЛица
2. что это даст, когда нужны сами клиентосы ?

врТЗ.ВыбратьСтроки();
   Ном = 0;
   ИНН1="";
   Пока врТЗ.ПолучитьСтроку() = 1 Цикл
       Ном = Ном+1;
(37) к твоему коду добавил вот этот кусочек:    
   Если  врТЗ.Служ>=2 Тогда
           ПЕчНом = Ном;
           ПечКон = врТЗ.Клиентос;
           ПечИнн = врТЗ.ИНН;
           Таб.ВывестиСекцию("Строка");
           Если ИНН1 <>врТЗ.ИНН  Тогда
               Таб.ВывестиСекцию("СтрокаР");
           КонецЕсли;
       КонецЕсли;
       
       ИНН1 = врТЗ.ИНН;
   КонецЦикла;
Но прога ругается и пишет Поле агрегатного объекта не обнаружено (Клиентос) я может не то вывожу?

упс
(37) к твоему коду добавил вот этот кусочек:
врТЗ.ВыбратьСтроки();
   Ном = 0;
   ИНН1="";
   Пока врТЗ.ПолучитьСтроку() = 1 Цикл
       Ном = Ном+1;
   
   Если  врТЗ.Служ>=2 Тогда
           ПЕчНом = Ном;
           ПечКон = врТЗ.Клиентос;
           ПечИнн = врТЗ.ИНН;
           Таб.ВывестиСекцию("Строка");
           Если ИНН1 <>врТЗ.ИНН  Тогда
               Таб.ВывестиСекцию("СтрокаР");
           КонецЕсли;
       КонецЕсли;
       
       ИНН1 = врТЗ.ИНН;
   КонецЦикла;
Но прога ругается и пишет Поле агрегатного объекта не обнаружено (Клиентос) я может не то вывожу?

(39) не то.
нужно бегать по ТЗ и искать по ИНН в врТЗ, во  врТЗ только ИНН и их количество после свертки.

(40) я не могу понять что выдает колонка служ в врТЗ, это число повторов ИНН?

(41) какой догадливый.

(41) Спасибо большое!) все заработало!)
Оказывается клиентов с одинаковыми ИНН очень много, в большинстве случаев это филиалы

вот итоговый код
//*******************************************
Процедура Сформировать()      
   Таб=СоздатьОбъект("Таблица");
   Таб.ВывестиСекцию("Шапка");
   Таб.ТолькоПросмотр(1);    
   ТЗ = СоздатьОбъект("ТаблицаЗначений");
   ТЗ.НоваяКолонка("Клиентос");
   ТЗ.НоваяКолонка("ИНН");
   ТЗ.НоваяКолонка("Служ","Число");  
   
   врТЗ = СоздатьОбъект("ТаблицаЗначений");
   врТЗ.НоваяКолонка("Клиентос");
   врТЗ.НоваяКолонка("ИНН");
   врТЗ.НоваяКолонка("Служ","Число");
   
   Спр = СоздатьОбъект("Справочник.Контрагенты");
   Спр.ВыбратьЭлементы();
   Пока Спр.ПолучитьЭлемент()=1 Цикл
       Если (Спр.ПометкаУдаления()=1) Или (Спр.ЭтоГруппа()=1) Тогда
           Продолжить;
         КонецЕсли;
       Если ПустоеЗначение(Спр.ЮрФизЛицо)=1 Тогда
           Сообщить("Клиентос "+Спр+" отсутствует ЮрФизЛицо");
           Продолжить;
         КонецЕсли;
         Если ПустоеЗначение(Спр.ЮрФизЛицо.ИНН)=1 Тогда
           Сообщить("Клиентос "+Спр+" отсутствует ИНН");
           Продолжить;
         КонецЕсли;

     ТЗ.НоваяСтрока();
     ТЗ.Клиентос = Спр.ТекущийЭлемент();
     ТЗ.ИНН = Спр.ЮрФизЛицо.ИНН;
     ТЗ.Служ = 1;
   КонецЦикла;
   ТЗ.Выгрузить(врТЗ);
   врТЗ.Свернуть("ИНН","Служ");
   врТЗ.Сортировать("-Служ");
   врТЗ.ВыбратьСтроки();
   Ном = 0;
   ИНН1="";
   Пока врТЗ.ПолучитьСтроку() = 1 Цикл
       
       Если  врТЗ.Служ>=2 Тогда
           ТЗ.ВыбратьСтроки();
           Пока  ТЗ.ПолучитьСтроку() = 1 Цикл
               Если врТЗ.ИНН = ТЗ.ИНН Тогда
                   Ном = Ном+1;
                   ПЕчНом = Ном;
                   ПечКон = ТЗ.Клиентос;
                   ПечИнн = ТЗ.ИНН;
                   Таб.ВывестиСекцию("Строка");  
               КонецЕсли;
           КонецЦикла;
           
           Если ИНН1 <>врТЗ.ИНН  Тогда
               Таб.ВывестиСекцию("СтрокаР");
           КонецЕсли;
       КонецЕсли;
       
       ИНН1 = врТЗ.ИНН;
   КонецЦикла;
    Таб.Показать();
КонецПроцедуры

(44) Цикл в цикле? Оригинально.

ТЗ тоже бы нужно отсортировать по ИНН

и .. лучше бегать по ТЗ и делать НайтиЗначение в врТЗ.

(45) они не ищут легких путей

(47) а чем вам запросом то не нравится?

(49) прямым - нравится, черным - не получится

точнее рполучится, но долго

(50) да ладно. мой код в 35 работает. по крайней мере на тестовой базе все правильно сформировал

(52) :) И где там в коде клиентосы ?
Автору клиентосов нужно получить, а не ЮрЛица/ФизЛица.

(49) прямым не получается никак, он же у тебя в итоге никак не связан со спр контрагенты

(47) попробую так сделать после обеда

Могу написать, в одном черном запросе, вот только скорость запроса не гарантирую..

Задача быстродействия не стояла - поэтому молотит неспешно..
.
//*******************************************
Процедура Сформировать()
   ОчиститьОкноСообщений();
   Спр = СоздатьОбъект("Справочник.Контрагенты");
   Спр.ВыбратьЭлементы();
   Пока Спр.ПолучитьЭлемент() = 1
   Цикл
       Если Спр.ЭтоГруппа()=1
       Тогда
           Продолжить;
       КонецЕсли;
       ИсключаемыйКонтрагент = Спр.ЮрФизЛицо;
       Результат = 2;
       Результат = Результат -
                   глКонтрольУникальностиИНН(ИсключаемыйКонтрагент, СтрЗаменить(ИсключаемыйКонтрагент.ИНН,Симв(160),""), "ФизЛица")-
                   глКонтрольУникальностиИНН(ИсключаемыйКонтрагент, СтрЗаменить(ИсключаемыйКонтрагент.ИНН,Симв(160),""), "ЮрЛица");
       Если Результат <> 0
       Тогда
           СООБЩИТЬ("********************* ПРОБЛЕМА: "+ИсключаемыйКонтрагент.ИНН+" "+ИсключаемыйКонтрагент);
           //ОткрытьФорму(Спр.ТекущийЭлемент());
       КонецЕсли;        
   
   КонецЦикла;
КонецПроцедуры
.
//******************************************************************************
// возврат:
//   1 - успешно, нет дублей ИНН
//   0 - ошибка, есть дубли ИНН
//
Функция глКонтрольУникальностиИНН(ВыбКонтрагент, ИННКПП, ВидСправочника)
Экспорт    

   Если ПустоеЗначение(ИННКПП) = 1
   Тогда //допустимо неуказание ИНН,
         //ответственность за дубли клиентов - на пользователе
       Возврат 1;
   КонецЕсли;
   
   Результат = глКонтрольУникальностиИННSQLite(ВыбКонтрагент, ИННКПП, ВидСправочника);
   Если Результат <> -1
   Тогда //поиск прошел успешно
       Возврат Результат;
   КонецЕсли;

   тИНН = глПолучитьИНН(ИННКПП);
   тКПП = глПолучитьКПП(ИННКПП);
   
   Запрос = СоздатьОбъект("Запрос");
   ТекстЗапроса ="
   |Без Итогов;
   |Элемент = Справочник.*.ТекущийЭлемент;
   |ИНН     = Справочник.*.ИНН;
   |Условие(Найти(ИНН,ИННКПП)>0);
   |Группировка Элемент Без Упорядочивания Без Групп;
   |";
   
   ТекстЗапроса = СтрЗаменить(ТекстЗапроса,"*",ВидСправочника);
   Если Запрос.Выполнить(ТекстЗапроса) = 0
   Тогда
       Возврат 0;
   КонецЕсли;

   ТЗ = СоздатьОбъект("ТаблицаЗначений");
   Запрос.Выгрузить(ТЗ,0,0);
   
   Если ПустоеЗначение(ВыбКонтрагент)=0
   Тогда //удалим из результатов поиска текущий элемент, который записываем
       поз = 0;
       Если  ТЗ.НайтиЗначение(ВыбКонтрагент,поз,"Элемент") > 0
       Тогда ТЗ.УдалитьСтроку(поз);
       КонецЕсли;    
   КонецЕсли;

   Если ТЗ.КоличествоСтрок()>0
   Тогда //обнаружены клиенты с дублирующимися ИНН
       Сообщить("Внимание: обнаружено дублирование ИНН..?!","!");
       Сообщить(СимволТабуляции+"|_ по справочнику: "+Метаданные.Справочник(ВидСправочника).Синоним);
       Сообщить(СимволТабуляции+"|_ текущий ИНН\КПП для записи: "+ИННКПП);
       ТЗ.ВыбратьСтроки();
       Пока ТЗ.ПолучитьСтроку() = 1
       Цикл Сообщить(СимволТабуляции+"|_ дубль: "+СокрЛП(ТЗ.Элемент.Код)+" "+СокрЛП(ТЗ.Элемент)+", "+ТЗ.Элемент.ИНН);
       КонецЦикла;
       Возврат 0;
   КонецЕсли;    
   
   //если попали сюда - нет дублей клиентов с заданными ИНН\КПП
   Если Найти("\/",Прав(СокрЛП(ИННКПП),1)) =0
   Тогда
       Возврат 1;
   КонецЕсли;
   
   //но!
   //проверим на дубли только ИНН, без учета КПП
   //т.к. возможны случаи когда сравниваются ИНН вида "1234567890" и "1234567890\"
   //тогда предыдущий запрос это не отловит
   
   ТекстЗапроса = СтрЗаменить(ТекстЗапроса,"ИННКПП","тИНН");
   Если Запрос.Выполнить(ТекстЗапроса) = 0
   Тогда
       Возврат 0;
   КонецЕсли;
   Запрос.Выгрузить(ТЗ,0,0);
   
   Если ПустоеЗначение(ВыбКонтрагент)=0
   Тогда //удалим из результатов поиска текущий элемент, который записываем
       поз = 0;
       Если  ТЗ.НайтиЗначение(ВыбКонтрагент,поз,"Элемент") > 0
       Тогда ТЗ.УдалитьСтроку(поз);
       КонецЕсли;    
   КонецЕсли;

   Если ТЗ.КоличествоСтрок()>0
   Тогда //обнаружены клиенты с дублирующимися ИНН
       Сообщить("Внимание: обнаружено дублирование ИНН..?!","!");
       Сообщить(СимволТабуляции+"|_ по справочнику: "+Метаданные.Справочник(ВидСправочника).Синоним);
       Сообщить(СимволТабуляции+"|_ текущий ИНН\КПП для записи: "+ИННКПП);
       ТЗ.ВыбратьСтроки();
       Пока ТЗ.ПолучитьСтроку() = 1
       Цикл Сообщить(СимволТабуляции+"|_ дубль: "+СокрЛП(ТЗ.Элемент.Код)+" "+СокрЛП(ТЗ.Элемент)+", "+ТЗ.Элемент.ИНН);
       КонецЦикла;
       Возврат 0;
   КонецЕсли;    

   //если попали сюда - нет дублей клиентов не только с заданными ИНН\КПП
   //но и с ИНН без указания КПП
   Возврат 1;
   
КонецФункции // глКонтрольУникальностиИНН()
.
Внимание: обнаружено дублирование ИНН..?!
   |_ по справочнику: Сторонние юридические лица
   |_ текущий ИНН\КПП для записи: 7721232508\772101001
   |_ дубль: 00001293 ООО "САМОХВАЛ", 7721232508\772101001
   |_ дубль: 00001333 ООО "Самохвал", 7721232508\772101001
********************* ПРОБЛЕМА: 7721232508\772101001 САМОХВАЛ ООО

err проца глКонтрольУникальностиИННSQLite не обнаружена..

в топку!

(58) Кочегар, блин... ;-)

(38) у меня там загушка стоит, которая неуспех возвращает... ;-) не осилил...

Имхо, для поиска одиноковых так красивее:

Запрос = СоздатьОбъект("Запрос");
   ТекстЗапроса = "
   |Обрабатывать Все;
   |Клиент = Справочник.ЮрЛица.ТекущийЭлемент, Справочник.ФизЛица.ТекущийЭлемент;
   |ИНН = Справочник.ЮрЛица.ИНН, Справочник.ФизЛица.ИНН;
   |Группировка Клиент без групп;";
   
   ОчиститьОкноСообщений();
   СписокИНН = СоздатьОбъект("СписокЗначений");
   КлиентДанные = "";
   
   Если Запрос.Выполнить(ТекстЗапроса) = 1 Тогда
       Пока Запрос.Группировка(1) = 1 Цикл
           
           Позиция = СписокИНН.НайтиЗначение(Запрос.ИНН);
           Если Позиция = 0 Тогда
               СписокИНН.ДобавитьЗначение(Запрос.ИНН,
                   СокрЛП(Запрос.Клиент.Наименование) + "; " + СокрЛП(Запрос.Клиент.ЮрАдрес));
           Иначе
               ТекКлиент = СоздатьОбъект("Справочник.Контрагенты");
               СписокИНН.ПолучитьЗначение(Позиция,КлиентДанные);
               Сообщить("ИНН = " + СокрЛП(Запрос.ИНН)+ " = " + КлиентДанные + " = "
                   + СокрЛП(Запрос.Клиент.Наименование) + "; " + СокрЛП(Запрос.Клиент.ЮрАдрес));
           КонецЕсли;
           
       КонецЦикла;
   КонецЕсли;
   Предупреждение("ОБРАБОТКА СПРАВОЧНИКОВ КЛИЕНТОВ ЗАВЕРШЕНА !"

+(61) для поиска "пустышек" соответственно:

Запрос = СоздатьОбъект("Запрос");
   ТекстЗапроса = "
   |Обрабатывать Все;
   |Клиент = Справочник.ЮрЛица.ТекущийЭлемент, Справочник.ФизЛица.ТекущийЭлемент;
   |ИНН = Справочник.ЮрЛица.ИНН, Справочник.ФизЛица.ИНН;
   |Условие(ПустоеЗначение(ИНН)=1);
   |Группировка Клиент без групп;";
   
   ОчиститьОкноСообщений();
   Если Запрос.Выполнить(ТекстЗапроса) = 1 Тогда
       Пока Запрос.Группировка(1) = 1 Цикл
           
           Сообщить(СокрЛП(Запрос.Клиент.Наименование) + "; "
               + СокрЛП(Запрос.Клиент.ЮрАдрес) + " - НЕ УКАЗАН ИНН !!!");
           КонецЕсли;
           
       КонецЦикла;
   КонецЕсли;
   Предупреждение("ОБРАБОТКА СПРАВОЧНИКОВ КЛИЕНТОВ ЗАВЕРШЕНА !");

(61) не словит
1234567890\123456789
1234567890/123456789