Ковыряя одну конфу от Раруса, обратил внимание, что очень много параметров процедур и функций в общих модулях описаны с использованием ключевого слова Знач. Такое описание делается даже в тех случаях, когда 100% с данные только читаются (т.е. исключено изменение объекта).

Подумалось следующее. А не фича ли это?
Ведь Знач (в случае передачи ссылки) на уровне СУБД по сути одним  запросом выберет копию объекта и передаст в процедуру/функцию, где уже можно спокойно с ней работать, без дергания сервера мелкими запросами при обращении к свойствам объекта по ссылке.

Прав ли я или тут закопан какой-то другой смысл?

(0) Закопан.

в УФ это еще и обход ошибки "нельзя менять объект данных формы" или как-то так.

http://v8.1c.ru/o7/201312opt/index.htm

В-четвёртых, использование ключевого слова Знач при объявлении параметров процедур и функций. Дело в том, что при клиент-серверном взаимодействии это ключевое слово значит совсем не то, что при работе внутри одного компьютера, клиентского или серверного. Когда мы используем Знач при объявлении параметра серверной процедуры и вызываем её с клиента, это означает, что значение этого параметра обратно на клиент не приедет. Если же мы не устанавливаем Знач, а стандартно так и есть, то происходит следующее. Допустим, мы вызываем серверную процедуру и передаём в неё массив. Предположим, что на клиенте мы даже не собираемся потом этим массивом пользоваться. Он просто был параметром и на самом деле нам не нужен больше. Но когда серверный вызов закончится, массив будет упакован в XML или JSON (на веб-клиенте), и уедет обратно на клиент. Понятно, что это совсем неэффективно. Поэтому если вам не нужно возвращаемое значение, переданное через параметр, пишите ключевое слово Знач у таких параметров. Конечно, если параметр Булево, Знач можно сэкономить и не писать. Но по сути это нехорошо.

(0) Я бы не стал конфу от раруса рассматривать, как объект для подражания. Смотрел УАТ, так в шоке был от увиденного...

(3) Понял. Спасибо.

(0) Покопай любую конфу на БСП. Там тоже многие параметры передаются по значению.

(4) +100500. Так придётся делать тему "Использование "Попытка - Исключение" в процедурах и функциях"

(6) Ну это похоже и есть БСП функции.
Смысл главное понял.Возьму на вооружение.

Значит в клиент-серверном варианте, если передавать через Знач ссылку на, к примеру элемент справочника, то в процедуру/функцию все равно придет ссылка, а не копия объекта элемента справочника?

(9) Да.

(9) Что значит "копия объекта элемента?"
Смотрите, все просто, тут 2 аспекта.
Первый - сугубо идеологический. Указывая "Знач" вы явно объявляете свое намерение сделать параметр строго входным (обязуетесь не изменять параметр)
Любой человек, который ваш код будет читать, может посмотреть на сигнатуру метода и сказать: "так, эти два параметра входные, а вот этот без "Знач" - выходной, он где-то в коде присваивается и в нем что-то возвращается". То есть, указывая знач, вы облегчаете чтение своего кода и явно объявляете намерения в сигнатуре метода.

Второй аспект - технический. При передаче чего-то на сервер, если параметр без слова "Знач", то платформа считает этот параметр выходным и при возврате на клиента будет обратно передавать его значение. Указывая Знач вы оптимизируете трафик.

а по поводу копии объекта, это вы не понимаете что такое ссылка. Ссылка это просто GUID. Ее можете передавать с сервера на клиент и обратно, никаких копий "объектов" не создается.
СправочникОбъект на сервер передать вообще нельзя, это мутабельное значение.

Когда вы пишете "А = Ссылка.Наименование" происходит запрос в СУБД и в память поднимается ВЕСЬ объект вместе со всеми табличными частями. Передавая ссылку на сервер вы передаете только GUID. Эти два процесса (запрос в базу и передача ссылки) вообще не связаны никак.

(11) А, ну понял. Меня просто СП сбил с толку.
Получается если мы передаем ссылку на элемент справочника, то без Знач передаем ссылку на ссылку, вернее указатель на ссылку. А со Знач само значение ссылки.

(12) %) Я Ничего Не Понял

