СКД: программная установка ограничения доступности полей

Предположим, есть код программного построения отчета в СКД:

    //1. создаем схему компоновки данных
    СхемаКомпоновкиДанных = Новый СхемаКомпоновкиДанных;

    //1.1 определяем источник данных для схемы
    //для наших целей - текущая ИБ
    Источник = СхемаКомпоновкиДанных.ИсточникиДанных.Добавить();
    Источник.Имя = "ЛокальнаяБаза";
    Источник.СтрокаСоединения = "";
    Источник.ТипИсточникаДанных = "Local";

    //1.2 определяем набор данных
    НаборДанных = СхемаКомпоновкиДанных.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));
    НаборДанных.Имя = "Продажи";
    НаборДанных.ИсточникДанных = "ЛокальнаяБаза";
    НаборДанных.АвтоЗаполнениеДоступныхПолей = Ложь;
    НаборДанных.Запрос = (
        "ВЫБРАТЬ
        |    1 КАК Колонка1,
        |    2 КАК Колонка2"
    );

    //1.2.1 добавляем поля
    ПолеНабораДанных = НаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));
    ПолеНабораДанных.Поле = "Колонка1";
    ПолеНабораДанных.ПутьКДанным = "Колонка1";

    ПолеНабораДанных.Поле = "Колонка2";
    ПолеНабораДанных.ПутьКДанным = "Колонка2";
    ПолеНабораДанных.ОграничениеИспользования.Группировка = Истина;
    ПолеНабораДанных.ОграничениеИспользования.Поле = Истина;
    ПолеНабораДанных.ОграничениеИспользования.Порядок = Истина;
    ПолеНабораДанных.ОграничениеИспользования.Условие = Истина;
    ПолеНабораДанных.ОграничениеИспользованияРеквизитов.Группировка = Истина;
    ПолеНабораДанных.ОграничениеИспользованияРеквизитов.Поле = Истина;
    ПолеНабораДанных.ОграничениеИспользованияРеквизитов.Порядок = Истина;
    ПолеНабораДанных.ОграничениеИспользованияРеквизитов.Условие = Истина;


    //2. создаем настройки для схемы
    НастройкиКомпоновкиДанных = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;

    //2.1 определяем структуру
    //2.1.1 добавляем группировку "Номенклатура"
    Группировка = НастройкиКомпоновкиДанных.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));

    ПолеГруппировки = Группировка.ПоляГруппировки.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
    ПолеГруппировки.Использование = Истина;
    ПолеГруппировки.Поле = Новый ПолеКомпоновкиДанных("Колонка1");

    //2.2 определим выбранные поля
    ВыбранноеПоле = НастройкиКомпоновкиДанных.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
    ВыбранноеПоле.Заголовок = "Колонка1";
    ВыбранноеПоле.Использование = Истина;
    ВыбранноеПоле.Поле = Новый ПолеКомпоновкиДанных("Колонка1");

    //3. компонуем
    КомпНастроек = Новый КомпоновщикНастроекКомпоновкиДанных;
    КомпНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаКомпоновкиДанных));
    КомпНастроек.ЗагрузитьНастройки(НастройкиКомпоновкиДанных);
    НастройкиКомпоновкиДанных = КомпНастроек.ПолучитьНастройки();

    //4. готовим макет
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    Макет = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновкиДанных);

    //5. исполняем макет
    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(Макет);
    ПроцессорКомпоновки.Сбросить();

    //6. выводим результат
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ТабДок = Новый ТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ТабДок);
    ПроцессорВывода.НачатьВывод();
    ЭлементРезультата =  ПроцессорКомпоновки.Следующий();
    Пока ЭлементРезультата <> Неопределено Цикл
        ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
        ЭлементРезультата = ПроцессорКомпоновки.Следующий();
    КонецЦикла;
    ПроцессорВывода.ЗакончитьВывод();

    ТабДок.Показать();