СКД

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ВЫБОР
        КОГДА ЕПСБУОстаткиИОбороты.Учреждение ЕСТЬ NULL
            ТОГДА РасчетАмортизацииОССрезПоследних.ОС.Учреждение
        ИНАЧЕ ЕПСБУОстаткиИОбороты.Учреждение
    КОНЕЦ КАК Учреждение,
    ЕПСБУОстаткиИОбороты.Баланс КАК Баланс,
    ВЫБОР
        КОГДА ЕПСБУОстаткиИОбороты.Счет ЕСТЬ NULL
            ТОГДА РасчетАмортизацииОССрезПоследних.ОС.СчетУчета
        ИНАЧЕ ЕПСБУОстаткиИОбороты.Счет
    КОНЕЦ КАК Поле3,
    ВЫБОР
        КОГДА ЕПСБУОстаткиИОбороты.КВД ЕСТЬ NULL
            ТОГДА РасчетАмортизацииОССрезПоследних.ОС.КВД
        ИНАЧЕ ЕПСБУОстаткиИОбороты.КВД
    КОНЕЦ КАК КВД,
    ВЫБОР
        КОГДА ЕПСБУОстаткиИОбороты.КБК ЕСТЬ NULL
            ТОГДА РасчетАмортизацииОССрезПоследних.ОС.КБК
        ИНАЧЕ ЕПСБУОстаткиИОбороты.КБК
    КОНЕЦ КАК КБК,
    ЕСТЬNULL(ЕПСБУОстаткиИОбороты.СуммаНачальныйОстатокКт, 0) КАК АмортизацияНачПериода,
    ЕСТЬNULL(ЕПСБУОстаткиИОбороты.СуммаКонечныйОстатокКт, 0) КАК АмортизацияКонПериода,
    ЕСТЬNULL(ЕПСБУОстаткиИОбороты.СуммаОборотДт, 0) КАК АмортизацияСписано,
    ЕСТЬNULL(ЕПСБУОстаткиИОбороты.СуммаОборотКт, 0) КАК АмортизацияНачислено,
    РасчетАмортизацииОССрезПоследних.ОС КАК ОС,
    ВЫБОР
        КОГДА ВЫРАЗИТЬ(ЕПСБУОстаткиИОбороты.Субконто2 КАК Справочник.ОсновныеСредства).ПорядокПогашенияСтоимости ЕСТЬ NULL
            ТОГДА РасчетАмортизацииОССрезПоследних.ОС.ПорядокПогашенияСтоимости
        ИНАЧЕ ВЫРАЗИТЬ(ЕПСБУОстаткиИОбороты.Субконто2 КАК Справочник.ОсновныеСредства).ПорядокПогашенияСтоимости
    КОНЕЦ КАК Поле1,
    ВЫБОР
        КОГДА ВЫРАЗИТЬ(ЕПСБУОстаткиИОбороты.Субконто2 КАК Справочник.ОсновныеСредства).СпособНачисленияАмортизации ЕСТЬ NULL
            ТОГДА РасчетАмортизацииОССрезПоследних.ОС.СпособНачисленияАмортизации
        ИНАЧЕ ВЫРАЗИТЬ(ЕПСБУОстаткиИОбороты.Субконто2 КАК Справочник.ОсновныеСредства).СпособНачисленияАмортизации
    КОНЕЦ КАК Поле2,
    ЕСТЬNULL(РасчетАмортизацииОССрезПоследних.СрокПолезногоИспользования, 0) КАК СрокПолезногоИспользования,
    ЕСТЬNULL(РасчетАмортизацииОССрезПоследних.СрокИспользованияДляВычисленияАмортизации, 0) КАК СрокИспользованияДляВычисленияАмортизации,
    ЕСТЬNULL(РасчетАмортизацииОССрезПоследних.СтоимостьДляВычисленияАмортизации, 0) КАК СтоимостьДляВычисленияАмортизации