Если мы передаем со Знач или без Знач ссылку, то мы передаем GUID. Ссылка в базе данных и Ссылка на объект в памяти это как бы разные ссылки, не находите?

&НаСервере
Процедура ПоСсылке(Переменная)
    Переменная = 1;
КонецПроцедуры

&НаКлиенте
Процедура ВызватьСКлиента()
    А = 0;
    ПоСсылке(А);
КонецПроцедуры

Вот здесь будет переход с машины на машину (с клиента на сервер). Параметр передается "по ссылке". Поскольку это две разных машины, то у них никак не может быть общая память. Платформа здесь делает следующее:
1. Передает значение 0 на сервер (по сути делает копию переменной А)
2. На сервере устанавливается некой переменной значение 1
3. При возврате на клиента платформа помнит, что передача должна быть "как бы по ссылке" и присваивает в А значение, установленное на сервере.

Теперь, если поменять код и вместо &НаКлиенте написать &НаСервере, то будет следующее:

1. В метод ПоСсылке будет передан условный адрес переменной А, по этому адресу записано значение
2. В точке вызова будет видно, что А стало равно единице.

Я, собственно, к чему. Не думайте про ссылки, как про указатели. Если происходит переход с одной машины на другую, то в любом случае будет задействована сериализация туда и обратно. Слово Знач указывает на то каким должно быть НАБЛЮДАЕМОЕ поведение в коде. Технически это могут быть более сложные вещи.

(4) и че там такого, сделан там уже Путевой лист на УФ?

(0) Знач не имеет никакого отношения к СУБД

(6) ИМХО там в большинстве случаев параметры передаются по значению, скорее передаче по ссылке является исключением.

Использование знач для ссылок приводит к созданию новой ссылки то есть другого обьекта с типом ссылка
Со строками тоже самое
В случае вызова функции с сервера нп сервер будет происходить копирование данных
А вот в случае с клиент серверным желательно

(16) "Использование знач для ссылок приводит к созданию новой ссылки то есть другого обьекта с типом ссылка" - какие-нибудь подтверждения этому тезису есть?
В документации сказано, что агрегаты передаются всегда по ссылке.

(17) "По ссылке" означает, что если вы перезапишете переменную внутри функции, то она изменится и в точке вызова.

Если "По Значению", то в точке вызова останется то же значение.

Если передали "По значению" коллекцию, внутри метода вызвали Очистить(), то в точке вызова она тоже будет очищена. Вы не перезаписали переменную коллекции, а вызвали метод, который изменил внутренности объекта. Т.е. агрегат (коллекция) как бы ни передавался - если вы меняете состояние объекта - оно меняется везде.

(18) молодец, теперь мой вопрос перечитай.

Вот правда вы как школьники.
Это же основы программирования.
С Знач копия объекта создается в процедуре и там же умирает.
Без Знач- передается ссылка(и это может быть ссылка на объект с возможностью изменения) . Вот тут возможны варианты когда работать или не будет или не оптимально.

(3) где на сайте 1с можно найти "Заметки из зазеркалья" на главной странице?

(21) нигде + первоистоки этой ссылки - на партнерке

Вот не знаю как там внутре 1С, некоторые другие языки создают копию объекта только в момент изменения. Если вы понимаете о чем я.
Но на самом деле это не имеет значения.
Хотя изредка очень хочется, чтобы про типобезопасность и имьютабилити платформа "думала" сама.

http://its.1c.ru/db/v83doc#bookmark:dev:TI000000151

В контексте ветки внимание, вопрос: зачем нужна такая функция:

Функция Присвоить(а, Знач б) Экспорт
    а = б;
    Возврат а;
КонецФункции

На ИТС есть же статья "Передача параметров по ссылке и по значению при вызове процедур и функций"? Там всё подробно разжёвано.

(26) да-да-да, и ссылка аж двумя постами раньше висит

я что-то не понял
Разве код не меняет количество элементов в массиве?

М = Новый Массив();
Чтото(М);

Процедура Чтото(Знач М)
  М.Добавить(0);
КонецПроцедуры

(28) нет

По крайней мере не должен

Расставим точки,

применение Знач везде где можно - хороший тон программирования?

(29) ?

(31) поправил: "применение Знач везде, где нужно - хороший тон программирования".

(33) если можно применить Знач, значит - нужно :)

