Варианты оптимизации запроса ?

1С v8

21.10.13

✎

23:38

ВЫБРАТЬ
    ПродукцияВРезервеНаСкладахОстатки.Склад,
    ПродукцияВРезервеНаСкладахОстатки.Номенклатура,
    ПродукцияВРезервеНаСкладахОстатки.Партия,
    ПродукцияВРезервеНаСкладахОстатки.КоличествоОстаток
ПОМЕСТИТЬ ВТПродукцияВРезервеНаСкладахОстатки
ИЗ
    РегистрНакопления.ПродукцияВРезервеНаСкладах.Остатки(
            &Дата,
            Организация = &Организация
                И Склад В (&СкладРеализации)) КАК ПродукцияВРезервеНаСкладахОстатки

ИНДЕКСИРОВАТЬ ПО
    ПродукцияВРезервеНаСкладахОстатки.Партия
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура) КАК Субконто1,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто2 КАК Справочник.Партии) КАК Субконто2,
    ХозрасчетныйОстатки.КоличествоОстатокДт,
    ХозрасчетныйОстатки.КоличествоОстатокКт
ПОМЕСТИТЬ ОстаткиХозрасчетный
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Остатки(
            &Дата,
            Счет = &СчетУчета,
            &ВидыСубконто,
            Организация = &Организация
                И Субконто3 В (&СкладРеализации) И Субконто2.Тара.ЛокальныйКодПродукции < 20
                        И Субконто2.Тара.ЛокальныйКодПродукции > 9
                    ИЛИ Организация = &Организация
                        И Субконто3 В (&СкладРеализации)
                        И Субконто2.Тара.ЛокальныйКодПродукции > 39
                        И Субконто2.Тара.ЛокальныйКодПродукции < 50
                    ИЛИ Организация = &Организация
                        И Субконто3 В (&СкладРеализации)
                        И Субконто2.Тара.ЛокальныйКодПродукции = 99) КАК ХозрасчетныйОстатки

ИНДЕКСИРОВАТЬ ПО
    Субконто2
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).Ссылка КАК Ссылка,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).Услуга КАК Услуга,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).Родитель КАК Родитель,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).ПометкаУдаления КАК ПометкаУдаления,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).ЭтоГруппа КАК ЭтоГруппа,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).Код КАК Код,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).Наименование КАК Наименование,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).БазоваяЕдиницаИзмерения КАК БазоваяЕдиницаИзмерения,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).КодПродукции КАК КодПродукции,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).ЛокальныйКодПродукции КАК ЛокальныйКодПродукции,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).Тара КАК Тара,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто2 КАК Справочник.Партии).КоличествоВУпаковке КАК КоличествоВУпаковке,
    ПродукцияВРезервеНаСкладахОстатки.КоличествоОстаток КАК КоличествоВРезерве,
    ХозрасчетныйОстатки.КоличествоОстатокДт КАК КоличествоОстатокДт,
    ХозрасчетныйОстатки.КоличествоОстатокКт КАК КоличествоОстатокКт,
    ХозрасчетныйОстатки.Субконто1 КАК Субконто1
ПОМЕСТИТЬ ВТОстатки
ИЗ
    ОстаткиХозрасчетный КАК ХозрасчетныйОстатки
        ЛЕВОЕ СОЕДИНЕНИЕ ВТПродукцияВРезервеНаСкладахОстатки КАК ПродукцияВРезервеНаСкладахОстатки
        ПО ХозрасчетныйОстатки.Субконто2 = ПродукцияВРезервеНаСкладахОстатки.Партия

ИНДЕКСИРОВАТЬ ПО
    Субконто1
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЦеныНоменклатурыСрезПоследних.Номенклатура
ПОМЕСТИТЬ ВТЦеныНоменклатурыСрезПоследних
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
            ,
            Прейскурант = &Прейскурант
                ИЛИ Протокол = &Протокол) КАК ЦеныНоменклатурыСрезПоследних

