v7: Крипто Про и 1С 7.7

Вот кусок кода из http://infostart.ru/public/156973/
касаемо подписи и шифрования

//======================================================================
Функция ПолучитьПредставлениеСертификата(ТекСубъект)
ПредставлениеСертификата="";
СубъектИмя=""; СубъектДолжность=""; СубъектОрганизация=""; СубъектОрганизацияИНН=""; СубъектОрганизацияМестонахождение="";

СписокСтр=СтрЗаменить(ТекСубъект,", ",РазделительСтрок);
Для НомСтр=1 По СтрКоличествоСтрок(СписокСтр) Цикл
ТекПараметр="";
ТекЗначение="";
ТекСтр=СокрЛП(СтрПолучитьСтроку(СписокСтр,НомСтр));
ПозРавно=Найти(ТекСтр,"=");
Если ПозРавно>0 Тогда
ТекПараметр=СокрЛП(Лев(ТекСтр,ПозРавно-1));
ТекЗначение=СокрЛП(Сред(ТекСтр,ПозРавно+1));
КонецЕсли;

Если ТекПараметр="CN" Тогда
СубъектИмя=ТекЗначение;
ИначеЕсли ТекПараметр="T" Тогда
СубъектДолжность=ТекЗначение;
ИначеЕсли ТекПараметр="O" Тогда
Если (Лев(ТекЗначение,1)="""") И (Прав(ТекЗначение,1)="""") Тогда
ТекЗначение=Сред(ТекЗначение,2,СтрДлина(ТекЗначение)-2);
КонецЕсли;
ТекЗначение=СтрЗаменить(ТекЗначение,"""""","""");
СубъектОрганизация=ТекЗначение;
ИначеЕсли ТекПараметр="L" Тогда
СубъектОрганизацияМестонахождение=ТекЗначение;
ИначеЕсли (ТекПараметр="ИНН") ИЛИ (ТекПараметр="INN") ИЛИ (ТекПараметр="OID.1.2.643.3.131.1.1") Тогда
СубъектОрганизацияИНН="ИНН "+ТекЗначение;
КонецЕсли;

КонецЦикла;

ПредставлениеСертификата=СубъектОрганизация+" "+СубъектОрганизацияМестонахождение+" "+СубъектОрганизацияИНН+", "+СубъектДолжность+" "+СубъектИмя;

Возврат ПредставлениеСертификата;
КонецФункции

//======================================================================
Функция ПодписатьФайл(ИмяФайла,ВыбСертификат,ИмяВыхФайла)

Попытка
JS=СоздатьОбъект("MSScriptControl.ScriptControl");
JS.Language="jscript";
JS.Timeout=-1;
Исключение
ТекстОшибки=ОписаниеОшибки();
Сообщить("Не удалось создать объект MSScriptControl.ScriptControl","!");
Сообщить("Описание ошибки: "+ТекстОшибки,"!");
Возврат 0;
КонецПопытки;

Попытка

СтрКода="function SignFile(FileName,Cert,OutFileName)
|{
| InStream=new ActiveXObject(""ADODB.Stream"");
| InStream.Type=1; // binary data
| InStream.Mode=3; // read/write
| InStream.Open();
| InStream.LoadFromFile(FileName);
| InData=InStream.Read(-1);
|
| Signer=new ActiveXObject(""CAPICOM.Signer"");
| Signer.Certificate=Cert;
| Signer.Options=2; // CAPICOM_CERTIFICATE_INCLUDE_END_ENTITY_ONLY
| SignedData=new ActiveXObject(""CAPICOM.SignedData"");
| SignedData.Content=InData;
| OutSignedData=SignedData.Sign(Signer,0,1);
|
| OutStream=new ActiveXObject(""ADODB.Stream"");
| OutStream.Type=2; // text data
| OutStream.Mode=3; // read/write
| OutStream.Open();
| OutStream.WriteText(OutSignedData);
| OutStream.SaveToFile(OutFileName,2);
| OutStream.Close();
|
| return(0);
|}
|";

JS.AddCode(СтрКода);
Рез=JS.Modules("Global").CodeObject.SignFile(ИмяФайла,ВыбСертификат,ИмяВыхФайла);
Исключение
ТекстОшибки=ОписаниеОшибки();
Сообщить("Произошла ошибка при подписи файла!","!");
Сообщить("Описание ошибки: "+ТекстОшибки,"!");
Возврат 0;
КонецПопытки;
Возврат 1;
КонецФункции

//======================================================================
Функция УпаковатьФайл(ИмяФайла,ИмяВыхФайла)

КоротИмяФайла=ФС.НайтиПервыйФайл(ИмяФайла);
Если ПустоеЗначение(КоротИмяФайла)=1 Тогда
Сообщить("Не найден файл "+ИмяФайла,"!");
Возврат 0;
КонецЕсли;
ИмяКат=Лев(ИмяФайла,СтрДлина(ИмяФайла)-СтрДлина(КоротИмяФайла));

Попытка
BinData=СоздатьОбъект("BinaryData");
Исключение
ТекстОшибки=ОписаниеОшибки();
Сообщить("Не удалось создать объект BinaryData","!");
Сообщить("Описание ошибки: "+ТекстОшибки,"!");
Возврат 0;
КонецПопытки;

Попытка

ФС.УстТекКаталог(ИмяКат);
BinData.pkZip(""""+ИмяВыхФайла+""" """+КоротИмяФайла+"""");
BinData.Закрыть();

Исключение
ТекстОшибки=ОписаниеОшибки();
Сообщить("Произошла ошибка при упаковке файла!","!");
Сообщить("Описание ошибки: "+ТекстОшибки,"!");
Возврат 0;
КонецПопытки;
Возврат 1;
КонецФункции

//======================================================================
Функция ЗашифроватьФайл(ИмяФайла,ВыбПолучатели,ИмяВыхФайла)

Попытка
JS=СоздатьОбъект("MSScriptControl.ScriptControl");
JS.Language="jscript";
JS.Timeout=-1;
Исключение
ТекстОшибки=ОписаниеОшибки();
Сообщить("Не удалось создать объект MSScriptControl.ScriptControl","!");
Сообщить("Описание ошибки: "+ТекстОшибки,"!");
Возврат 0;
КонецПопытки;

Попытка

СтрКода="function CryptFile(FileName,Recipients,OutFileName)
|{
| InStream=new ActiveXObject(""ADODB.Stream"");
| InStream.Type=1; // binary data
| InStream.Mode=3; // read/write
| InStream.Open();
| InStream.LoadFromFile(FileName);
| InData=InStream.Read(-1);
|
| EnvelopedData=new ActiveXObject(""CAPICOM.EnvelopedData"");
| EnvelopedData.Content=InData;
| for (var i=1; i<=Recipients.Count; i++) {EnvelopedData.Recipients.Add(Recipients.Item(i));}
| OutEnvelopedData=EnvelopedData.Encrypt(1);
|
| OutStream=new ActiveXObject(""ADODB.Stream"");
| OutStream.Type=2; // text data
| OutStream.Mode=3; // read/write
| OutStream.Open();
| OutStream.WriteText(OutEnvelopedData);
| OutStream.SaveToFile(OutFileName,2);
| OutStream.Close();
|
| return(0);
|}
|";

JS.AddCode(СтрКода);
Рез=JS.Modules("Global").CodeObject.CryptFile(ИмяФайла,ВыбПолучатели,ИмяВыхФайла);
Исключение
ТекстОшибки=ОписаниеОшибки();
Сообщить("Произошла ошибка при шифровании файла!","!");
Сообщить("Описание ошибки: "+ТекстОшибки,"!");
Возврат 0;
КонецПопытки;
Возврат 1;
КонецФункции

//======================================================================
Процедура БезопасноУдалитьФайл(ИмяФайла);

Попытка
ФС.УдалитьФайл(ИмяФайла);
Исключение
КонецПопытки;

КонецПроцедуры

//======================================================================
Процедура ПодписатьЗашифроватьФайл(ИмяФайла,ПоказыватьНастройки=1)

ИмяФайлаПодписи=ИмяФайла+".sig";
ИмяФайлаАрхива=ИмяФайлаПодписи+".zip";
ИмяФайлаЗашифр=ИмяФайлаАрхива+".enc";

ТекИНН=Сред(КороткоеИмяФайла,4,12);
ПозПодч=Найти(ТекИНН,"_");
Если (ПозПодч>0) Тогда
ТекИНН=Лев(ТекИНН,ПозПодч-1);
КонецЕсли;

ПрефиксДекл=Лев(КороткоеИмяФайла,3);
Если (ПрефиксДекл="R1_") ИЛИ (ПрефиксДекл="R2_") Тогда
// розничные
ПравильноеЧислоПолучателей=2;
ИмяНастроек="ПодписьРознАлкоДеклараций_"+ТекИНН;
Иначе
ПравильноеЧислоПолучателей=1;
ИмяНастроек="ПодписьАлкоДеклараций_"+ТекИНН;
КонецЕсли;

// CAPICOM constants
CAPICOM_CURRENT_USER_STORE=2;
CAPICOM_MY_STORE="My";
CAPICOM_OTHER_STORE="AddressBook";
CAPICOM_STORE_OPEN_READ_ONLY=0;
CAPICOM_CERTIFICATE_FIND_TIME_VALID=9;

ТекДата=ТекущаяДата();

СохранённыйОтпечатокДекларанта="";
СохранённыеОтпечаткиПолучателей=СоздатьОбъект("СписокЗначений");
// восстанавливаем настройки
Попытка
НастройкиПодписи=ВосстановитьЗначение(ИмяНастроек);
Если ТипЗначенияСтр(НастройкиПодписи)="СписокЗначений" Тогда
СохранённыйОтпечатокДекларанта=НастройкиПодписи.Получить("ОтпечатокДекларанта");
СохранённыеОтпечаткиПолучателей=НастройкиПодписи.Получить("ОтпечаткиПолучателей");
Если ТипЗначенияСтр(СохранённыеОтпечаткиПолучателей)<>"СписокЗначений" Тогда
СохранённыеОтпечаткиПолучателей=СоздатьОбъект("СписокЗначений");
КонецЕсли;
КонецЕсли;
Исключение

КонецПопытки;

СписокНашихСертификатов=СоздатьОбъект("СписокЗначений");
СписокСертификатовПолучателей=СоздатьОбъект("СписокЗначений");
ВыбСертификатЭЦП="";

Попытка
// формируем список наших сертификатов
Store=CreateObject("CAPICOM.Store");
Store.Open(CAPICOM_CURRENT_USER_STORE,CAPICOM_MY_STORE,CAPICOM_STORE_OPEN_READ_ONLY);
Certs=Store.Certificates;
ValidCerts=Certs.Find(CAPICOM_CERTIFICATE_FIND_TIME_VALID,ТекущаяДата(),-1);
Для CertNum=1 По ValidCerts.Count Цикл
CurCert=ValidCerts.Item(CertNum);
Thumbprint=CurCert.Thumbprint;
SerialNumber=CurCert.SerialNumber;
SubjectName=CurCert.SubjectName;
ValidFromDate=CurCert.ValidFromDate;
ValidToDate=CurCert.ValidToDate;

ПредставлениеСертификата=ПолучитьПредставлениеСертификата(SubjectName);
ПредставлениеСертификата=ПредставлениеСертификата+", с "+Формат(ValidFromDate,"Д ДДММГГГГ")+" по "+Формат(ValidToDate,"Д ДДММГГГГ");
СписокНашихСертификатов.ДобавитьЗначение(CurCert,ПредставлениеСертификата);
Если (Thumbprint=СохранённыйОтпечатокДекларанта) Тогда
ВыбСертификатЭЦП=CurCert;
КонецЕсли;

КонецЦикла;
Исключение
ТекстОшибки=ОписаниеОшибки();
Сообщить("Произошла ошибка при работе с хранилищем сертификатов! (Возможно, не установлен модуль CAPICOM)","!");
Сообщить("Описание ошибки: "+ТекстОшибки,"!");
Возврат;
КонецПопытки;

Если (ПоказыватьНастройки=1) Тогда
РезВыбора=СписокНашихСертификатов.ВыбратьЗначение(ВыбСертификатЭЦП,"Укажите сертификат Декларанта");
Если РезВыбора<>1 Тогда
Возврат;
КонецЕсли;
Иначе
Если (ПустоеЗначение(ВыбСертификатЭЦП)=1) Тогда
Предупреждение("Сертификат Декларанта не выбран или отсутствует в списке действительных сертификатов");
Возврат;
КонецЕсли;
КонецЕсли;

СохранённыйОтпечатокДекларанта=ВыбСертификатЭЦП.Thumbprint;

Попытка
// формируем список получателей
Store.Open(CAPICOM_CURRENT_USER_STORE,CAPICOM_OTHER_STORE,CAPICOM_STORE_OPEN_READ_ONLY);
Certs=Store.Certificates;
ValidCerts=Certs.Find(CAPICOM_CERTIFICATE_FIND_TIME_VALID,ТекущаяДата(),-1);
Для CertNum=1 По ValidCerts.Count Цикл
CurCert=ValidCerts.Item(CertNum);
Thumbprint=CurCert.Thumbprint;
SerialNumber=CurCert.SerialNumber;
SubjectName=CurCert.SubjectName;
ValidFromDate=CurCert.ValidFromDate;
ValidToDate=CurCert.ValidToDate;

ПредставлениеСертификата=ПолучитьПредставлениеСертификата(SubjectName);
ПредставлениеСертификата=ПредставлениеСертификата+", с "+Формат(ValidFromDate,"Д ДДММГГГГ")+" по "+Формат(ValidToDate,"Д ДДММГГГГ");
СписокСертификатовПолучателей.ДобавитьЗначение(CurCert,ПредставлениеСертификата);
Если (СохранённыеОтпечаткиПолучателей.НайтиЗначение(Thumbprint)>0) Тогда
СписокСертификатовПолучателей.Пометка(СписокСертификатовПолучателей.РазмерСписка(),1);
КонецЕсли;

КонецЦикла;
Исключение
ТекстОшибки=ОписаниеОшибки();
Сообщить("Произошла ошибка при работе с хранилищем сертификатов!","!");
Сообщить("Описание ошибки: "+ТекстОшибки,"!");
Возврат;
КонецПопытки;

Если (ПоказыватьНастройки=1) Тогда
РезВыбора=СписокСертификатовПолучателей.ОтметитьЗначения(,"Отметьте сертификаты получателей");
Если РезВыбора<>1 Тогда
Возврат;
КонецЕсли;
КонецЕсли;

ВыбПолучатели=CreateObject("CAPICOM.Certificates");
СохранённыеОтпечаткиПолучателей=СоздатьОбъект("СписокЗначений");
Для НомСерт=1 По СписокСертификатовПолучателей.РазмерСписка() Цикл
Если (СписокСертификатовПолучателей.Пометка(НомСерт)=1) Тогда
CurCert=СписокСертификатовПолучателей.ПолучитьЗначение(НомСерт);
ВыбПолучатели.Add(CurCert);
СохранённыеОтпечаткиПолучателей.ДобавитьЗначение(CurCert.Thumbprint);
КонецЕсли;
КонецЦикла;

Если (СохранённыеОтпечаткиПолучателей.РазмерСписка()=0) Тогда
Предупреждение("Сертификаты получателей не выбраны или отсутствуют в списке действительных сертификатов");
Возврат;
ИначеЕсли (СохранённыеОтпечаткиПолучателей.РазмерСписка()<ПравильноеЧислоПолучателей) Тогда
Предупреждение("Выбрано менее "+ПравильноеЧислоПолучателей+" сертификатов получателей");
ИначеЕсли (СохранённыеОтпечаткиПолучателей.РазмерСписка()>ПравильноеЧислоПолучателей) Тогда
Предупреждение("Выбрано более "+ПравильноеЧислоПолучателей+" сертификатов получателей");
КонецЕсли;

// сохраняем настройки
НастройкиПодписи=СоздатьОбъект("СписокЗначений");
НастройкиПодписи.Установить("ОтпечатокДекларанта",СохранённыйОтпечатокДекларанта);
НастройкиПодписи.Установить("ОтпечаткиПолучателей",СохранённыеОтпечаткиПолучателей);
СохранитьЗначение(ИмяНастроек,НастройкиПодписи);

// подписываем и шифруем файл
РезУпак=0; РезШифр=0;
РезПодписи=ПодписатьФайл(ИмяФайла,ВыбСертификатЭЦП,ИмяФайлаПодписи);
Если (РезПодписи=1) Тогда
РезУпак=УпаковатьФайл(ИмяФайлаПодписи,ИмяФайлаАрхива);
Если (РезУпак=1) Тогда
РезШифр=ЗашифроватьФайл(ИмяФайлаАрхива,ВыбПолучатели,ИмяФайлаЗашифр);
КонецЕсли;

БезопасноУдалитьФайл(ИмяФайлаАрхива);

КонецЕсли;

БезопасноУдалитьФайл(ИмяФайлаПодписи);

Если (РезШифр=1) Тогда
Предупреждение("Файл успешно сформирован");
КонецЕсли;

КонецПроцедуры