т.е. создание копии изменяемого объекта - гораздо менее трудоемкая задача, чем его сериализация при возврате?

(25) Чтоб на этапе отладки менять переменные
(28) меняет. У коллекций то передается ссылка на коллекцию.

(34) нет

(29) спецом полез проверить:

Процедура КнопкаВыполнитьНажатие(Кнопка)
    М = Новый Массив();
    Сообщить("М.Количество()="+М.Количество());   // выдает 0
    Чтото(М);
    Сообщить("М.Количество()="+М.Количество());   // выдает 1
КонецПроцедуры


Процедура Чтото(Знач М)
  М.Добавить(0);
КонецПроцедуры

(38) коллекция же

(38) на этой фишке основан гвнокодистый способ реализации временных глобальных переменных.

В общем модуле с кешированием на сеанс пишется функция

Функция ГлобальныеПеременные() Экспорт
Возврат Новый Структура();
КонецФункции

А потом в других местах с ней работают кеш.ГлобальныеПеременные().Вставить( "НовПараметр", 3 );

и при следующем обращении там будет этот параметр

(33) Хорошим тоном будет вообще отказ от изменения значений через параметры. У функции должна быть одна точка возврата - возвращаемое значение. Если их много - можно использовать структуру. Радикально повышает читаемость и отлаживаемость кода.

(41) так и до ООП дойдем))

(41) Ты, конечно, недальновидно это заявил, но право на свое мнение, ты, естественно, имеешь.

(25) Ума не приложу. Примитивные типы всегда присваиваются по значению, а коллекции всегда по ссылке. Поэтому фишки именно со "Знач" я тут не просекаю.

(40) прям альтернатива ПараметрамСеанса

(38) За такое поведение, конечно, разработчикам платформы надо что-то отстреливать.

(46) Не согласен. Это, конечно, менее похоже на более другие языки, зато применительно к зергам-одинэсникам более безопасно.

(38) Ну лоханулся. Не проснулся ещё.
(46) А что, на более другом языке такого нет?

(40) Тут нет гарантии, что платформа не почистит кеш когда ей вздумается. А ей ведь вздумается…

(48) Концептуально, переданное по значению должно умереть вместе с функцией.

(49) а я и говорю, что так себе способ. Кеш живет чот минут 20, вроде, во всяком случае я на этот срок ориентируюсь при использовании кешируемых методов.

(50) а если аналогичный пример, но не с коллекцией? Тут тоже пометка удаления должна откатится?

Процедура ПометитьНаУдаление( Знач пСсылка )

об = пСсылка.ПолучитьОбъект();
об.УстановитьПометкуУдаления(Истина);

КонецПроцедуры

(52) Ты оперируешь уже с другим объектом.
По-честному, пСсылка должен стать внутри процедуры "только для чтения".

(53) дык он её итак только читает

(50) И в каком языке дохнет объект, ссылку на который передают по значению?

Например,

Процедура ЧтоНибудь(пСсылка)
    пСсылка = Справочники.Номенклатура.ПустоеЗначение();
КонецПроцедуры

ЧтоНибудь(КакаяТоНоменклатура.ПолучитьОбъект().Ссылка);

это верный способ выстрелить себе в ногу?

(55) А где указано, что ты передаешь ссылку?

(57) MyFunc(&MyVar)

Получается, что передача, например, массива без или с Знач не имеет разницы.

(58) Так это не передача по значению!

(60) Это передача по значению ссылки, а не объекта )

(61) Значит ты и в функции ожидаешь ссылку, а не значение.
Сигнатура функции какая у тебя будет?

(62) void MyFunc(MyObject* MyVar)

(63) Ну так это и есть передача по ссылке.
Другое дело, что в сях коллекции только так и можно передавать.

java в этом плане честнее. Там нет никаких "знач" и всё передается по значению. Только оговаривается, что "значением" объекта является ссылка на объект в куче.

Кстати, как отработает (38) в клиент-сервере?

(66)+ в смысле, в УФ

(66) так же

(68) а вот и нет
0
0

(59) при передачи агрегатных параметров по значению, их можно изменять

Если с клиента на клиент, то
0
1
Если с клиента на сервер, то
0
0

(66) 0 будет

(71) Спасибо 1Су за "радости" отладки.

Выходит, что при клиент-серверном взаимодействии, Знач отрабатывает "честно" даже с коллекциями

