Чет не пойму, можно ли с клиента прочитать файл, лежащий на сервере в обычной (незашаренной)папке. Если можно то как?

Прочитать на сервере, отдать через временное хранилище на клиента

Прочитать на сервере как?

?

(3) Ух тяжелый случай.
Давай так, ты это где хош сделать, я как подозреваю это действие какойто кнопки на форме?

(4) Хочу сделать из модуля со свойством "сервер" (обработка какого-либо события)

(5) а что мешает?
прочитал файл в двоичные данные, положил во времянку. ссылку на времянку вернул на клиента. на клиенте открыл двоичные данные из времянки.

(6)т.е. в серверном модуле ПоместитьВоВременноеХранилище
а затем в клиентском ПолучитьИзВременногоХранилища ?

да

Весь код условно делится на клиентский и серверный. Разделение происходит директивами компиляции "&НаКлиенте", "&НаСервере" и т.п. Весь серверный код выполняется в контексте сервера, а клиентский в контексте клиента. При этом в модуле формы может присутствовать как клиентский, так и серверный код.
С клиента на сервер и обратно могут передаваться только типы данных в описании которых указано, что они стерилизуются. В основном это примитивные типы данных: Строка, Число, Дата и т.п.
Передать прочие данные между клиентом и сервером можно по средством временного хранилища. Данные читаются на сервере, помещаются во временное хранилище, а на клиент возвращается адрес во временном хранилище. На клиенте данные по этому адресу читаются и обрабатываются, если они могу существовать в контексте клиента. При этом данные файла читаются объектом «Двоичные данные». Он может быть помещен во временное хранилище на сервере и на клиенте получен оттуда и сохранен в файл.
В вашем случае необходимо реализовать:
1. Серверную функцию читающую файл из указанной папки (на сервере). Имя папки передается параметром. После прочтения двоичных данных файла их необходимо поместить во временное хранилище, а на клиент вернуть адрес.
2. На клиенте получить двоичные данные по адресу из временного хранилища, а затем сохранить их в файл на клиенте.

&НаКлиенте
Процедура ИмяФайлаКлиентНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
    
    Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);
    
    Если Диалог.Выбрать() Тогда
        
        ИмяФайлаКлиент = Диалог.ПолноеИмяФайла;
        
    КонецЕсли;
    
КонецПроцедуры

&НаКлиенте
Процедура СкопироватьФайл(Команда)
    
    Текст = НСтр("ru = 'Файл не найден на сервере'");
    
    АдресДанных = ПрочитатьФайлСервер(ИмяФайлаСервер, УникальныйИдентификатор);
    Если ЭтоАдресВременногоХранилища(АдресДанных) Тогда
        
        ДвоичныеДанные = ПолучитьИзВременногоХранилища(АдресДанных);
        Если ТипЗнч(ДвоичныеДанные) = Тип("ДвоичныеДанные") Тогда
            
            ДвоичныеДанные.Записать(ИмяФайлаКлиент);
            
            Текст = НСтр("ru = 'Файл сохранен на клиенте'");
            
        КонецЕсли;
        
    КонецЕсли;
    
    Сообщение = Новый СообщениеПользователю;
    Сообщение.Текст = Текст;
    Сообщение.Сообщить();
    
КонецПроцедуры

&НаСервереБезКонтекста
Функция ПрочитатьФайлСервер(Знач ИмяФайла, Знач УникальныйИдентификаторФормы)
    
    АдресДанных = Неопределено;
    
    Файл = Новый Файл(ИмяФайла);
    Если Файл.Существует() Тогда
        
        ДанныеНаСервере = Новый ДвоичныеДанные(ИмяФайла);
        АдресДанных = ПоместитьВоВременноеХранилище(ДанныеНаСервере, УникальныйИдентификаторФормы);
        
    КонецЕсли;
    
    Возврат АдресДанных;
    
КонецФункции

(9) "типы данных в описании которых указано, что они стерилизуются.
Что они делают? )

:))) Ворд проклятый :)))

не "стерилизуются", а "сериализуются" :)))

(8)-(9) Большое спасибо. Все понял.

(11) ссылки тоже сериализуются, не только примитивные типы.

(13) Это все у Радчёнка написано и в синтаксис помошнике. Кстати ссылка это строка!!! GUID так называемый.