БП 2.0, производство, есть производство и реализация с НДС и без НДС. Ведется раздельный учет входящего НДС.
При списании материалов в производство, вне зависимости от того, что материалы списываются в прямые (20.1) или косвенные затраты (не 20.1),  формируется движения по регистру "НДС по косвенным расходам", и, соответственно, при распределении НДС косвенных расходов в распределение попадают и распределяются прямые затраты. Отсюда вопрос:   так и должно быть, или можно как то "заставить" не включить через статьюзатрат\номенклатурную группу?

перечень прямых расходов задан?

кхм.. нЭт..

вроде

(1) и вроде бы они для расходов производства по налогу на прибыль...
и никак не сказываются на регистре ндс.

(4) в 1С все что не указано прямыми -- косвенные

(5) так, вопрос не по налогу на прибыль.. а по распределению ндс косвенных расходов.

Ну и ладно тогда...

Настройками проблема не решается.
В общем модуле УчетНДС в функции ОпределитьСчетаУчетаКосвенныхРасходов() закомментируй ненужные счета.

(8) плин.. мне, наоборот добавлять пришлось 08.. похоже, тем же способом придется решить вопрос и с 20.01..
через номенклатурные группы тож никак?

(8) а если в статью затрат поставить "С особы порядком налогооблажения...". ЕНВД нет, и в состав косвенных они гарантированно не попадут))

(9) Насколько мне известно, нет.
(10) А из налогового учета они при этом случайно не вылетят?

(11) надо поискать.. вариант с номенклатурными группами я пробовал - не получил результат.. думал, вдруг у кого получилось..
сейчас методом ручных механизмов сделали - просто удалили строки в документе распределения... но, свербит..

похоже, 1С не захотел заморачиваться с распределением при производстве "Без НДС" и "С НДС 0%".. и все подряд распределяет..

(0)Все что уходило на 20 счет делал ПРЯМЫМИ. А распределение пришлось корректировать для своего случая (На комиссионку методика 1С не расчитана).

(14) как делать их прямыми??..

Прям в фунции прописаны для распределения косвенные.
Функция ОпределитьСчетаУчетаКосвенныхРасходов() Экспорт

    ПланСчетовБУ = ПланыСчетов.Хозрасчетный;
    
    СчетаУчетаЗатрат = Новый СписокЗначений();

    СчетаУчетаЗатрат.Добавить(ПланСчетовБУ.ОсновноеПроизводство);
    СчетаУчетаЗатрат.Добавить(ПланСчетовБУ.ОбслуживающиеПроизводства);
    СчетаУчетаЗатрат.Добавить(ПланСчетовБУ.ВспомогательныеПроизводства);
    СчетаУчетаЗатрат.Добавить(ПланСчетовБУ.ОбщепроизводственныеРасходы);
    СчетаУчетаЗатрат.Добавить(ПланСчетовБУ.ОбщехозяйственныеРасходы);
    СчетаУчетаЗатрат.Добавить(ПланСчетовБУ.ИздержкиОбращения);
    СчетаУчетаЗатрат.Добавить(ПланСчетовБУ.КоммерческиеРасходы);
.....
КонецФункции

(0) В БП 2.0 ВСЕ расходы для НДС являются косвенными. Я исправлял заполнение табличной части документа "РаспределениеНДСКосвенныхРасходов" и добавив доп.реквизит в номенклатурных группах.

(17) думаю, поправлю проведение и добавлю реквизит в док распределения..

(18) Проведение править не нужно. Изменяется заполнение табличных частей в форме. Попробую завтра найти готовую процедуру.

(19) а как же регистр косвенных расходов? Он ж распухнет как баварский бюргер отт пива.

(20) Так он регламентным документом "РаспределениеНДСКосвенныхРасходов" и закрывается.

(21) так, приход в регистр документами списания, расход документом распределения. Если проведение не трогать - распухнет..

(22) Зато можно остаться на типовой конфигурации.

(23) эт да, согласен. Но уже конфа подрихтована в плане счетов в функции из (16)..
А вообще - нужно вернутся на поддержку, и добавлять то, что заблагорассудится))