(73) Примечательно, что про эти особенности СП умалчивает, ну или я не там смотрю

(71) а вот сейчас обидно было

Проверил на 2014, файловая. Не подтверждается (71)

(77) а где у тебя сервер в файловой?

(77) а я на клиент-серверной

правда, у меня 8.2.19

Ну вообще (71) объясняется в (3)

(81) это все понятно, меня интересует ответ на (35)

А, не, подтверждается! Это я косякнул.

(82) Когда среда не меняется (клиент-клиент, сервер-сервер), то у коллекции передается ссылка, а вот при смене среды передается весь объект, потому что его тупо на сервере нет. Если стоит знач, то назад ничего не передается, если не стоит, то этот весь объект возвращается.

Я так это понимаю.

Вот код, можете проверить:


&НаСервереБезКонтекста
Процедура Команда1НаСервере()
    м=Новый Массив();
    Сообщить(м.Количество());
    Фигакс(м);
    Сообщить(м.Количество());
    Фигакс1(м);
    Сообщить(м.Количество());
КонецПроцедуры

&НаКлиенте
Процедура Команда1(Команда)
    Команда1НаСервере();
КонецПроцедуры

&НаКлиенте
Процедура Команда2(Команда)
    м=Новый Массив();
    Сообщить(м.Количество());
    Фигакс(м);
    Сообщить(м.Количество());
    Фигакс1(м);
    Сообщить(м.Количество());
КонецПроцедуры

&НаКлиентеНаСервереБезКонтекста
Процедура Фигакс(Знач мм)
    мм.Добавить(0);    
КонецПроцедуры

&НаСервереБезКонтекста
Процедура Фигакс1(Знач мм)
    мм.Добавить(0);    
КонецПроцедуры

Даже на файловой.

(84) Только не сам объект передается, а его копия

Усугубим ситуацию:



&НаСервереБезКонтекста
Процедура Команда1НаСервере()
    м=Новый Массив();
    Сообщить(м.Количество());
    Фигакс(м);
    Сообщить(м.Количество());
    Фигакс1(м);
    Сообщить(м.Количество());
КонецПроцедуры

&НаКлиенте
Процедура Команда1(Команда)
    Команда1НаСервере();
КонецПроцедуры

&НаКлиенте
Процедура Команда2(Команда)
    м=Новый Массив();
    Сообщить(м.Количество());
    Фигакс(м);
    Сообщить(м.Количество());
    Фигакс1(м);
    Сообщить(м.Количество());
КонецПроцедуры

&НаКлиентеНаСервереБезКонтекста
Процедура Фигакс(Знач мм)
    Перем ммм;
    ммм = мм;
    ммм.Добавить(0);    
КонецПроцедуры

&НаСервереБезКонтекста
Процедура Фигакс1(Знач мм)
    Перем ммм;
    ммм = мм;
    ммм.Добавить(0);    
КонецПроцедуры


(86) Что файловая, что клиент-серверная, работа одинаковая

(89) не всегда

Исходя из вышеизложенного, легко видеть, что Знач не защищает вас от случайной "порчи" объекта внутри процедуры.

(90) "При работе в файл-серверном варианте клиент и сервер представляют собой один компьютер, но на логику взаимодействия это не влияет"

Продолжаем издевательства:


&НаСервереБезКонтекста
Процедура Команда1НаСервере()
    м=Новый Массив();
    Сообщить(ТипЗнч(м));
    Фигакс(м);
    Сообщить(ТипЗнч(м));
    Фигакс1(м);
    Сообщить(ТипЗнч(м));
КонецПроцедуры

&НаКлиенте
Процедура Команда1(Команда)
    Команда1НаСервере();
КонецПроцедуры

&НаКлиенте
Процедура Команда2(Команда)
    м=Новый Массив();
    Сообщить(ТипЗнч(м));
    Фигакс(м);
    Сообщить(ТипЗнч(м));
    Фигакс1(м);
    Сообщить(ТипЗнч(м));
КонецПроцедуры

&НаКлиентеНаСервереБезКонтекста
Процедура Фигакс(Знач мм)
    Перем ммм;
    ммм = Новый Структура;
    мм = ммм;    
КонецПроцедуры