ИНДЕКСИРОВАТЬ ПО
    ЦеныНоменклатурыСрезПоследних.Номенклатура
;ВЫБРАТЬ
    ВТОстаткиХоз.Ссылка КАК Номенклатура,
    ВТОстаткиХоз.Код КАК Код,
    ВТОстаткиХоз.ЛокальныйКодПродукции КАК КодПродукции,
    ВТОстаткиХоз.ЭтоГруппа КАК ЭтоГруппа,
    ВТОстаткиХоз.ПометкаУдаления КАК ПометкаУдаления,
    ВТОстаткиХоз.Услуга КАК Услуга,
    ВТОстаткиХоз.Родитель КАК Родитель,
    ВТОстаткиХоз.БазоваяЕдиницаИзмерения КАК ЕдиницаИзмерения,
    ВТОстаткиХоз.Ссылка.Представление КАК ПредставлениеНоменклатура,
    ВЫБОР
        КОГДА ВТОстаткиХоз.ЭтоГруппа
            ТОГДА "Группа"
        ИНАЧЕ ВТОстаткиХоз.Ссылка.НоменклатурнаяГруппа.Представление
    КОНЕЦ КАК ПредставлениеНоменклатурнаяГруппа,
    ЛОЖЬ КАК ПереходитьВверх,
    ВТОстаткиХоз.БазоваяЕдиницаИзмерения.Наименование КАК ПредставлениеЕдиницаИзмерения,
    СУММА(ЕСТЬNULL(ВТОстаткиХоз.КоличествоВРезерве, 0) / ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоВУпаковке <> 0
                ТОГДА ВТОстаткиХоз.КоличествоВУпаковке
            ИНАЧЕ 1
        КОНЕЦ) КАК КоличествоЗаказаное,
    СУММА((ЕСТЬNULL(ВТОстаткиХоз.КоличествоОстатокДт, 0) - ЕСТЬNULL(ВТОстаткиХоз.КоличествоОстатокКт, 0) - ЕСТЬNULL(ВТОстаткиХоз.КоличествоВРезерве, 0)) / ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоВУпаковке <> 0
                ТОГДА ВТОстаткиХоз.КоличествоВУпаковке
            ИНАЧЕ 1
        КОНЕЦ) КАК КоличествоСвободныйОстаток,
    СУММА((ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоОстатокДт ЕСТЬ NULL
                ТОГДА 0
            ИНАЧЕ ВТОстаткиХоз.КоличествоОстатокДт
        КОНЕЦ - ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоОстатокКт ЕСТЬ NULL
                ТОГДА 0
            ИНАЧЕ ВТОстаткиХоз.КоличествоОстатокКт
        КОНЕЦ) / ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоВУпаковке <> 0
                ТОГДА ВТОстаткиХоз.КоличествоВУпаковке
            ИНАЧЕ 1
        КОНЕЦ) КАК КоличествоОстатокОрганизации
ИЗ
    ВТЦеныНоменклатурыСрезПоследних КАК ЦеныНоменклатурыСрезПоследних
        ЛЕВОЕ СОЕДИНЕНИЕ ВТОстатки КАК ВТОстаткиХоз
        ПО ЦеныНоменклатурыСрезПоследних.Номенклатура = ВТОстаткиХоз.Субконто1

СГРУППИРОВАТЬ ПО
    ВТОстаткиХоз.Ссылка,
    ВТОстаткиХоз.Код,
    ВТОстаткиХоз.ЭтоГруппа,
    ВТОстаткиХоз.ПометкаУдаления,
    ВТОстаткиХоз.Услуга,
    ВТОстаткиХоз.Родитель,
    ВТОстаткиХоз.БазоваяЕдиницаИзмерения,
    ВТОстаткиХоз.Ссылка.Представление,
    ВЫБОР
        КОГДА ВТОстаткиХоз.ЭтоГруппа
            ТОГДА "Группа"
        ИНАЧЕ ВТОстаткиХоз.Ссылка.НоменклатурнаяГруппа.Представление
    КОНЕЦ,
    ВТОстаткиХоз.ЛокальныйКодПродукции,
    ВТОстаткиХоз.БазоваяЕдиницаИзмерения.Наименование

