Прочитал множество ссылок, сделал простой пример - ТЗ из одной колонки, типизированной, нужно вывести в отчет на СКД. С помощью описаний, я смог это сделать, но, увы, не работают отборы в полученном отчете.
Для совсем горячих голов, повторюсь - отчет выводит мою ТЗ, но отборы, установленные через настройки СКД не работают в принципе.
Сам я подозреваю, что это связано с тем, что в процедуре «ПриКомпоновкеРезультата» установлено «СтандартнаяОбработка = ЛОЖЬ;»
Кто сталкивался с этим и знает решение, прошу оказать помощь.

(0) а в ролях полей измерения прописаны?

(1) Нет, не прописаны
А там что можно прописать? У меня тип поля - строка

(0) так отчет программно выводится?

(3) Отчет выводится. Но через настройки СКД делаю отбор - он не применяется.

(4) код вывода-то покажете?

(4) я имею ввиду отчет выводится _программно_?

(5)
Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
    
    СтандартнаяОбработка = ЛОЖЬ;
    
    ВнешниеНаборыДанных = Новый Структура;
    ВнешниеНаборыДанных.Вставить("ТЗ",ТЗ);
    
    СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
    Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
    
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки);
    
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных);  
    
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
    
КонецПроцедуры

(6) Да, отчет выводится программно. При открытии формы отчета заполняется ТЗ (реквизит отчета), по кнопке "Сформировать" выводится моя ТЗ в поле результата. Но отборы мне не победить

(7) >>Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
не настораживает??
попробуйте
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, );

(7) МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки);
проверь в отладчие что у тебя с отбором в Настройки

(10) в Настройки в отборе такое:
ДоступныеПоляОтбора - Элементы
вообще пусто

имеет смысл покопать в сторону программного отбора
v8: Как в СКД программно установить отбор?

автор, куда пропал, ответь на (9)

(12), (13) По ходу, дело в том, что настройки отбора надо формировать также программно. Сейчас подсказали умные люди, как это в принципе можно реализовать. Пока пробую через программный отбор.

(13) если стандартная обработка отключена, не будет его отбор работать по умолчанию

(15) + 1, согласен. Хотя.. возможно ведь, что мой код перезаписывает отбор принудительно. Сейчас проверю.

(11) его отбор находится в КомпоновщикНастроек.ПользовательскиеНастройки

(17) Действительно.. А их можно просто "загрузить" в настройки отчета?

(17) в любом случае, придется отбор программно делать.

(18) как то я это делал, пытаюсь вспомнить...

КомпоновщикНастроек.ЗагрузитьНастройки(ТвоиПользовательскиеНастройки);

На данный момент у меня вот так:
Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
    
    СтандартнаяОбработка = ЛОЖЬ;
    
    ВнешниеНаборыДанных = Новый Структура;
    ВнешниеНаборыДанных.Вставить("ТЗ",ТЗ);
    
    СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
    
    Настройки = КомпоновщикНастроек.Настройки;
    Если Настройки.Отбор.Элементы.Количество()=0 Тогда
        Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
    Иначе
        ЭлементОтбора = Настройки.Отбор.Элементы.Получить(0);
        ЭлементОтбора.ПравоеЗначение = "6";
        ЭлементОтбора.Использование = Истина;
        ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Содержит;
    КонецЕсли;
    
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки);
    
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных);  
    
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
    
КонецПроцедуры

(22) + В принципе, работает, но буду пытаться установить то, что прописал пользователь, я не я в коде. Попробую (21)

(21) ошибку даст - несовпадение типов

(24) Да, дает такую ошибку. Может, удастся обойти коллекцию пользовательских настроек и как-то их протащить..

(25) в пользовательский настройках все в куче и параметры данных и элементы отбора, но я без переборов это делал, блин давно это было очень и один раз, вылетело из головы напрочь, считай с нуля разбираюсь

(26) я тоже очень давно это делала, не помню уже, как. По-моему программно.

Всем спасибо, проблема решена наилучшим образом )))
СКД просто не надо мешать делать свою работу.
Код:
Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
    
    СтандартнаяОбработка = ЛОЖЬ;
    
    ВнешниеНаборыДанных = Новый Структура;
    ВнешниеНаборыДанных.Вставить("ТЗ",ТЗ);
    
    СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
    
    Настройки = КомпоновщикНастроек.Настройки;
    Если Настройки.Отбор.Элементы.Количество()=0 Тогда
        Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;
    КонецЕсли;
    
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки);
    
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных);  
    
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
    
КонецПроцедуры

(28) + При первом открытии - без настроек, а при выборе настроек пользователем, они сами применяются.
Спасибо за моральную поддержку и хорошие советы.

(28) Зачетно) ларчик просто открывался значит)

(30) Да... не потребовалось его ломать. Хотя я уже готовился копировать выбор пользователя в Массив и его программно прописывать.

(29) а ты проверил, точно работает?

(32) Проверил. У меня работает )

(33) так еще проще, проверь

    Настройки = КомпоновщикНастроек.ПолучитьНастройки();
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,  Настройки);

(34) Проверил - работает :)