ПОМЕСТИТЬ АмортизацияЗаПериод
ИЗ
    РегистрСведений.РасчетАмортизацииОС.СрезПоследних({(&КонецПериода)}, ) КАК РасчетАмортизацииОССрезПоследних
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.ЕПСБУ.ОстаткиИОбороты({(&НачалоПериода)}, {(&КонецПериода)}, , ДвиженияИГраницыПериода, Счет В ИЕРАРХИИ (&СчетАмор), , ) КАК ЕПСБУОстаткиИОбороты
        ПО (ЕПСБУОстаткиИОбороты.Субконто2 = РасчетАмортизацииОССрезПоследних.ОС)
{ГДЕ
    ЕПСБУОстаткиИОбороты.Учреждение.*,
    ЕПСБУОстаткиИОбороты.Баланс.*,
    ЕПСБУОстаткиИОбороты.Счет.*,
    ЕПСБУОстаткиИОбороты.КВД.*,
    ЕПСБУОстаткиИОбороты.КБК.*}
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ОстатокНаКонецПериода.Учреждение,
    ОстатокНаКонецПериода.Баланс,
    ОстатокНаКонецПериода.Счет,
    ОстатокНаКонецПериода.КВД,
    ОстатокНаКонецПериода.КБК,
    ВЫРАЗИТЬ(ОстатокНаКонецПериода.Субконто2 КАК Справочник.ОсновныеСредства) КАК ОС,
    ЕСТЬNULL(ОстатокНаКонецПериода.СуммаОстатокДт, 0) КАК БалансоваяСтоимостьКон,
    ЕСТЬNULL(ОстатокНаКонецПериода.КоличествоОстатокДт, 0) КАК КоличествоКон
ПОМЕСТИТЬ БалансоваяСтоимостьОСКон
ИЗ
    РегистрБухгалтерии.ЕПСБУ.Остатки({(&КонецПериодаОстатки)}, Счет.Ссылка В ИЕРАРХИИ (&СчетОС), , ) КАК ОстатокНаКонецПериода
{ГДЕ
    ОстатокНаКонецПериода.Учреждение.*,
    ОстатокНаКонецПериода.КВД.*,
    ОстатокНаКонецПериода.КБК.*,
    ОстатокНаКонецПериода.Баланс.*,
    ОстатокНаКонецПериода.Счет.*}

ИНДЕКСИРОВАТЬ ПО
    ОС
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ РАЗЛИЧНЫЕ
    СобытияОССрезПоследних.ОС КАК ОС,
    СобытияОССрезПоследних.Событие,
    СобытияОССрезПоследних.ДатаСобытия КАК ДатаПринятияКУчету
ПОМЕСТИТЬ События
ИЗ
    РегистрСведений.СобытияОС.СрезПоследних({(&КонецПериода)}, {(Учреждение)}) КАК СобытияОССрезПоследних
ГДЕ
    СобытияОССрезПоследних.Событие = &ПринятиеКУчету