УПОРЯДОЧИТЬ ПО
    ВТОстаткиХоз.ЛокальныйКодПродукции

1 crazydimka

21.10.13

✎

23:41

Помогите идеями кто чем сможет, изменения структуры метаданных не предлагать, индексирование измерений тоже=) Спасибо.

2 Лефмихалыч

21.10.13

✎

23:42

план запроса посмотреть не предлагать?

3 crazydimka

21.10.13

✎

23:44

это вроде сложно, надо разбираться, да и сейчас нет под рукой SQL... на файловой пишу.

пока писал пришла идея заменить СчетУчета на Занчение(ПланыСчетов.Хозрасчетный.СчетГотовойПродукции), т.к. счет учета применяется один, или это не ускорит ?

4 Лефмихалыч

21.10.13

✎

23:46

(3) это ускорит только на строчку Запрос.УстановитьЗначениеПараметра()

ты в отчаянии, если думаешь, что кому-то интересно будет это (0) читать внимательно

5 crazydimka

21.10.13

✎

23:47

ммм.... копи паст в консоль запросов и делов) ну кто его знает, надежда!=)

6 crazydimka

21.10.13

✎

23:49

кстати замер производительнсти на файловой СУБД и SQL СУБД будет отличаться, т.к. передалал все соединения с ВиртТаблицами на ВремТаблицы и прирост только 4%....

7 Лефмихалыч

21.10.13

✎

23:49

от херовой горы ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура) стоило бы отказаться посредством дополнительной временной таблицы, в которой только одно поле кастовать

8 crazydimka

21.10.13

✎

23:50

(6) это вопрос=)

9 Лефмихалыч

21.10.13

✎

23:50

а вообще, проблема в условиях вирутальной таблицы ОстаткиХозрасчетный

это польный пердоманокль

10 Лефмихалыч

21.10.13

✎

23:51

(6) может будет, а может нет. Запрос - гогно и к типу СУБД это не имеет отношения

11 crazydimka

21.10.13

✎

23:53

(9) Условие по организации и складу надо вынести выше над "ИЛИ", не заметил, спасибо!

12 crazydimka

21.10.13

✎

23:54

(7) и за это спасибо, приму к сведению

13 Лефмихалыч

21.10.13

✎

23:56

"Субконто2.Тара.Лок"

ты предсавляешь себе, сколько там соединений нарисовалось?

14 crazydimka

21.10.13

✎

23:58

(13) так точно ВЫРАЖАЛКУ ЗАБЫЛ!

15 Лефмихалыч

21.10.13

✎

23:59

нахрена три раза вот это

ИЛИ Организация = &Организация
И Субконто3 В (&СкладРеализации)

?

для красоты?

16 Лефмихалыч

21.10.13

✎

23:59

короче, твой запрос - хлам. Убей его

17 crazydimka

22.10.13

✎

00:01

(16) ну чего, если все подправить, что ты посоветовад будет куда красивее)

18 Armando

22.10.13

✎

00:14

>> ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).Ссылка КАК Ссылка,
Здесь просто ХозрасчетныйОстатки.Субконто1 КАК Ссылка.
Все остальные ВЫРАЗИТЬ в этом пакете по отношению к ХозрасчетныйОстатки.Субконто1 можно убрать, т.к. ты его уже выразил в предыдущем пакете.

Как сказал (15) этот кусок надо вынести "за скобки".

19 crazydimka

22.10.13

✎

00:16

(18) спасибо, убераю

20 Armando

22.10.13

✎

00:21

Еще бы на Субкното1 условие наложить, если есть возможность. Чтоб индексы по Субконто2 и 3 задействовались. Иначе Table Scan по ним будет, или как он там называется.

21 crazydimka

22.10.13

✎

00:24

