Есть обработка, у обработки реквизит - таблица значений.
На управляемой форме размещаю элемент формы (ПутьКДанным = Объект.МояТаблица). При нажатии кнопки на форме процедура обращается к процедуре модуля обработки где циклом происходит заполнение Реквизита МояТаблица. Смотрю под отладчиком, он заполнен как мне надо, но элемент формы пустой!! Тоесть под отладчиком я вижу, что в Объект.МояТаблица содержит значения, а на форме ничего не отображается. Как побороть? PS^ только начал осваивать УФ.

Такою ощущение, что реквизит формы и реквизит объекта живут отдельно.

без кода тут не понять

Колонки надо программно нарисовать.

Модуль формы

&НаКлиенте
Процедура НачатьЗаполнениеАнкеты(Команда)
    ПолучитьВопросыАнкеты();  
КонецПроцедуры

&НаСервере
Процедура ПолучитьВопросыАнкеты()
    ОбработкаОбъект = РеквизитФормыВЗначение("Объект");
    ОбработкаОбъект.ПолучитьВопросы();    
КонецПроцедуры

И "сформироватьКолонки()" тут не прокатит.

(1) Совершенно верно.
Надо в УФ сделать что-то вроде

МойОБъект = РеквизитФормыВЗначение("Объект","ТутТип")
ТЗ = мойОбъект.СформироватьЧтоТОТам()
ЗначениеВРеквизитФормы(ля-ля-ля)

(4) Нафига тут конвертация данных формы?

модуль объекта

Вопросы.Очистить();
    Пока Выборка.Следующий() Цикл
        нСтр = Вопросы.Добавить();
        нСтр.Вопрос = Выборка.Вопрос;
    КонецЦикла;

(7) Что бы обратится к экспортной процедуре объекта.

(8) динамический список не катит? надо именно свою левую ТЗ?

(10) Именно ее, там долбанутые запрос от сторонних разработчиков.

(9) А зачем это в модуле объекта описывать? Хотя, ладно. Вам нужно колонки нарисовать...

(12) Так колонки уже сами обавились, когда я реквизит объекта на форму перетащил.

(13) А с данными они как-то связаны?

(14) Да, путьКданным указан правильно.

(13) Да елки...
Модульную процедуру переделываем в функцию. Возвращаем ТЗ. ТЗ Загружаем или вообще значениеВРеквизитФормы, если колонки совпадают.

(6)(16) Спасибо!!! Взлетело!

ОбработкаОбъект = РеквизитФормыВЗначение("Объект");
ОбработкаОбъект.ПолучитьВопросы();    
ЗначениеВРеквизитФормы(ОбработкаОбъект.Вопросы, Объект.Вопросы");

Опечатка

ЗначениеВРеквизитФормы(ОбработкаОбъект.Вопросы, "Объект.Вопросы");

(17) Ну или так. Развели тут ))). Обычная ошибка при начале работы с УФ )))

Или так, уже было на форуме:

// ПРИМЕЧАНИЕ:
//        Эту процедуру можно разместить в общем модуле, для дальнейшего вызова из любого места
//        Для отображения таблицы необходиом чтобы на форме предварительно был создан реквизит типа "таблица значений",
//        и чтобы он был размещен среди элементов формы (по аналогии, как в этой форме)
//
// ОПИСАНИЕ:
//         Создает и отображает на управляемой форме (8.2) таблицу значений, переданную в качестве параметра
//         Дополнительно может подключить обработчики событий для таблицы
//
// ПАРАМЕТРЫ:
//        УФ - управляемая форма, на которую нужно вывести ТЗ
//        ТЗ - таблица значений, которую нужно отобразить на форме
//        ТЗОбработчиковСобытий - таблица со структурой данных, описывающих обработчики событий. Не обязательна.
//        Процедура обработки события должна именоваться как <ИмяЭлемента + ИмяСобытия>
&НаСервере
Процедура ВывестиТаблицуНаФорму(УФ, ИмяТЗНаФорме, Знач ТЗ, ТЗОбработчиковСобытий = Неопределено) Экспорт
    
    // СОЗДАНИЕ РЕКВИЗИТОВ ФОРМЫ

    МассивДобавляемыхРеквизитов = Новый Массив;
    
    Для Каждого Колонка Из ТЗ.Колонки Цикл
        МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения,ИмяТЗНаФорме ,Колонка.Заголовок));    
    КонецЦикла;
    
    МассивУдаляемыхРеквизитов = УФ.ПолучитьРеквизиты(ИмяТЗНаФорме);
    МассивИменУдаляемыхРеквизитов = Новый Массив;
    Для каждого Элемент Из МассивУдаляемыхРеквизитов Цикл
        МассивИменУдаляемыхРеквизитов.Добавить(ИмяТЗНаФорме + "." + Элемент.Имя);
    КонецЦикла;
    
    УФ.ИзменитьРеквизиты(МассивДобавляемыхРеквизитов,МассивИменУдаляемыхРеквизитов);
    
    // СОЗДАНИЕ ЭЛЕМЕНТОВ ФОРМЫ

    Для каждого Элемент Из МассивУдаляемыхРеквизитов Цикл
        УдаляемыйЭлемент = УФ.Элементы.Найти(ИмяТЗНаФорме + Элемент.Имя);
        УФ.Элементы.Удалить(УдаляемыйЭлемент);
    КонецЦикла;
    
    Для Каждого Колонка Из ТЗ.Колонки Цикл
        НоваяКолонка = УФ.Элементы.Добавить(ИмяТЗНаФорме + Колонка.Имя, Тип("ПолеФормы"), УФ.Элементы[ИмяТЗНаФорме]);
        НоваяКолонка.Заголовок = Колонка.Заголовок;
        НоваяКолонка.ПутьКДанным = ИмяТЗНаФорме + "." + Колонка.Имя;
        НоваяКолонка.Вид = ВидПоляФормы.ПолеВвода;
        НоваяКолонка.РежимРедактирования = РежимРедактированияКолонки.ВходПриВводе;    
    КонецЦикла;    
    
    УФ[ИмяТЗНаФорме].Загрузить(ТЗ);
    
    // Привязка обработчиков событий

    Если ТЗОбработчиковСобытий = Неопределено Тогда
        Возврат;
    КонецЕсли;    
    
    Для Каждого Строка Из ТЗОбработчиковСобытий Цикл
        УФ.Элементы[Строка.ИмяЭлемента].УстановитьДействие(Строка.ИмяСобытия, Строка.ИмяЭлемента + Строка.ИмяСобытия);
    КонецЦикла;    
    
КонецПроцедуры