ИНДЕКСИРОВАТЬ ПО
    ОС
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    АмортизацияЗаПериод.Учреждение,
    ВЫБОР
        КОГДА БалансоваяСтоимостьОСКон.Счет ЕСТЬ NULL
            ТОГДА АмортизацияЗаПериод.ОС.СчетУчета
        ИНАЧЕ БалансоваяСтоимостьОСКон.Счет
    КОНЕЦ КАК Счет,
    АмортизацияЗаПериод.Баланс,
    АмортизацияЗаПериод.КВД,
    АмортизацияЗаПериод.КБК,
    АмортизацияЗаПериод.ОС КАК ОС,
    АмортизацияЗаПериод.ОС.ИнвентарныйНомер КАК ИнвентарныйНомер,
    АмортизацияЗаПериод.ОС.КодПоОКОФ КАК ОКОФ,
    АмортизацияЗаПериод.ОС.АмортизационнаяГруппа КАК АмортизационнаяГруппа,
    ВЫБОР
        КОГДА АмортизацияЗаПериод.ОС.НаименованиеПолное = ""
            ТОГДА АмортизацияЗаПериод.ОС.Наименование
        ИНАЧЕ АмортизацияЗаПериод.ОС.НаименованиеПолное
    КОНЕЦ КАК пОС,
    АмортизацияЗаПериод.СрокПолезногоИспользования,
    События.ДатаПринятияКУчету,
    ЕСТЬNULL(БалансоваяСтоимостьОСКон.БалансоваяСтоимостьКон, 0) КАК БалансоваяСтоимостьКон,
    ЕСТЬNULL(БалансоваяСтоимостьОСКон.КоличествоКон, 0) КАК КоличествоКон,
    ЕСТЬNULL(АмортизацияЗаПериод.АмортизацияНачПериода, 0) КАК АмортизацияНачПериода,
    ЕСТЬNULL(АмортизацияЗаПериод.АмортизацияСписано, 0) КАК АмортизацияСписано,
    ЕСТЬNULL(АмортизацияЗаПериод.АмортизацияНачислено, 0) КАК АмортизацияНачислено,
    ЕСТЬNULL(АмортизацияЗаПериод.АмортизацияКонПериода, 0) КАК АмортизацияКонПериода,
    ВЫБОР
        КОГДА БалансоваяСтоимостьОСКон.БалансоваяСтоимостьКон <> 0
            ТОГДА АмортизацияЗаПериод.АмортизацияКонПериода / БалансоваяСтоимостьОСКон.БалансоваяСтоимостьКон * 100
        ИНАЧЕ 0
    КОНЕЦ КАК ПроцентИзноса,
    ВЫБОР
        КОГДА БалансоваяСтоимостьОСКон.КоличествоКон <> 0
            ТОГДА БалансоваяСтоимостьОСКон.БалансоваяСтоимостьКон / БалансоваяСтоимостьОСКон.КоличествоКон
        ИНАЧЕ 0
    КОНЕЦ КАК Цена,
    ЕСТЬNULL(АмортизацияЗаПериод.СрокИспользованияДляВычисленияАмортизации, 0) КАК СрокИспользованияДляВычисленияАмортизации,
    ЕСТЬNULL(АмортизацияЗаПериод.СтоимостьДляВычисленияАмортизации, 0) КАК СтоимостьДляВычисленияАмортизации
ИЗ
    АмортизацияЗаПериод КАК АмортизацияЗаПериод
        ЛЕВОЕ СОЕДИНЕНИЕ БалансоваяСтоимостьОСКон КАК БалансоваяСтоимостьОСКон
        ПО (БалансоваяСтоимостьОСКон.ОС = АмортизацияЗаПериод.ОС)
            И (БалансоваяСтоимостьОСКон.Баланс = АмортизацияЗаПериод.Баланс)
        ЛЕВОЕ СОЕДИНЕНИЕ События КАК События
        ПО АмортизацияЗаПериод.ОС = События.ОС
ГДЕ
    (БалансоваяСтоимостьОСКон.Счет В ИЕРАРХИИ (&СчетОС)
            ИЛИ АмортизацияЗаПериод.ОС.СчетУчета В ИЕРАРХИИ (&СчетОС))

УПОРЯДОЧИТЬ ПО
    Счет,
    ОС
{ХАРАКТЕРИСТИКИ
    ТИП(Справочник.ОсновныеСредства)
    ВИДЫХАРАКТЕРИСТИК ПланВидовХарактеристик.ХарактеристикиОС
    ПОЛЕКЛЮЧА Ссылка
    ПОЛЕИМЕНИ Наименование
    ПОЛЕТИПАЗНАЧЕНИЯ ТипЗначения
    ЗНАЧЕНИЯХАРАКТЕРИСТИК РегистрСведений.ЗначенияХарактеристикОС
    ПОЛЕОБЪЕКТА ОсновноеСредство
    ПОЛЕВИДА ВидХарактеристики
    ПОЛЕЗНАЧЕНИЯ ЗначениеХарактеристики }