а поможет ли изменение &Дата, если оно равно конец сегодняшнего дня на "пустоезначение", остатки на ТА получаются вроде быстрее ? или я не прав ? (20) я думаю можно получить ВремТаблицу по срезупоследних регистра ЦеныНоменклатуры и выгрузить колонку с номенклатурой в это условие(т.к. главное условие что бы в подбор попадали остакти только с установленными ценами), или это не "рентабельно" ?

22 Armando

22.10.13

✎

00:37

(21) >> а поможет ли изменение &Дата, если оно равно конец сегодняшнего дня на "пустоезначение"
Скорее всего не поможет.

>> получить ВремТаблицу по срезупоследних регистра ЦеныНоменклатуры и выгрузить колонку с номенклатурой в это условие
Надо пробовать

(3) План запроса можно и на файловой базе смотреть. Через ТЖ.
Недавно стал юзать "Инструменты разработчика". Анализ ТЖ доставляет. Там можно прям из консоли запросов включить ТЖ и посмотреть как этот запрос на БД исполняется.

23 crazydimka

22.10.13

✎

00:44

(22) спасибо попробую разобраться с помощью ТЖ

24 Armando

22.10.13

✎

00:48

Кстати, счет активный или пассивный? Зачем количество по Дт и Кт анализируется?

25 Полотенчик

22.10.13

✎

00:54

Какой хотя бы запрос в пакете долго выполняется? ВТ ОстаткиХозрасчетный долго делается? Мне кажется что Субконто2.Тара.ЛокальныйКодПродукции < 20 в параметрах вирт. таблице не айс. Получи нужные субконто во временную таблицу, и используй "субконто2 в (выбрать субконто из ВТсубконто2)"

26 crazydimka

22.10.13

✎

00:59

(24) Счет Активный, можно использовать КоличествоОстаток ?

27 crazydimka

22.10.13

✎

01:01

(25)
ВТЦеныНоменклатурыСрезПоследних КАК ЦеныНоменклатурыСрезПоследних
        ЛЕВОЕ СОЕДИНЕНИЕ ВТОстатки КАК ВТОстаткиХоз
        ПО ЦеныНоменклатурыСрезПоследних.Номенклатура = ВТОстаткиХоз.Субконто1

50% времени, хотя поля соединения проиндексированы....

28 Armando

22.10.13

✎

01:02

(26) КоличествоОстатокДт или КоличествоОстаток

29 Полотенчик

22.10.13

✎

01:03

соединить по ссылке, которую уже выразил как справочник номенклатура?
ЛЕВОЕ СОЕДИНЕНИЕ ВТОстатки КАК ВТОстаткиХоз
ПО ЦеныНоменклатурыСрезПоследних.Номенклатура = ВТОстаткиХоз.Ссылка

30 crazydimka

22.10.13

✎

01:04

(28) спасибо, полезно

31 crazydimka

22.10.13

✎

01:04

(29) попробую

32 Полотенчик

22.10.13

✎

01:05

и ВТОстаткиХоз, соответственно, проиндексировать по этой ссылке

33 Armando

22.10.13

✎

01:07

(27) Если субконто1 отфильтруешь по номенклатуре из регистра цен, тогда в соединении с ВТЦеныНоменклатурыСрезПоследних и ВТОстаткиХоз можно использовать внутреннее соединение и отказаться от естьnull

34 crazydimka

22.10.13

✎

01:09

(33) спасибо за наводку на внутренее соединение

35 Armando

22.10.13

✎

01:12

(34) покажи хоть как сейчас запрос выглядит?

36 crazydimka

22.10.13

✎

01:15

(35) упс секундочку, я его развалил... минут 15-20 надо, валится на уже существующую ВТ не вьеду вроде один раз ее помещаю...

37 crazydimka

22.10.13

✎

01:29

ВЫБРАТЬ
    ПродукцияВРезервеНаСкладахОстатки.Склад,
    ПродукцияВРезервеНаСкладахОстатки.Номенклатура,
    ПродукцияВРезервеНаСкладахОстатки.Партия,
    ПродукцияВРезервеНаСкладахОстатки.КоличествоОстаток