&НаСервереБезКонтекста
Процедура Фигакс1(Знач мм)
    Перем ммм;
    ммм = Новый Структура;
    мм = ммм;    
КонецПроцедуры


что выведет этот код?

(93) массивы

(93) "Например, если в процедуру по значению передан массив, то можно очистить этот массив методом Очистить(), но нельзя изменить в вызывающей процедуре само значение параметра"

(71) идиоты

(96) Ну почему? Логика тут есть. Смотри (3).
На клиенте коллекции только по ссылке ходят (чтобы не гоняли через стек большие коллекции), но при серверном вызове это выливается в то, что коллекция поползет обратно с сервера и десериализуется, что зачастую абсолютно лишнее. Вот и сделали другое поведение. Хотя путаницу вызывает, да.

Если подытожить, то Рарус из (0) был прав, массово используя Знач.

(97) это неправильно потому что функция/процедура ведет себя по-разному, в зависимости от места вызова

(73) Сериализация же. Вполне логично :)

(99) А мне очень понравилась фраза из (3) :)

"В-четвёртых, использование ключевого слова Знач при объявлении параметров процедур и функций. Дело в том, что при клиент-серверном взаимодействии ЭТО КЛЮЧЕВОЕ СЛОВО ЗНАЧИТ СОВСЕМ НЕ ТО, что при работе внутри одного компьютера, клиентского или серверного.

Чувствую себя на уроке информатики в 9том классе.
Реально, никто не задавался вопросом, как передача параметров работает? Не могу поверить.

Да все наверное задавались, но, думаю, многие не знали, например (71).

(102) для элементарных типов: числа, строки, булево, даты - поведение одинаковое как для клиент/серверной передачи, так и для внутри одного клиента (или сервера) - со Знач не возвращает измененный параметр, без - возвращает

для объектов: для клиент/серверной передачи сериализуется в копию объекта, при этом со Знач в одну только сторону, а без - в обе
внутри клиента (или сервера) - передается ссылка на объект, соответственно со Знач в одну сторону, без - в обе

(102) Указание ЗНАЧ, вовсе не означает что передается ЗНАЧЕНИЕ параметра, а не ссылка на него (а ведь это и должно происходить), все зависит от условий вызова функции.

(105)  Так это и без 1с понятно.

(106) Логичнее было бы заменить ключевое слово ЗНАЧ, скажем, на НЕВОЗВР.

(107) логичнее было бы вообще запретить возвращать параметры процедур, либо указывать это явно.

(107)+ ...либо наоборот, по умолчанию, без ключевых слов движение параметра только в процедуру/функцию, а если нужно вернуть значение параметра обратно, то использовать перед ним какой-нибудь ВОЗВР.

Глянул сейчас в типовой "Управление Скромной Фирмой" форму документа "ПриходнаяНакладная", и о, ужас, из нескольких десятков процедур, где есть передача ссылок на объекты (договор, валюта, контрагент), только в одной процедуре есть ключевое слово ЗНАЧ:

Процедура ОбработатьИзмененияПоКнопкеЦеныИВалюты(Знач ВалютаРасчетовПередИзменением, ПересчитатьЦены = Ложь)

Все остальное НЕОПТИМИЗОРОВАНО согласно (3), хотя конфигурация на УФ изначально делалась.

(99) С точки зрения прозрачности - да, неправильно. Но тут из двух зол выбирали меньшее. Была бы статическая типизация - компилятор просто ругался бы при попытке указания Знач не для примитивных типов на клиенте и всё было бы совсем ок.

А, не. Гоню. Для объектных типов на клиенте Знач работает как final в java. Объект передается по ссылке, но переназначить ссылку нельзя. А без Знач - можно.

(108)+1

Вернее, не совсем так. Запутался.
Короче без Знач - ссылка на объект передается напрямую. А со Знач - помещается в стек, что гарантирует неизменность исходной ссылки.

Вот она старая добрая Миста, с глобальными вопросами, а не пустым трепом про бог знает что...

Если Знач - добро, почему оно редко встречается в типовых? Причем именно там, где можно обойтись без возврата параметра процедур? Может, выигрыш в производительности, если он есть, ничтожен?

(116) Если передавать ссылки на объекты, то да, выигрыш ничтожен (но он есть), а если коллекции, то тут различия в производительности серьезные.