Нужно удалить определенные строки тз. Типа такого варианта


ТЗ_уд.ВыбратьСтроки();
       Пока ТЗ_уд.ПолучитьСтроку() = 1 Цикл
           
           
           Если Тз_уд.Предоплата = 1 Тогда
               Сообщить("ДокАкт "+ТЗ_уд.Док+"  Номер строки "+ТЗ_уд.НомерСтроки+" Удаляем!");
               Тз_уд.УдалитьСтроку();
           КонецЕсли;
           
       КонецЦикла;

ТЗ_уд.ВыбратьСтроки();
       Пока ТЗ_уд.ПолучитьСтроку() = 1 Цикл          
           
          Пока (Тз_уд.Предоплата = 1) и (ТЗ_уд.НомерСтроки>0) Цикл
               Сообщить("ДокАкт "+ТЗ_уд.Док+"  Номер строки "+ТЗ_уд.НомерСтроки+" Удаляем!");
               Тз_уд.УдалитьСтроку();
КонеЦикла;
           
       КонецЦикла;

Строчка = 1;
Пока Строчка <= ТЗ_уд.КоличествоСтрок() Цикл
 Если Тз_уд.ПолучитьЗначение(Строчка,"Предоплата")=1 Тогда
   Тз_уд.УдалитьСтроку();
 Иначе
   Строчка = Строчка + 1;
 КонецЕсли;
КонецЦикла;

(0) Кажется здесь нужно вводить счетчик.

(+3) смотри (2)

Сейчас кто-нибудь предложит вариант в пару строчек с использованием индексированной таблицы :)

http://www.mista.ru/tutor_1c/tz.htm#del

(5) ненене, самый популярный здесь обратным циклом, дабы выборка не сбивалась

(7) +1

Для Сч = -ТЗ_уд.КоличествоСтрок() По -1 Цикл
  ТЗ_уд.ПолучитьСтрокуПоНомеру(-Сч);            
  Если Тз_уд.Предоплата = 1 Тогда
     Сообщить("ДокАкт "+ТЗ_уд.Док+"  Номер строки "+ТЗ_уд.НомерСтроки+" Удаляем!");
     Тз_уд.УдалитьСтроку();
  КонецЕсли;
КонецЦикла;

тз.выбратьСтроки();
пока тз.получитьСтроку()=1 цикл
если (условие = 1 ) тогда
 тз.удалитьСтроку();
 тз.выбратьСтроки();
конецЕсли;
конецЦикла;

(10) А не будет ли оно тормозить на маленькой таблице из пары миллионов строк?

будет конечно , но несколько тысяч удалить можно.

(10) работает, но конечно....

всетаки наверное счетчик нужен

(2)

вот так вроде работает норм

Строчка = 1;
       Пока Строчка <= ТЗ_уд.КоличествоСтрок() Цикл
           Если Тз_уд.ПолучитьЗначение(Строчка,"Предоплата")=1 Тогда
               Тз_уд.УдалитьСтроку(Строчка);
           Иначе
               Строчка = Строчка + 1;
           КонецЕсли;
       КонецЦикла;

(0)см.на проклабе
Конкурс: самый быстрый вариант удаления ненужных строк из Таблицы Значений

или см.(9)

в общем виде:
Для Индекс = -ТЗ.КоличествоСтрок() По -1 Цикл
   ТЗ.ПолучитьСтрокуПоНомеру(-Индекс);
   Если <ПроверкаУсловий> Тогда
       ТЗ.УдалитьСтроку();
   КонецЕсли;
КонецЦикла;

(0) Получать и удалять строки нужно по индексу. Только нужно учитывать что при удалении строки общее количество индексов уменьшается. Соответственно и индекс следующей строки после удаленной будет таким же как у только что удаленной строки.

(15) еще и самый правильный и безопасный :)

(0)
КвоСтрок = ТЗ.КоличествоСтрок();
Для НомСтрТИ = <Начальный_Номер_Строки> По КвоСтрок Цикл
Если ТЗ.ПолучитьЗначение(НомСтрТИ,"ИМЯ_ПОЛЯ") = <Требуемое_услове> Тогда
ТЗ.УдалитьСтроку(НомСтрТИ);
КвоСтрок = КвоСтрок - 1;
НомСтрТИ = НомСтрТИ - 1;
КонецЕсли;
КонецЦикла;

Правильный вариант (9) с обратным перебором цикла. Ибо самый простой и быстрый.

(15) Хотя вариант с обходом ТЗ с конца к началу более симпатичный.

Мой метод будет быстрее тогда когда мы можем сначала правильно отсортировать ТЗ и найти первый нужный индекс удаляемой строки. И выходить из цикла когда условие не истина. Тогда всю ТЗ не надо пробегать.

Не универсально, но лучше всего (по скорости) подходит когда нужно удалить строки с определенным признаком.

Давненько этого вопроса не было. Я уже тревожится стал.

