Открытие значения в компоновке.

1С v8

, ,

29.11.12

✎

09:20

Есть задача, сделать отчет на компоновке с тем чтобы печаталось время формирования.
Сделал так, через параметр и вынес формирование в код.

СхемаКомпоновкиДанных = ПолучитьМакет("Командировки");
//Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
Настройки = ЭтотОбъект.КомпоновщикНастроек.Настройки;
Настройки.ПараметрыДанных.Элементы[0].Значение = ТекущаяДата();
Настройки.ПараметрыДанных.Элементы[0].Использование = Истина;

КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки);

ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки);

ЭлементыФормы.Результат.Очистить();
ТабДок = ЭлементыФормы.Результат;
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

но перестало работать открытие выводимых элементов справочников и документов через контекстное меню. Как это настроить через код?

1 cw014

29.11.12

✎

09:21

Расшифровка то где?

2 cw014

29.11.12

✎

09:22

Компоновщик.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки)

3 kumena

29.11.12

✎

09:31

ДанныеРасшифровки - как эту переменную заполнять? с неопределено не прокатывает, да и не расшифровка там нужна а открытие, детальные записи уже некуда расшифровывать.

4 cw014

29.11.12

✎

09:32

Расширение формы отчета.ДанныеРасшифровки (Report form extension.DetailsData)
Расширение формы отчета (Report form extension)
ДанныеРасшифровки (DetailsData)
Использование:

Чтение и запись.
Описание:

Тип: ДанныеРасшифровкиКомпоновкиДанных.
Содержит данные расшифровки последнего выполненного отчета.

Доступность:

Толстый клиент.

5 cw014

29.11.12

✎

09:33

Так, почитай что такое "расшифровка" у табличного поля, потом задавай вопросы

6 kumena

29.11.12

✎

13:02

рабочий вариант, если кому интересно

СхемаКомпоновкиДанных = ПолучитьМакет("Командировки");
//Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
Настройки = ЭтотОбъект.КомпоновщикНастроек.Настройки;
Настройки.ПараметрыДанных.Элементы[0].Значение = ТекущаяДата();
Настройки.ПараметрыДанных.Элементы[0].Использование = Истина;
//ДанныеРасшифровки = Неопределено;
ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);

ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);

ЭлементыФормы.Результат.Очистить();
ТабДок = ЭлементыФормы.Результат;
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

ПроцессорВывода.УстановитьДокумент(ТабДок);
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);