ПОМЕСТИТЬ ВТПродукцияВРезервеНаСкладахОстатки
ИЗ
    РегистрНакопления.ПродукцияВРезервеНаСкладах.Остатки(
            &Дата,
            Организация = &Организация
                И Склад В (&СкладРеализации)
                И Номенклатура В (&МассивНоменклатуры)
                И Партия В (&МассивПартий)) КАК ПродукцияВРезервеНаСкладахОстатки

ИНДЕКСИРОВАТЬ ПО
    ПродукцияВРезервеНаСкладахОстатки.Партия
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура) КАК Субконто1,
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто2 КАК Справочник.Партии) КАК Субконто2,
    ХозрасчетныйОстатки.КоличествоОстатокДт,
    ХозрасчетныйОстатки.КоличествоОстатокКт
ПОМЕСТИТЬ ОстаткиХозрасчетный
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Остатки(
            &Дата,
            Счет = Значение(ПланСчетов.Хозрасчетный.ГотоваяПродукция),
            &ВидыСубконто,
            (Организация = &Организация И Субконто1 В (&МассивНоменклатуры) И Субконто2 В (&МассивПартий))
                 И (Субконто3 В (&СкладРеализации))) КАК ХозрасчетныйОстатки

ИНДЕКСИРОВАТЬ ПО
    Субконто2
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто1 КАК Справочник.Номенклатура).Ссылка КАК Ссылка,
    ХозрасчетныйОстатки.Субконто1.Услуга КАК Услуга,
    ХозрасчетныйОстатки.Субконто1.Родитель КАК Родитель,
    ХозрасчетныйОстатки.Субконто1.ПометкаУдаления КАК ПометкаУдаления,
    ХозрасчетныйОстатки.Субконто1.ЭтоГруппа КАК ЭтоГруппа,
    ХозрасчетныйОстатки.Субконто1.Код КАК Код,
    ХозрасчетныйОстатки.Субконто1.Наименование КАК Наименование,
    ХозрасчетныйОстатки.Субконто1.БазоваяЕдиницаИзмерения КАК БазоваяЕдиницаИзмерения,
    ХозрасчетныйОстатки.Субконто1.КодПродукции КАК КодПродукции,
    ХозрасчетныйОстатки.Субконто1.ЛокальныйКодПродукции КАК ЛокальныйКодПродукции,
    ХозрасчетныйОстатки.Субконто1.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
    ХозрасчетныйОстатки.Субконто1.Тара КАК Тара,
    ХозрасчетныйОстатки.Субконто2.КоличествоВУпаковке КАК КоличествоВУпаковке,
    ПродукцияВРезервеНаСкладахОстатки.КоличествоОстаток КАК КоличествоВРезерве,
    ХозрасчетныйОстатки.КоличествоОстатокДт КАК КоличествоОстатокДт,
    ХозрасчетныйОстатки.КоличествоОстатокКт КАК КоличествоОстатокКт,
    ХозрасчетныйОстатки.Субконто1 КАК Субконто1
ПОМЕСТИТЬ ВТОстатки
ИЗ
    ОстаткиХозрасчетный КАК ХозрасчетныйОстатки
        ЛЕВОЕ СОЕДИНЕНИЕ ВТПродукцияВРезервеНаСкладахОстатки КАК ПродукцияВРезервеНаСкладахОстатки
        ПО ХозрасчетныйОстатки.Субконто2 = ПродукцияВРезервеНаСкладахОстатки.Партия

