Можно ли программно распечатать табличную часть документа 8.1-8.2

Функция ВывестиТаблицуЗначений(П) Экспорт
//Назначение: Выводит таблицу значений в макет
//ДатаСоздания: 20070221
//Автор: Fixin
//Тестирована: Да
//$П:                     Структура параметров
//$П.ТЗ:                 Таблица значений, выводимая в отчет
//$П.Макет:             Макет, который используется для вывода в отчет, может отсутствовать
//$П.Т:                 Таблица, в которую выводить отчет, если не задана, создается
//$П.ПараметрыШапки:     Параметры, передаваемые в шапку
//$П.ПараметрыПодвала:     Параметры, передаваемые в подвал
//$П.ИмяШапки:             Имя шапки в макете, по умолчанию Шапка
//$П.ИмяСтроки:         Имя строки в макете, по умолчанию Строка
//$П.Показывать:         Показывать ли таблицу, по умолчанию истина
//$П.ИмяПодвала:         Имя подвала, по умолчанию Подвал
//$П.Показывать:         Показывать ли таблицу, по умолчанию истина
//$П.РасчитыватьИтоги:     Расчитывать ли итоги, по умолчанию истина
//Описание:
//    Сначала выводится шапка, затем строки, затем подвал.
//    Если указан флаг "Расчитывать итоги", то подвал заполняется итогами таблицы,
//    а затем из структуры "Параметры подвала".
//Пример:
//    ВывестиТаблицуЗначений(Новый Структура("ТЗ, ЗаголовокОкна", ТЗ, "Моя ТЗ"));

#Если Клиент Тогда
    Перем
        ТЗ,
        Макет,
        Т,
        ПараметрыШапки,
        ПараметрыПодвала,
        ИмяШапки,
        ИмяСтроки,
        ИмяПодвала,
        Показывать,
        РасчитыватьИтоги,
        НачальнаяСтрока, ЗаголовокОкна;

    П.Свойство("ЗаголовокОкна", ЗаголовокОкна);
    П.Свойство("ТЗ", ТЗ);
    П.Свойство("Макет", Макет);
    П.Свойство("Т", Т);
    П.Свойство("ПараметрыШапки", ПараметрыШапки);
    П.Свойство("ПараметрыПодвала", ПараметрыПодвала);
    Если НЕ П.Свойство("ИмяШапки", ИмяШапки) Тогда
        ИмяШапки="Шапка";
    КонецЕсли;
    Если НЕ П.Свойство("ИмяСтроки", ИмяСтроки) Тогда
        ИмяСтроки="Строка";
    КонецЕсли;
    Если НЕ П.Свойство("ИмяПодвала", ИмяПодвала) Тогда
        ИмяПодвала="Подвал";
    КонецЕсли;
    Если НЕ П.Свойство("Показывать", Показывать) Тогда
        Показывать=Истина;
    КонецЕсли;
    Если НЕ П.Свойство("РасчитыватьИтоги", РасчитыватьИтоги) Тогда
        РасчитыватьИтоги=Истина;
    КонецЕсли;

    //Если таблица не задана, создаем ее
    Если Т=Неопределено Тогда
        Т=Новый ТабличныйДокумент();
        НачальнаяСтрока=1;
    Иначе
        НачальнаяСтрока=Т.ВысотаТаблицы+1;
    КонецЕсли;


    //Выводим шапку через макет
    Если ИмяШапки<>Неопределено И Макет<>Неопределено Тогда
        Шапка=Макет.ПолучитьОбласть(ИмяШапки);
        Если ПараметрыШапки<>Неопределено Тогда
            Шапка.Параметры.Заполнить(ПараметрыШапки);
        КонецЕсли;
        Т.Вывести(Шапка);
    Иначе
        //выводим шапку непосредственно в ячейки
        Для Каждого Кол ИЗ ТЗ.Колонки Цикл
            Заг=СокрЛП(Кол.Заголовок);
            Заг=?(Заг="",Кол.Имя, Заг);
            Т.Область(НачальнаяСтрока, 1+ТЗ.Колонки.Индекс(Кол), НачальнаяСтрока, 1+ТЗ.Колонки.Индекс(Кол)).Текст=Заг;
        КонецЦикла;
    КонецЕсли;

    Для Каждого Стр ИЗ ТЗ Цикл
        Если ИмяСтроки<>Неопределено И Макет<>Неопределено Тогда
            Строка=Макет.ПолучитьОбласть(ИмяСтроки);
            Строка.Параметры.Заполнить(Стр);
            Т.Вывести(Строка);
        Иначе
            //выводим строки
            Для Каждого Кол ИЗ ТЗ.Колонки Цикл
                Т.Область(НачальнаяСтрока+1+ТЗ.Индекс(Стр), 1+ТЗ.Колонки.Индекс(Кол), НачальнаяСтрока+1+ТЗ.Индекс(Стр), 1+ТЗ.Колонки.Индекс(Кол)).Текст=Стр[Кол.Имя];
            КонецЦикла;
        КонецЕсли;
    КонецЦикла;

    Если ИмяПодвала<>Неопределено И Макет<>Неопределено Тогда
        Подвал=Макет.ПолучитьОбласть(ИмяПодвала);
        Если РасчитыватьИтоги=истина Тогда
            ПараметрыИтогов=Новый Структура();
            Для Каждого Кол ИЗ ТЗ.Колонки Цикл
                ПараметрыИтогов.Вставить(Кол.Имя, ТЗ.Итог(Кол.Имя));
            КонецЦикла;
            Подвал.Параметры.Заполнить(ПараметрыИтогов);
        КонецЕсли;

        Если ПараметрыПодвала<>Неопределено Тогда
            Подвал.Параметры.Заполнить(ПараметрыПодвала);
        КонецЕсли;
        Т.Вывести(Подвал);
    КонецЕсли;

    Если Показывать Тогда
        Т.Показать(ЗаголовокОкна);
    КонецЕсли;
    Возврат Т;
#КонецЕсли
КонецФункции