Всю голову уже сломал...
Простой батник:

@echo off

set ConnectionString=/F "D:\1CBases\v82\Моя база" /N "Логин" /P "Пароль"
set ArchivePath=D:\1CBases\v82\Моя база\Архив

"C:\Program Files\1cv82\8.2.17.143\bin\1cv8.exe" DESIGNER %ConnectionString% /DumpIB "%ArchivePath%\1Cv8.dt" /Out "%ArchivePath%\Лог.txt"
type "%ArchivePath%\Лог.txt"

pause


Вместо великого могучего выводит крякозяблы! Как вывести текст лог-файла в нормальной кодировке?
Весь инет перерыл, не могу победить...
Пробовал даже так: http://ab57.ru/cmd.html#id15 но во втором файле, почему то, только одна строка - путь до первого файла...

Помогите победить, не прибегая к внешним библиотекам.

Ах да, в лог-файле 1С кодировка ANSI (1251), а в батнике кодировка DOS (866).

а зачем его смотреть в бантике? Открой в блакноте

перевести "на великий могучий латинский алфавит" не судьба?

(3) кого перевести? Научить 1С писать логи транслитом? Исходниками не поделишься, чтобы код платформы поправить?

(2) Лог-файл выводит полезную инфу об открытых сессиях, я хочу сделать бесконечный цикл в батнике, чтобы он показывал, кто блокирует базу, если нельзя сделать архивную копию.

(3) Ты, видимо, не понял, о чем речь)

(5) Ну так и показывай в блокноте?
вместо type напиши notepad (или что там у тебя в винде)

Или я несовсем понял кому ты эту инфу выводишь?

(0) ну напиши перекодировщик своих текстовых файлов, делов0то...

(7) Понимаешь, это кусок батника, поэтому нужно выводить инфу в этом же окне, а не открывать новые окна.

"кому ты эту инфу выводишь?" - тому, кто будет делать архивную копию. Запустил батник, а тебе в лицо: "Не могу сделать архив, Ива Иваныч, волк тряпошный, из базы не вышел")))

(8) Не получается... Помоги?)

(10) с сишняком/паскалем знаком?

а хотя нафига! ну например http://www.softholm.com/download-software-free9813.htm

(11) Можно сказать, что уже нет))) Но зачем они тут? Ты хочешь внешнюю прогу наваять?

(10) wiki:Iconv

(12) (14) В (0) написано: "не прибегая к внешним библиотекам"

(15) Ну ты же сам просил помощи в написания конвертора?
iconv -f windows-1251 -t cp866 input.txt > output.tx

(16) Мне не нужно писать конвертор, мне нужно сконвертировать файл средствами батника без внешних компонент. Или вывести инфу из файла в читаемом виде.

(17) а разве куций язык пакетных файлов умеет организовывать циклы и пилить строку? Вроде как нет - значит и решения нет...

(18) По ссылке в (0) ходил? Как-то можно, но у меня не получается что-то...

а хотя.... имем 866.тхт -> 1251.тхт

@echo off
chcp 866 >nul
for /f "tokens=*" %%i in (866.txt) do call:to1251 "%%i"
exit
:to1251
chcp 1251 >nul
echo %~1 >>1251.txt
chcp 866 >nul
exit /b

(18) Он много что может

Куцыф он только в хелпе

(20) Пробовал? А я пробовал:

@echo off

set ConnectionString=/F "D:\1CBases\v82\Моя база" /N "Логин" /P "Пароль"
set ArchivePath=D:\1CBases\v82\Моя база\Архив

"C:\Program Files\1cv82\8.2.17.143\bin\1cv8.exe" DESIGNER %ConnectionString% /DumpIB "%ArchivePath%\1Cv8.dt" /Out "%ArchivePath%\Лог.txt"

chcp 1251 >nul
for /f "tokens=*" %%i in ("%ArchivePath%\Лог.txt") do call:to866 "%%i"
exit
:to866
chcp 866 >nul
echo %~1 >>"%ArchivePath%\Лог_866.txt"
chcp 1251 >nul

type "%ArchivePath%\Лог_866.txt"

pause


Во втором файле только одна строка - путь до первого файла.

(22) Логично что одна строка, у тебя же цикл не отрабатывает до конца

(23) Где ошибка, подскажи?

(24) возврат есть?

или вместо него пауза?