Как обещал. Процедура написана для экспорта т.е. 0% ставка НДС. В номенклатурных группах добавлен реквизит "Реализация0". Это признак того, что затраты 20сч. этой номенклатурной группы относятся к 0% НДС.


Процедура РаспределитьПоВыручке() Экспорт

    БазаРаспределенияСЕНВД = ВыручкаНДС + ВыручкаБезНДС + ВыручкаЕНВД + ВыручкаНДС0;
    БазаРаспределенияБезЕНВД =  ВыручкаНДС + ВыручкаБезНДС + ВыручкаНДС0;

    Если БазаРаспределенияСЕНВД = 0 Тогда
        Сообщить("На закладке ""Выручка от реализации"" не указаны параметры реализации!", СтатусСообщения.Внимание);
        Возврат;
    КонецЕсли;

    Для Каждого СтрТабЧасти Из СоставКосвенныхРасходов Цикл
        
        Если СтрТабЧасти.БазисРаспределенияВключаетЕНВД Тогда
            БазаРаспределения = БазаРаспределенияСЕНВД;
        Иначе
            БазаРаспределения = БазаРаспределенияБезЕНВД;
        КонецЕсли;
        
        Запрос = Новый Запрос;
        Запрос.Текст =
        "ВЫБРАТЬ
        |    РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов.СчетЗатрат,
        |    РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов.Субконто1,
        |    РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов.Субконто2,
        |    РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов.Субконто3,
        |    РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов.СуммаБезНДС,
        |    РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов.НДС
        |ИЗ
        |    Документ.РаспределениеНДСКосвенныхРасходов.СчетаУчетаРасходов КАК РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов
        |ГДЕ
        |    РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов.КлючСтроки = &КлючСтроки
        |    И РаспределениеНДСКосвенныхРасходовСчетаУчетаРасходов.Ссылка = &Ссылка";
        
        Запрос.УстановитьПараметр("КлючСтроки", СтрТабЧасти.КлючСтроки);
        Запрос.УстановитьПараметр("Ссылка", ЭтотОбъект.Ссылка);
        
        Результат = Запрос.Выполнить();
        
        ВыборкаДетальныеЗаписи = Результат.Выбрать();
        
        СтрТабЧасти.НДССумма    = 0;
        СтрТабЧасти.НДС         = 0;
        СтрТабЧасти.БезНДССумма = 0;
        СтрТабЧасти.БезНДС      = 0;
        СтрТабЧасти.ЕНВДСумма   = 0;
        СтрТабЧасти.ЕНВДНДС     = 0;
        СтрТабЧасти.НДС0Сумма   = 0;
        СтрТабЧасти.НДС0        = 0;
        
        
        Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
            УчтеноСуммы   = 0;
            УчтеноНДС     = 0;
            УчтеноВыручки = 0;
            
            Если ВыборкаДетальныеЗаписи.СчетЗатрат=ПланыСчетов.Хозрасчетный.ОсновноеПроизводство Тогда//Прямые затраты распределяем в соответствии с номенклатурной группой
                Если ВыборкаДетальныеЗаписи.Субконто1.Реализация0 Тогда
                    СтрТабЧасти.НДС0Сумма = СтрТабЧасти.НДС0Сумма+ВыборкаДетальныеЗаписи.СуммаБезНДС;
                    СтрТабЧасти.НДС0      = СтрТабЧасти.НДС0+ВыборкаДетальныеЗаписи.НДС;
                Иначе
                    СтрТабЧасти.НДССумма  = СтрТабЧасти.НДССумма+ВыборкаДетальныеЗаписи.СуммаБезНДС;
                    СтрТабЧасти.НДС       = СтрТабЧасти.НДС+ВыборкаДетальныеЗаписи.НДС;
                КонецЕсли;
            Иначе
                
                Если ВыручкаНДС <> 0 Тогда
                    
                    СтрТабЧасти.НДССумма = СтрТабЧасти.НДССумма+Окр(ВыборкаДетальныеЗаписи.СуммаБезНДС * (ВыручкаНДС + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноСуммы;
                    СтрТабЧасти.НДС      = СтрТабЧасти.НДС+Окр(ВыборкаДетальныеЗаписи.НДС * (ВыручкаНДС + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноНДС;
                    
                    УчтеноСуммы     = УчтеноСуммы + Окр(ВыборкаДетальныеЗаписи.СуммаБезНДС * (ВыручкаНДС + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноСуммы;
                    УчтеноНДС       = УчтеноНДС + Окр(ВыборкаДетальныеЗаписи.НДС * (ВыручкаНДС + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноНДС;
                    УчтеноВыручки   = УчтеноВыручки + ВыручкаНДС;
                    
                КонецЕсли;
                
                Если ВыручкаБезНДС <> 0 Тогда
                    
                    СтрТабЧасти.БезНДССумма = СтрТабЧасти.БезНДССумма+Окр(ВыборкаДетальныеЗаписи.СуммаБезНДС * (ВыручкаБезНДС + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноСуммы;
                    СтрТабЧасти.БезНДС      = СтрТабЧасти.БезНДС+Окр(ВыборкаДетальныеЗаписи.НДС * (ВыручкаБезНДС + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноНДС;
                    
                    УчтеноСуммы   = УчтеноСуммы + Окр(ВыборкаДетальныеЗаписи.СуммаБезНДС * (ВыручкаБезНДС + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноСуммы;
                    УчтеноНДС     = УчтеноНДС + Окр(ВыборкаДетальныеЗаписи.НДС * (ВыручкаБезНДС + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноНДС;
                    УчтеноВыручки = УчтеноВыручки + ВыручкаБезНДС;
                    
                КонецЕсли;
                
                Если ВыручкаЕНВД <> 0 и СтрТабЧасти.БазисРаспределенияВключаетЕНВД Тогда
                    
                    СтрТабЧасти.ЕНВДСумма = СтрТабЧасти.ЕНВДСумма+Окр(ВыборкаДетальныеЗаписи.СуммаБезНДС * (ВыручкаЕНВД + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноСуммы;
                    СтрТабЧасти.ЕНВДНДС   = СтрТабЧасти.ЕНВДНДС+Окр(ВыборкаДетальныеЗаписи.НДС *   (ВыручкаЕНВД + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноНДС;
                    
                    УчтеноСуммы   = УчтеноСуммы + Окр(ВыборкаДетальныеЗаписи.СуммаБезНДС * (ВыручкаЕНВД + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноСуммы;
                    УчтеноНДС     = УчтеноНДС + Окр(ВыборкаДетальныеЗаписи.НДС *   (ВыручкаЕНВД + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноНДС;
                    УчтеноВыручки = УчтеноВыручки + ВыручкаЕНВД;
                    
                КонецЕсли;
                
                Если ВыручкаНДС0 <> 0 Тогда
                    
                    СтрТабЧасти.НДС0Сумма = СтрТабЧасти.НДС0Сумма+Окр(ВыборкаДетальныеЗаписи.СуммаБезНДС * (ВыручкаНДС0 + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноСуммы;
                    СтрТабЧасти.НДС0      = СтрТабЧасти.НДС0+Окр(ВыборкаДетальныеЗаписи.НДС * (ВыручкаНДС0 + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноНДС;
                    
                    УчтеноСуммы   = УчтеноСуммы + Окр(ВыборкаДетальныеЗаписи.СуммаБезНДС * (ВыручкаНДС0 + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноСуммы;
                    УчтеноНДС     = УчтеноНДС + Окр(ВыборкаДетальныеЗаписи.НДС * (ВыручкаНДС0 + УчтеноВыручки)/БазаРаспределения, 2) - УчтеноНДС;
                    УчтеноВыручки = УчтеноВыручки + ВыручкаНДС0;
                    
                КонецЕсли;
            КонецЕсли;
        КонецЦикла;
    КонецЦикла;

КонецПроцедуры // РаспределитьПоВыручке()


Спс..