//======================================================================
       Процедура гд_УдалитьСтрокиТЗ(тз, флСообщить = 0) Экспорт
           //Универсальная процедура быстрой очистки таблицы значений.
           //тз - таблица значений. Перед передачи в эту процедуру тз необходимо обработать след.
           //образом:
           //        - Создать колонку "Удалить"
           //        - пройтись по условию, и пометить удалемые строки флагом 1.
           //флСообщить - флаг, если 1 - сообщается количество удаленных и оставшихся строк.
           //Колонка удалить авт. удаляется из тз.
           
           Попытка
               КолСтрокУд = тз.Итог("Удалить");
           Исключение
               Возврат;
           КонецПопытки;
           
           Если КолСтрокУд <= 0 Тогда
               Если флСообщить = 1 Тогда
                   Сообщить("Не было удалено ни одной строки.");
               КонецЕсли;
               тз.УдалитьКолонку("Удалить");
               Возврат;
           КонецЕсли;
           
           КолСтрок = тз.КоличествоСтрок();
           Если КолСтрок = КолСтрокУд Тогда
               тз.УдалитьСтроки();
               Если флСообщить = 1 Тогда
                   Сообщить("Таблица полностью очищена.", "I");
               КонецЕсли;
           Иначе
               ТЗРаб = СоздатьОбъект("ТаблицаЗначений");
               тз.Выгрузить(ТЗРаб);
               ТЗРаб.Сортировать("+Удалить");
               ТЗРаб.Выгрузить(тз,1,КолСтрок - КолСтрокУд);
               ТЗРаб = 0;
               Если флСообщить = 1 Тогда
                   Сообщить("Из " + КолСтрок + " строк таблицы, было удалено " +
                   КолСтрокУд + ". Осталось - " + тз.КоличествоСтрок() + " строк.", "I");
               КонецЕсли;                
           КонецЕсли;
           тз.УдалитьКолонку("Удалить");
           
       КонецПроцедуры // УдалитьСтрокиТЗ

(19) Самый простой в (1)

(23) Самый простой в (1) сильно страдает от плохой читабельности. А посему некошерен при сколько-нибудь серьёзном проекте с N разработчиками и текучкой кадров.

самый быстрый и беспроблемный способ в (15). Сам таким пользуюсь

(23)

(c) Эльниньо

(24) в твоем случае просче так

Стр=0;
Пока ТЗ_уд.НайтиЗначение(1,Стр,"Предоплата")=1 Цикл
   ТЗ_уд.УдалитьСтроку();
   Стр=0;
КонецЦикла;

ТЗ_уд.УдалитьСтроку(Стр);

(27) Если точно известно, что удаляемых строк мало, возможно и так. При большой таблице и большом количестве удаляемых строк будет не только проще, но еще и медленней, и печальней.

(24) Ничем не более плохочитаем по сравнение со всем остальным, я бы сказал даже запоминается лучше ибо неожиданно и красиво. Скажем метод NS как самый быстрый тоже не очень то читаем, но используется часто, ибо скорость нужна...

(0) Шо? Опять?

(27)(30) Два вложенных цикла делают один обход таблицы значений построчно. Используется некошерная особенность 1С, что получение атрибута таблицы при невыбранной строке возвращает пустое значение вместо фатальной ошибки. Используется недокументированное поведение 1С в случае удаления последней строки таблицы (позиционирование строки после удаления текущей).
Да, я нуден, но неужели вы это называете хорошим стилей программирования?

(32) Да, вариант (1) я называю хорошим стилем программирования, ибо Красиво. Если ты не видишь этой красоты, то извини, о вкусах не спорят...

+(32) Если уж на то пошло, то вариант NS тоже использует именно особенности 1С, тем не менее ты вряд ли будешь утверждать, что он некошерен...

(34) Какие особенности?

Все варианты с УдалитьСтроку() годятся только для ТЗ < 100 строк, ибо медленно.

(33) Я ж не про красоту. А про читабельность. Попробуй проведи эксперимент - отлови Nцать произвольных 1Сников и спроси их, что делает этот код. На мой взгляд, если у заметного количества опрошенных время на правильный ответ займёт больше нескольких секунд - код плохой. И это еще идеальный выхолощенный вариант, когда примитивое однострочное условие на удаление и нет каких-то других выполняемых действий в цикле.

(29) отсортируй и будет простой цикл, не быстро но просто

(36) Что за читабельность такая? Компьютер читает - значит читабельно.

(38) не умничай

(36) вот въехать в запрос на восьмерке на тысячу строчек с кучей подзапросов трудно, а если кто-то понять не может пару вложенных циклов, то зря в 1с пошел...

(0) Зачем? Не ешьте что не надо.. мешает - выгрузите в другую таблицу.. заодно и от лишней поиибени избавитесь.. ох уж эти восьмершники.. - даже не представляют, что адинасс умеет и на 128 метрах памяти с целкой 500-й работать..

(36) Многие крутые одинэсники сходу смеялись над ним, потом извинялись.
И что теперь - писать код в расчёте на будущих прогеров тугодумов?

(42) подумайте на досуге, может быть лучше котёнка с дерева снять, чем услаждать своё самомнение сложностью написанного кода?

(43) Проще этого только код в (27)

Проще - не проще...
Совсем забыли, что речь в (0):"v7: Как правильно удалить строки таблицы значений".
Там утверждается, что правильно так, как в (0).
Разошлись...
А вопрос никто и не задавал.