Есть запрос по регистру хозрасчетный
Мне надо чтобы в этот запрос НЕ попали документы определенного типа "КорректировкаДолгаПоЗаказам"

Как написать такое условие ?

ВЫБРАТЬ
   ХозрасчетныйОбороты.Регистратор.Дата КАК Дата,
   ХозрасчетныйОбороты.Регистратор КАК Документ,
   ХозрасчетныйОбороты.Субконто2 КАК Договор,
   ВЫБОР
       КОГДА ХозрасчетныйОбороты.Субконто2.ВедениеВзаиморасчетов В (&ПоСчетамПоЗаказам)
           ТОГДА ХозрасчетныйОбороты.Субконто3
       ИНАЧЕ НЕОПРЕДЕЛЕНО
   КОНЕЦ КАК Сделка,
   0 КАК ОстатокНаНачало,
   ВЫБОР
       КОГДА &Валюта = НЕОПРЕДЕЛЕНО
           ТОГДА ХозрасчетныйОбороты.СуммаОборотДт
       ИНАЧЕ ХозрасчетныйОбороты.ВалютнаяСуммаОборотДт
   КОНЕЦ КАК Дебет,
   ВЫБОР
       КОГДА &Валюта = НЕОПРЕДЕЛЕНО
           ТОГДА ХозрасчетныйОбороты.СуммаОборотКт
       ИНАЧЕ ХозрасчетныйОбороты.ВалютнаяСуммаОборотКт
   КОНЕЦ КАК Кредит,
   0 КАК ОстатокНаКонец,
   ЕСТЬNULL(ХозрасчетныйОбороты.Регистратор.НомерВходящегоДокумента, НЕОПРЕДЕЛЕНО) КАК НомерВходящегоДокумента,
   ЕСТЬNULL(ХозрасчетныйОбороты.Регистратор.ДатаВходящегоДокумента, НЕОПРЕДЕЛЕНО) КАК ДатаВходящегоДокумента,
   ВЫБОР
       КОГДА НЕ ЕСТЬNULL(ХозрасчетныйОбороты.Регистратор.НомерПоручения, НЕОПРЕДЕЛЕНО) = НЕОПРЕДЕЛЕНО
           ТОГДА ХозрасчетныйОбороты.Регистратор.НомерПоручения
       ИНАЧЕ ЕСТЬNULL(ХозрасчетныйОбороты.Регистратор.НомерОрдера, НЕОПРЕДЕЛЕНО)
   КОНЕЦ КАК НомерДокумента,
   ХозрасчетныйОбороты.КорСчет,
   ХозрасчетныйОбороты.КорСубконто1,
   ХозрасчетныйОбороты.КорСубконто2,
   ХозрасчетныйОбороты.КорСубконто3,
   ХозрасчетныйОбороты.Валюта,
   ХозрасчетныйОбороты.ВалютнаяСуммаОборот,
   ХозрасчетныйОбороты.Счет
ИЗ
   РегистрБухгалтерии.Хозрасчетный.Обороты(
           &ДатаНачала,
           &ДатаОкончания,
           Регистратор,
           Счет В ИЕРАРХИИ (&ФильтрСписокСчетов),
           &АналитикаРасчетов,
           Организация = &Организация
               И ВЫБОР
                   КОГДА &Валюта = НЕОПРЕДЕЛЕНО
                       ТОГДА ИСТИНА
                   ИНАЧЕ Валюта = &Валюта
               КОНЕЦ
               И Субконто1 = &Контрагент
               И ВЫБОР
                   КОГДА &ДоговорКонтрагента = НЕОПРЕДЕЛЕНО
                       ТОГДА ИСТИНА
                   ИНАЧЕ Субконто2 = &ДоговорКонтрагента
               КОНЕЦ,
           ,
           ) КАК ХозрасчетныйОбороты
ГДЕ
   ВЫБОР
           КОГДА ХозрасчетныйОбороты.КорСчет В ИЕРАРХИИ (&ФильтрСписокСчетов)
               ТОГДА ВЫБОР
                       КОГДА &ДоговорКонтрагента = НЕОПРЕДЕЛЕНО
                           ТОГДА НЕ ХозрасчетныйОбороты.КорСубконто1 = &Контрагент
                       ИНАЧЕ НЕ(ХозрасчетныйОбороты.КорСубконто1 = &Контрагент
                                   И ХозрасчетныйОбороты.КорСубконто2 = &ДоговорКонтрагента)
                   КОНЕЦ
           ИНАЧЕ ИСТИНА
       КОНЕЦ
   И ХозрасчетныйОбороты.Регистратор = &Регистратор

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "Остатки",
   НЕОПРЕДЕЛЕНО,
   НЕОПРЕДЕЛЕНО,
   НЕОПРЕДЕЛЕНО,
   ВЫБОР
       КОГДА &Валюта = НЕОПРЕДЕЛЕНО
           ТОГДА ХозрасчетныйОстатки.СуммаНачальныйОстаток
       ИНАЧЕ ХозрасчетныйОстатки.ВалютнаяСуммаНачальныйОстаток
   КОНЕЦ,
   0,
   0,
   ВЫБОР
       КОГДА &Валюта = НЕОПРЕДЕЛЕНО
           ТОГДА ХозрасчетныйОстатки.СуммаКонечныйОстаток
       ИНАЧЕ ХозрасчетныйОстатки.ВалютнаяСуммаКонечныйОстаток
   КОНЕЦ,
   НЕОПРЕДЕЛЕНО,
   НЕОПРЕДЕЛЕНО,
   НЕОПРЕДЕЛЕНО,
   NULL,
   NULL,
   NULL,
   NULL,
   NULL,
   NULL,
   NULL
ИЗ
   РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
           &ДатаНачала,
           &ДатаОкончания,
           Период,
           ДвиженияИГраницыПериода,
           Счет В ИЕРАРХИИ (&ФильтрСписокСчетов),
           &АналитикаРасчетов,
           Организация = &Организация
               И ВЫБОР
                   КОГДА &Валюта = НЕОПРЕДЕЛЕНО
                       ТОГДА ИСТИНА
                   ИНАЧЕ Валюта = &Валюта
               КОНЕЦ
               И Субконто1 = &Контрагент
               И ВЫБОР
                   КОГДА &ДоговорКонтрагента = НЕОПРЕДЕЛЕНО
                       ТОГДА ИСТИНА
                   ИНАЧЕ Субконто2 = &ДоговорКонтрагента
               КОНЕЦ) КАК ХозрасчетныйОстатки

УПОРЯДОЧИТЬ ПО
   Дата,
   Документ,
   Дебет

где не регистратор ссылка документ.твойдокумент

ГДЕ ТИПЗНАЧЕНИЯ(ХозрасчетныйОбороты.Регистратор) <> ТИП(Документ.КорректировкаДолгаПоЗаказам)

(1) +1

(2) аплодирую )) Спасибо всем сработало !

(1) кроссплатформенно, (2) - начиная с 8.2