ИНДЕКСИРОВАТЬ ПО
    Ссылка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТОстаткиХоз.Ссылка КАК Номенклатура,
    ВТОстаткиХоз.Код КАК Код,
    ВТОстаткиХоз.ЛокальныйКодПродукции КАК КодПродукции,
    ВТОстаткиХоз.ЭтоГруппа КАК ЭтоГруппа,
    ВТОстаткиХоз.ПометкаУдаления КАК ПометкаУдаления,
    ВТОстаткиХоз.Услуга КАК Услуга,
    ВТОстаткиХоз.Родитель КАК Родитель,
    ВТОстаткиХоз.БазоваяЕдиницаИзмерения КАК ЕдиницаИзмерения,
    ВТОстаткиХоз.Ссылка.Представление КАК ПредставлениеНоменклатура,
    ВЫБОР
        КОГДА ВТОстаткиХоз.ЭтоГруппа
            ТОГДА "Группа"
        ИНАЧЕ ВТОстаткиХоз.Ссылка.НоменклатурнаяГруппа.Представление
    КОНЕЦ КАК ПредставлениеНоменклатурнаяГруппа,
    ЛОЖЬ КАК ПереходитьВверх,
    ВТОстаткиХоз.БазоваяЕдиницаИзмерения.Наименование КАК ПредставлениеЕдиницаИзмерения,
    СУММА(ЕСТЬNULL(ВТОстаткиХоз.КоличествоВРезерве, 0) / ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоВУпаковке <> 0
                ТОГДА ВТОстаткиХоз.КоличествоВУпаковке
            ИНАЧЕ 1
        КОНЕЦ) КАК КоличествоЗаказаное,
    СУММА((ЕСТЬNULL(ВТОстаткиХоз.КоличествоОстатокДт, 0) - ЕСТЬNULL(ВТОстаткиХоз.КоличествоОстатокКт, 0) - ЕСТЬNULL(ВТОстаткиХоз.КоличествоВРезерве, 0)) / ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоВУпаковке <> 0
                ТОГДА ВТОстаткиХоз.КоличествоВУпаковке
            ИНАЧЕ 1
        КОНЕЦ) КАК КоличествоСвободныйОстаток,
    СУММА((ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоОстатокДт ЕСТЬ NULL
                ТОГДА 0
            ИНАЧЕ ВТОстаткиХоз.КоличествоОстатокДт
        КОНЕЦ - ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоОстатокКт ЕСТЬ NULL
                ТОГДА 0
            ИНАЧЕ ВТОстаткиХоз.КоличествоОстатокКт
        КОНЕЦ) / ВЫБОР
            КОГДА ВТОстаткиХоз.КоличествоВУпаковке <> 0
                ТОГДА ВТОстаткиХоз.КоличествоВУпаковке
            ИНАЧЕ 1
        КОНЕЦ) КАК КоличествоОстатокОрганизации
ИЗ
    ВТЦеныНоменклатурыСрезПоследних КАК ЦеныНоменклатурыСрезПоследних
        ЛЕВОЕ СОЕДИНЕНИЕ ВТОстатки КАК ВТОстаткиХоз
        ПО ЦеныНоменклатурыСрезПоследних.Номенклатура = ВТОстаткиХоз.Ссылка

СГРУППИРОВАТЬ ПО
    ВТОстаткиХоз.Ссылка,
    ВТОстаткиХоз.Код,
    ВТОстаткиХоз.ЭтоГруппа,
    ВТОстаткиХоз.ПометкаУдаления,
    ВТОстаткиХоз.Услуга,
    ВТОстаткиХоз.Родитель,
    ВТОстаткиХоз.БазоваяЕдиницаИзмерения,
    ВТОстаткиХоз.Ссылка.Представление,
    ВЫБОР
        КОГДА ВТОстаткиХоз.ЭтоГруппа
            ТОГДА "Группа"
        ИНАЧЕ ВТОстаткиХоз.Ссылка.НоменклатурнаяГруппа.Представление
    КОНЕЦ,
    ВТОстаткиХоз.ЛокальныйКодПродукции,
    ВТОстаткиХоз.БазоваяЕдиницаИзмерения.Наименование

УПОРЯДОЧИТЬ ПО
    ВТОстаткиХоз.ЛокальныйКодПродукции

38 crazydimka

22.10.13

✎

01:30

еще не все спаял

39 Armando

22.10.13

✎

01:48

Уже лучше)
Остальное завтра смогу посмотреть

40 crazydimka

22.10.13