Уважаемые форумчане,
стоит задача сделать выгрузку в файл данных стандартного отчета (РасчетныеВедомостиОрганизаций) но немного поиграть с полями - некоторые поля сложить, некоторые убрать.
Вообще хотелось бы сформировать этот отчет, но вместо того, чтобы выводить его в поле табличного документа, сразу поиграть с этими полями и вывести уже в файл.
Вопрос - как получить ТЗ с данными этого отчета или что-то более удобоваримое чем поле табличного документа?

Вот так смог вывести данные на форму, но лазая в конфигураторе не смог найти что-то вроде ТЗ с этими данными

    //Получаем схему из макета
    СхемаКомпоновкиДанных = Отчеты.РасчетныеВедомостиОрганизаций.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
    
    //Из схемы возьмем настройки по умолчанию
    Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
    
    //Помещаем в переменную данные о расшифровке данных
    ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
    
    //Формируем макет, с помощью компоновщика макета
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    
    //Передаем в макет компоновки схему, настройки и данные расшифровки
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);
    МакетКомпоновки.ЗначенияПараметров.НачалоПериода.Значение = НачалоМесяца(Период);
    МакетКомпоновки.ЗначенияПараметров.КонецПериода.Значение = КонецМесяца(Период);
    
    //Выполним компоновку с помощью процессора компоновки
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);
      
    //Очищаем поле табличного документа
    Результат = ЭлементыФормы.Результат;
    Результат.Очистить();
      
    //Выводим результат в табличный документ
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(Результат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

(0) тупо запрос из скд вырвать и выполнить в своей обработке не айс?

(2) Там порядка 8 запросом в одном отчете. Думаю долго буду разбираться как они там все соединяются

(2) хотя не удивлюсь, если это все-таки окажется единственный вариант )))

(3) Получи табдок и сохрани его в ексель

(5) Сразу получить таб док тоже не получится, как я писал - надо кое какие поля сложить, какие-то убрать
В общем не меняя стандартный отчет не получится

Выходит, что нельзя так?

1. Если программно сформировать и выгрузить в ТЗ то нужно потом как то избавиться от итогов(если у тебя есть какие то группировки).

ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений

и потом что угодно с ней крутить
примеры в сегментации если УТ11

(9) Спасибо!
Как раз наткнулся на эту статью
http://langslab.com/ebooks/skd/dcs-ch3/built-in-language
И курю этот процессор

Только вот такая ошибка выскакивает.
Не поддерживается вывод таблиц, диаграмм и вложенных отчетов в универсальную коллекцию значений
Может кто знает?

{Форма.Форма.Форма(40)}: Ошибка при вызове метода контекста (Выполнить)
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
по причине:
Ошибка компоновки макета
по причине:
Ошибка генерации макета
по причине:
Не поддерживается вывод таблиц, диаграмм и вложенных отчетов в универсальную коллекцию значений

(12) и не получится при наличии итогов и наверное еще чего то

не надо выводить таблицы, вложенные отчеты и диаграммы в универсальную коллекцию значений - все просто; сделай свой простейший вариант отчета с детальными записями и дальше полетит

+13 кури таки запрос и формируй сразу нужные тебе данные

и не забывать про
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки,,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));

(16) а. уже)

Скопировать схемуКД из отчета к себе в обработку, удалил все настройки КД и все взлетело
Теперь осталось программно удалить все эти настройки, но думаю с этим я уж разберусь
Всем спасибо)))

Если что - вот код

    //Получаем схему из макета
    СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
    
    //Из схемы возьмем настройки по умолчанию
    Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
    
    //Помещаем в переменную данные о расшифровке данных
    ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
    
    //Формируем макет, с помощью компоновщика макета
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    
    //Передаем в макет компоновки схему, настройки и данные расшифровки
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
    МакетКомпоновки.ЗначенияПараметров.НачалоПериода.Значение = НачалоМесяца(Период);
    МакетКомпоновки.ЗначенияПараметров.КонецПериода.Значение = КонецМесяца(Период);
    
    //Выполним компоновку с помощью процессора компоновки
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    //ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки);
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки);
    
    ДеревоРезультата = Новый ТаблицаЗначений;
    
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
    ПроцессорВывода.УстановитьОбъект(ДеревоРезультата);
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
    Сообщить("Ура");

(19) спасибо, таких кодов как грязи