Здравия всем.

Подскажите, как можно при программном выводе подсчитать количество строк результата выполнения СКД? Сейчас это происходит путём формирования отчета сначала в ТЗ (для подсчета количества), а затем уже в ТабДокумент. Это бредово - дважды выполняется СКД. Можно как-то нормально получить количество строк без таких махинаций?

на зачем?

Количество (*) Как Колич

(2), добавлять спец поле количества строк и выводить в результат? По-момему, это тоже не ахти. Плюс, пользователи могут его отключить

(1), какой странный вопрос. Надо же

(4) ну да

"Зачем" ещё не спрашивали? ))

И это, а чем служебное поле № строки не устраивает?

Ок. Никогда не понимал зачем постоянно спрашивать "зачем". >_>

Мне нужно в конкретное поле на форме вывести количество строк

(7), ответ тот же (3).

(8) вперёд

(10), предложения есть? Без глупостей про "да это негому не нушна!"

На закладке Ресурсы добавь поле по которому количество хочешь считать.

(12), -> (9) -> (3)

Уже предлагали подобное. Но для этого нужно это самое поле выводить в результат, а оно там никому не нужно. Даже если условным оформлением его закрасить, то его могут отключить пользователи. Да и не гибко.

Неужели нет нормального способа\метода для СКД? 0_о

Ну так запрети пользователям его отключать.

(15), естественно это не выход. Костыль ещё тот

(0) Например так:
Создаешь пользовательское поле "КоличествоСтрок".
На закладке Выражение итоговых записей прописываешь формулу:
Сумма(ВычислитьВыражениеСГруппировкойМассив("1", "КакоеТоПолеОтчета"))

(17),
(12) -> (9) -> (3)

Уже отвечал ))

"Уже предлагали подобное. Но для этого нужно это самое поле выводить в результат, а оно там никому не нужно. Даже если условным оформлением его закрасить, то его могут отключить пользователи. Да и не гибко."

v8: СКД: СКД: вывести общее количество строк

(19), мне не нужно выводить в подвал таблицы. Мне нужно получить его программно и загнать в переменную

Юзай

Сч=0;
Пока Выборка.Следующий Цикл
Сч=Сч+1;
КонецЦикла;
ТвояПеременная=Сч;

Универсальный механизм!!!

(21), причем тут вообще выборка? У меня СКД

(0) в отдельную группировку вывести вычисляемое поле, которое вычисляет Количество(*) пробовал?

(23)
Эх...
(18) -> (12) -> (9) -> (3)
Уже отвечал

(20) переменная где/как объявляется?

(25), а это важно? В момент программного формирования СКД.

Тогда как-то так:

КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, СхемаКомпоновкиДанных.НастройкиПоУмолчанию,,, Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , , Истина);
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
ПроцессорВывода.УстановитьОбъект(ТаблицаЗначений);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);

КоличествоСтрок = ТаблицаЗначений.Количество();

(27), эмм.... Я ведь об этом писал в (0) =)

Пробуй так
КоличествоСтрокРезультатаВыполненияСКД= Новый ПроцессорРасчетаКоличестваСтрокРезультатаВыполненияКомпоновкиДанныхВМоюПеременнуюИЧтобПользовательНеСмогОтключитьБыстроНах(ПроцессорКомпоновки)

Почитаешь тему... ТС молодой и грубый.

(29) Нуралиев сейчас подпрыгнул от зависти

(29) +100500

А если так: МакетКомпоновки.Тело.Получить(1).КоличествоЗаписей

(33), к сожалению, тоже нет =(

КоличествоЗаписей (RecordsCount)
Использование:

Чтение и запись.
Описание:

Тип: Число.
Указывает количество записей, отображаемых в группировке.

Доступность:

Сервер, толстый клиент, внешнее соединение.
Примечание:

Если значение равно -1, выводятся все записи.

(31) всенепременно юзая "СделатьФсё" чего подпрыгивать?)

(0) Если используется программный вывод, то использовать вместо Вывести() ВывестиЭлемент() и при каждом выводе увеличивать счетчик.

Другой вариант добавить Вычисляемое поле "Кол-во элементов" с выражением "количество(массив(ИмяПоляПоКоторомуМожноПодсчитатьКоличество))"

Чтобы пользователи не отключили поле в событии "ПриКомпоновке" искустевенно его добавлять и в условном оформлении выключать видимость