(25) (26) добавил строку "exit /b" куда надо, но результат тот же... В файле Лог_866.txt только путь до первого файла...
Думаю, что проблема в том, что я путь до первого файла указываю как строку и он её хавать не хочет...

(27)  Да там полно ошибок

1. chcp 1251 >nul
2. for /f "tokens=*" %%i in ("%ArchivePath%\Лог.txt") do call:to866 "%%i"
3. exit
4. :to866
5. chcp 866 >nul
6. echo %~1 >>"%ArchivePath%\Лог_866.txt"
7. chcp 1251 >nul
8. type "%ArchivePath%\Лог_866.txt"
9. pause

Почему во второй строке ковычки "%ArchivePath%\Лог.txt" - ты же не строку передаешь, а пусть к файлу, вот и пиши просто без ковычек

Третью строку заменить на Goto :End. Тебе же дальше надо выполнять, а не закрывать

Вместо 8 строки нужно

:End
chcp 866 >nul
more %ArchivePath%\Лог_866.txt

(28) Пинай сильнее, не стесняйся))) Укажи на ошибки, плиз.

(30) Готово :)

А ну да, после твоих манипуляций у тебя будет кодировка 1251 для вывода, поэтому нужно

chcp 866 >nul

и после этого уже можно выводить

more %ArchivePath%\Лог_866.txt

more а не type - это чисто из моих эстетических соображений. Разница лишь в том что type выводит всю партянку, а more как только экран будет заполнен, он будет ждать нажатия кнопки и тогда следующую порцию выведет

P.S. Это уже учтено в (29)

А еще косяк, забыл про exit/b , кго нужно перед :End вставить

(29) "Почему во второй строке ковычки "%ArchivePath%\Лог.txt" - ты же не строку передаешь, а пусть к файлу, вот и пиши просто без ковычек"
Потому что путь до лога содержит пробелы. Без кавычек не взлетит.

chcp 1251 >nul
for /f "tokens=*" %%i in ("%ArchivePath%\Лог.txt") do call:to866 "%%i"
Goto :End

:to866
chcp 866 >nul
echo %~1 >>"%ArchivePath%\Лог_866.txt"
chcp 1251 >nul
exit/b

:End
chcp 866 >nul
more %ArchivePath%\Лог_866.txt

pause

(34) Должно взлететь, ты же как параметр передаешь %ArchivePath%

(36) Не взлетает. Говорит, что не может получить доступ к файлу "D:\1CBases\v82\Моя"...
А с кавчками он мне во второй файл пишет путь до файла 1 несколько раз подряд...

(37) Не несколько раз, а ты просто дописываешь в конце

Вначале пропиши
if exist "%ArchivePath%\Лог.txt" (del "%ArchivePath%\Лог.txt" /f /q)

И в начале замени
set ArchivePath=D:\1CBases\v82\Моя база\Архив

на

set ArchivePath="D:\1CBases\v82\Моя база\Архив"

И попробуй еще раз

(39) Не взлетит, пробовал уже. Скажет, что не нашел файл D:\1CBases\v82\Моя база\Архив"\Лог.txt (кавычка в пути)

ну так чё, не победили ещё?

(41) Неа...

(22) а ты скопируй, тупо скопируй из (20) - перекодирует весь исходный файл - проверял!!!

(43) Я верю, что код рабочий, только в моем случае, путь до файлов может содержать русские символы и пробелы... Вот в этом-то и проблема...

(44) а если путь скормить как параметр батнику? а вывод в некий фиксированный файл а в конце батника исходный мочим, резльтирующий копируем куда надо

(45) А где размещать фиксированный файл? В корень диска не положишь - неизвестно, есть туда у юзера доступ или нет, а в темп - так там в пути тоже русские символы и пробелы могут быть...

+(46) Я уж подумал о команде cd, но хз на сколько она поможет...

например основной каталог юзера, вроде такой:  %HOMEPATH%

(40) Удали пробелы, так как он считает что все что в ковычках строка

А он вообще "Моя база" находит? Там же кодировки разные?

(49) кста, а разве в имена файлов/папок можно всякие куавычки пихать?

(48) Русские символы и пробелы могут быть и там...

(49) В смысле удалить кавычки?

(51) В мена нет, поэтому обычно и передают в виде строки

(52) передавай полный путь+имя как параметр на вход пакетному файлу

