Сильно не пинать, только учусь.

Есть табличное поле на форме, тип ДокументСписок (обычные формы).
необходимо добавить колонку с флажком(с возможностью установки/удаления флага).

собственно как? добавил колонку, тип булево, но при нажатии на флаг - открывается документ.

собственно вопрос: каким образом можно добавить колонку(с возможностью редактирования ее данных) в ТабличноеПоле??

поиск... аж зубы ноют...

обработчик события ПриИзмененииФлажка...

Дмитрий, веселый понедельник))))))

тип ДокументСписок?..
а с какой целью может понадобиться отмечать что-то галками в ДокументСписок?

(4) клиент хочет отмечать в списке документов необходимые и выполнять с выделенными доками определенные действия.
(2) при попытке изменения флажка открывается документ

ап чтоли

Ну держи чтоли

Перем СписокДокументовДляОбработки;

Процедура ТабличноеПоле1ПриПолученииДанных(Элемент, ОформленияСтрок)
   
   Для Каждого ОформлениеСтроки Из ОформленияСтрок Цикл
       ОформлениеСтроки.Ячейки.Флажок1.УстановитьФлажок(СписокДокументовДляОбработки.Получить(ОформлениеСтроки.ДанныеСтроки.Ссылка) <> Неопределено);
   КонецЦикла;
   
КонецПроцедуры

Процедура ТабличноеПоле1ПередНачаломИзменения(Элемент, Отказ)
   
   Если ЭлементыФормы.ТабличноеПоле1.ТекущаяКолонка.Имя = "Флажок1" Тогда
       Отказ = Истина;
       Ссылка = ЭлементыФормы.ТабличноеПоле1.ТекущиеДанные.Ссылка;
       Если СписокДокументовДляОбработки.Получить(Ссылка) = Неопределено Тогда
           СписокДокументовДляОбработки.Вставить(Ссылка, Ссылка);
       Иначе
           СписокДокументовДляОбработки.Удалить(Ссылка);
       КонецЕсли;
   КонецЕсли;
   
КонецПроцедуры

СписокДокументовДляОбработки = Новый Соответствие;

Колонка = ЭлементыФормы.ТабличноеПоле1.Колонки.Вставить(0, "Флажок1");
Колонка.Имя = "Флажок1";
Колонка.Ширина = 3;
Колонка.Данные = "";
Колонка.ДанныеФлажка = "ПометкаУдаления";
Колонка.ИзменятьПозицию = Ложь;
Колонка.ИзменениеРазмера = ИзменениеРазмераКолонки.НеИзменять;
Колонка.ИзменятьВидимость = Ложь;
Колонка.ИзменятьНастройку = Ложь;
Колонка.РежимРедактирования =  РежимРедактированияКолонки.Непосредственно;