ПроцессорВывода.НачатьВывод();
Элемент = ПроцессорКомпоновкиДанных.Следующий();
Сч=1;
Пока Элемент<>Неопределено Цикл
     ПроцессорВывода.ВывестиЭлемент(Элемент);
        Если Элемент.ТипЭлемента = ТипЭлементаРезультатаКомпоновкиДанных.НачалоИКонец Тогда // ниже нет детальных записей
        //  Если <еще какое-нибудь условие, которое поможет понять, что выводится детальная запись, хз может по макету связаться> Тогда
                    Сч=Сч+1;
         // КонецЕсли;
        КонецЕсли;
        Элемент=ПроцессорКомпоновкиДанных.Следующий();  
    КонецЦикла;
    ПроцессорВывода.ЗакончитьВывод();

(36) группировки тоже считаться будут, а нужны только детальные записи

(38) группировки он тоже хочет, раз ТЗ считает

Функция СформироватьКакСКД(СтрокаПравила)
    
    {...}
    
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СКД, КомпоновщикДляВыполнения.Настройки,
    ДанныеРасшифровки,,Тип("ГенераторМакетаКомпоновкиДанных"));    
    
    МассивИменМакетовДетальныхЗаписей    = ИменаМакетовДетальныхЗаписей(МакетКомпоновки);
    
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки,,ДанныеРасшифровки,Истина);
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    РезультатТабДок = Новый ТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(РезультатТабДок);
    
    ПроцессорВывода.НачатьВывод();
    КоличествоСтрок    = 0;
    Пока Истина Цикл
        ЭлементРезультата = ПроцессорКомпоновкиДанных.Следующий();
        Если ЭлементРезультата= Неопределено Тогда
            Прервать;
        Иначе
            Если МассивИменМакетовДетальныхЗаписей.Найти(ЭлементРезультата.Макет) <> Неопределено Тогда
                КоличествоСтрок    = КоличествоСтрок + 1;
            КонецЕсли;
            ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
        КонецЕсли;
    КонецЦикла;
    
    ПроцессорВывода.ЗакончитьВывод();
                
КонецФункции

Функция ИменаМакетовДетальныхЗаписей(МакетКомпоновки, ИмяИтератора = "Тело")
    
    МассивЭлементов    = Новый Массив;
    
    МассивИменМакетовДетальныхЗаписей    = Новый Массив;
    
    Для Каждого Тело Из МакетКомпоновки.Тело Цикл
        
        ТипТела    = ТипЗнч(Тело);
        Если ТипТела = Тип("ЗаписиМакетаКомпоновкиДанных") Тогда
            МассивЭлементов.Добавить(Тело);
        ИначеЕсли ТипТела = Тип("ГруппировкаМакетаКомпоновкиДанных") Тогда
            врМассивИменМакетовДетальныхЗаписей    = ИменаМакетовДетальныхЗаписей(Тело);
            Для Каждого врЭлемент Из врМассивИменМакетовДетальныхЗаписей Цикл
                МассивИменМакетовДетальныхЗаписей.Добавить(врЭлемент);
            КонецЦикла;
        ИначеЕсли ТипТела = Тип("ТаблицаМакетаКомпоновкиДанных") Тогда
            врМассивИменМакетовДетальныхЗаписей    = ИменаМакетовДетальныхЗаписей(Тело, "Строки");
            Для Каждого врЭлемент Из врМассивИменМакетовДетальныхЗаписей Цикл
                МассивИменМакетовДетальныхЗаписей.Добавить(врЭлемент);
            КонецЦикла;
        КонецЕсли;
                
    КонецЦикла;
    
    Для Каждого ЭлементДетальныхЗаписей Из МассивЭлементов Цикл
        Для Каждого МакетДетальныхЗаписей Из ЭлементДетальныхЗаписей.Тело Цикл
            МассивИменМакетовДетальныхЗаписей.Добавить(МакетДетальныхЗаписей.Макет);
        КонецЦикла;
    КонецЦикла;
    
    Возврат МассивИменМакетовДетальныхЗаписей;
    
КонецФункции

(37), спасибо! Самый дельный совет.

Правда проверка не детальные записи таким образом не сработала. Нашел только способ в (40). Пока работает...

Понятно, что можно написать красивее, просто это то, что я сейчас накидал по-быстрому

(42) замерь время формирования (40) и простого вычисляемого поля

(43), не забывай о том, что подход в (40) сработает всегда, а вычисляемое поле - можно только надеяться.

Если, конечно, нет нюансов, которые я не учёл. Но пока что не нашел.

(3) Оно есть

(11) Оно есть в стандартных полях "Номер строки" и "Номер строки в группе"

Если интересует "Итого строк в группе", тогда реализуй подсчет кол строк в той или иной группе, через Дополнительный набор данных.
Только связку придумай.

Или в Запросе посчитай :)

(40) Извращенец, спасибо, но мы как нить без этой глупости :)

(47), если есть варианты без этой глупости, то буду рад

В СКД Вкладка "Настройки" -"Выбранные поля"  смотри окно "Доступные поля", там в папке "Системные поля" есть то, что тебе нужно.