(50) Находит...

(53) Параметры у For таки
без ковычек - путь
с ковычками - строка
одинарные ковычки - команда

(55) Из-за пробела не взлетит. Потому что в досе пробел - разделитель команд

(55) Не понял...

(57) (58) И что делать-то?

(54) т.о. это кривая папка или файл и не может считаться корректным для теста

(61) И что делать-то?)

(59) KruchuVerchuKodyZaputatHochu.bat "D:\1CBases\v82\Моя"

а внути него вместо переданного уже как параметр имени юзать %1

(63) Не взлетит

(63) Что-то мне подсказывает, что это не решение проблемы...

И кстати не уверен, что
set ArchivePath=D:\1CBases\v82\Моя база\Архив

нормально отработает в досе

(66) Код из (0) работает без ошибок.

(64) обоснуй

(67) ТОгда как вариант переименуй bat в cmd и попробуй запустить

(69)чем бат-то не правится?

(68) потому что он подставит результат и попытается выполнить. И обломается

(70) Есть мнение, что разные интерпритаторы команд, и по разному работают

(69) Не помогло.

(3) Ну хз у меня работает

Ты точно убрал ковычки?

текст в студию

(74) Не, кавычки не убирал))) Ща попробую)

(74) cmd-файл:

@echo off

set ConnectionString=/F "D:\1CBases\v82\Моя база" /N "Логин" /P "Пароль"
set ArchivePath=D:\1CBases\v82\Моя база\Архив

"C:\Program Files\1cv82\8.2.17.143\bin\1cv8.exe" DESIGNER %ConnectionString% /DumpIB "%ArchivePath%\1Cv8.dt" /Out "%ArchivePath%\Лог.txt"

chcp 1251 >nul
for /f "tokens=*" %%i in (%ArchivePath%\Лог.txt) do call:to866 "%%i"
Goto :End

:to866
chcp 866 >nul
echo %~1 >>%ArchivePath%\Лог_866.txt
chcp 1251 >nul
exit/b

:End
chcp 866 >nul
more %ArchivePath%\Лог_866.txt

pause



Не удалось получить доступ к файлу "D:\1CBases\v82\Моя"...

(77) имя+ путь, логнэём и пароль передавать как входные параметры

(78) Лог-файл создается без проблем. Ошибка возникает после этого.

Пробую так:

cd /d "%ArchivePath%"

chcp 1251 >nul
for /f "tokens=*" %%i in (Лог.txt) do call:to866 "%%i"
Goto :End

:to866
chcp 866 >nul
echo %~1 >>Лог_866.txt
chcp 1251 >nul
exit/b

:End
chcp 866 >nul
more Лог_866.txt

pause


Но если файла Лог_866.txt нет, то ошибка, а если есть, то выводит ошибку в крякозяблах про Лог_.txt...

(80) Ошибка какая?

В начале почему не добавил
if exist "%ArchivePath%\Лог_866.txt" (del "%ArchivePath%\Лог_866.txt" /f /q)

ну и

if exist Лог_866.txt more Лог_866.txt

(80) Если файла Лог_866.txt нет, то ошибка в крякозяблах про файл Лог.txt и ещё одна ошибка "Не удается получить доступ к файлу D:\1CBases\v82\Моя база\Архив\Лог_866.txt"

(82) Я все файлы вручную удаляю перед запуском. Так что, пока, не критично.

(83) Замени Лог_866.txt на Log_866.txt
И это плохой тон писать в бантике по русски

(85) Ахахахахах!!!!!! О, дааааааааааааааааа!!!!!
Работает!)))) Тынц-тынц))))
Ща, наведу марафет и выложу, что получилось)

(86) марафет это ваще-то по фене укол опия! Ты там кодишь за дозу?

(87) Наводить/ навести марафет.
1. Жарг. угол. Привести в замешательство неожиданным вопросом случайного свидетеля кражи и скрыться с места преступления. Трахтенберг, 37.
2. Жарг. угол. Заверять кого-л. в своей невинности, честности. СРВС 2, 51, 55, 189; СРВС 3, 102.
3. Кубан. Дурачить, обманывать кого-л. СРНГ 17, 369.
4. Прост. Приводить себя или что-л. в полный порядок (по случаю праздника, торжественной встречи кого-л. и т. п.). БМС 1998, 366; НЗС-84, 344; Глухов 1988, 87; Грачев, Мокиенко 2000, 118; Вахитов 2003, 104.

(с) http://dic.academic.ru/dic.nsf/proverbs/4994/МАРАФЕТ

(87) (88) Имеется ввиду
"4. Прост. Приводить себя или что-л. в полный порядок (по случаю праздника, торжественной встречи кого-л. и т. п.). БМС 1998, 366; НЗС-84, 344; Глухов"
Не надо тут мне... :)))
Блин, жена в магаз гонит, марафет наведу минут через 20... :)

(89) не, ну ты код когда покажешь?

(90) Ладно, вот что успел набросать:

@echo off

set ConnectionString=/F "D:\+\1CBases\v82\Домашняя бухгалтерия" /N "Администратор" /P "0"
cd /d "D:\+\1CBases\v82\Домашняя бухгалтерия\Архив"

:StartPoint
echo %date% %time:~0,8% - Создание архивной копии...
"C:\Program Files\1cv82\8.2.17.143\bin\1cv8.exe" DESIGNER %ConnectionString% /DumpIB 1Cv8.dt /Out Log.txt

rem Конвертируем лог-файл в DOS кодировку
if exist Log_for_cmd.txt (del Log_for_cmd.txt /f /q)
chcp 1251 >nul
for /f "tokens=*" %%i in (Log.txt) do call:to866 "%%i"
Goto :End
:to866
chcp 866 >nul
echo %~1 >>Log_for_cmd.txt
chcp 1251 >nul
exit/b
:End
chcp 866 >nul
rem Закончили конвертирование лог-файла в DOS кодировку

if 1==1 (
type Log_for_cmd.txt
ping 127.0.0.1 -n 5 > nul
Cls
Goto :StartPoint
)

pause


Нужно в строке "if 1==1 (" сделать поиск по файлу Log_for_cmd.txt и если в файле есть строка "Выгрузка информационной базы успешно завершена", то в условие не заходить... Поможете?)

(91) Ну вот, вывалил имя своей базы, логин и пароль))))))))) Эх)))

(91) день прожит не зря?

ping 127.0.0.1 -n 5 > nul
Замени на

choice /C Y /T 5 /D Y /M "Продолжить?"

Нужно в строке "if 1==1 (" сделать поиск по файлу Log_for_cmd.txt и если в файле есть строка "Выгрузка информационной базы успешно завершена", то в условие не заходить...


@find "Выгрузка информационной базы успешно завершена" Log_for_cmd.txt >nul
IF not %errorlevel%==0 (
 type Log_for_cmd.txt
 choice /C Y /T 5 /D Y /M "Continue?"
 Cls
 Goto :StartPoint
)

(94) Вещь! Спасибо)
(95) Угу, я уже был близок к этому коду, но спасибо, что подсказал))

Итак, вот он, мой bat-файл, который либо делает архивную копию, либо показывает активные сеансы (продолжая делать попытки создать архивную копию):

@echo off

set ConnectionString=/F "D:\1CBases\v82\Моя база" /N "Логин" /P "Пароль"
cd /d ArchivePath=D:\1CBases\v82\Моя база\Архив

:StartPoint
echo %date% %time:~0,8% - Создание архивной копии...
"C:\Program Files\1cv82\8.2.17.143\bin\1cv8.exe" DESIGNER %ConnectionString% /DumpIB 1Cv8.dt /Out Log.txt

rem Конвертируем лог-файл в DOS кодировку
if exist Log_for_cmd.txt (del Log_for_cmd.txt /f /q)
chcp 1251 >nul
for /f "tokens=*" %%i in (Log.txt) do call:to866 "%%i"
Goto :End
:to866
chcp 866 >nul
echo %~1 >>Log_for_cmd.txt
chcp 1251 >nul
exit/b
:End
chcp 866 >nul
rem Закончили конвертирование лог-файла в DOS кодировку

@find "Выгрузка информационной базы успешно завершена" Log_for_cmd.txt >nul
if not %ErrorLevel%==0 (
type Log_for_cmd.txt
choice /C Y /T 5 /D Y /M "Продолжить?" >nul
Cls
Goto :StartPoint
)
echo %date% %time:~0,8% - Архивная копия успешно создана

pause

Aleksey и rphosts спасибо большое)