Попроще. Если он есть вообще. Печатных форм типа Актов и Счетов. Может кто сталкивался


// Архивирование и отправка файла с данными
    Если ОтправитьПоЭлектроннойПочте Тогда
    
        ФайлНаДиске = Новый Файл(ИмяФайлаДанных);
        
        ИмяАрхива = ФайлНаДиске.Путь + "data_rtu.zip";
        
        Архив = Новый ЗаписьZipФайла(ИмяАрхива);
        
        Архив.Добавить(ИмяФайлаДанных);
        
        Архив.Записать();
        
        // Отправка письмом на e-mail основного контактного лица контрагента
        Если НЕ Покупатель.Пустая() И НЕ Покупатель.ОсновноеКонтактноеЛицо.Пустая() Тогда
        
            ОтборДанных = Новый Структура;
            ОтборДанных.Вставить("Объект", Покупатель.ОсновноеКонтактноеЛицо);
            ОтборДанных.Вставить("Тип",    Перечисления.ТипыКонтактнойИнформации.АдресЭлектроннойПочты);
            ОтборДанных.Вставить("Вид",    Справочники.ВидыКонтактнойИнформации.АдресЭлектроннойПочтыКонтактногоЛицаКонтрагента);
            
            ДанныеСтруктура = РегистрыСведений.КонтактнаяИнформация.ПолучитьПоследнее(, ОтборДанных);
            
            ЭлАдрес = ДанныеСтруктура.Представление;
            
            ЭлПочтаПользователя = РегистрыСведений.НастройкиПользователей.Получить(Новый Структура("Пользователь, Настройка", ПараметрыСеанса.ТекущийПользователь, ПланыВидовХарактеристик.НастройкиПользователей.ОсновнаяУчетнаяЗапись));
            
            Если ЭлПочтаПользователя = Неопределено ИЛИ НЕ ЗначениеЗаполнено(ЭлПочтаПользователя.Значение) Тогда
                ЗаписьЖурналаРегистрации("Обмен с покупателями", УровеньЖурналаРегистрации.Предупреждение,, УзелОбменаСтороннейИБ, "СТОП (не указан e-mail для отправки данных)");
                Возврат;
            КонецЕсли;
            
            УчетнаяЗапись = ЭлПочтаПользователя.Значение;
            
            Профиль = УправлениеЭлектроннойПочтой.ПолучитьИнтернетПочтовыйПрофиль(УчетнаяЗапись);
            
            ИнтернетПочта = Новый ИнтернетПочта;
            
            Попытка
                ИнтернетПочта.Подключиться(Профиль);
            Исключение
                ЗаписьЖурналаРегистрации("Обмен с покупателями", УровеньЖурналаРегистрации.Предупреждение,, УзелОбменаСтороннейИБ, "СТОП (ошибка подключения e-mail: " + ОписаниеОшибки() + ")");
                Возврат;
            КонецПопытки;
            
            ПочтовоеСообщение = Новый ИнтернетПочтовоеСообщение;
            
            КодировкаСообщения = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(ПараметрыСеанса.ТекущийПользователь, "КодировкаПисьмаЭлектроннойПочтыПоУмолчанию");
            Если Не ЗначениеЗаполнено(КодировкаСообщения) Тогда
                КодировкаСообщения = "utf-8";
            КонецЕсли;
            
            ПочтовоеСообщение.Кодировка = КодировкаСообщения;
            
            ПочтовоеСообщение.Вложения.Добавить(Новый ДвоичныеДанные(ИмяАрхива), "data_rtu.zip");
            
            ПочтовоеСообщение.ИмяОтправителя = "Обмен данными Бина Групп";
            ПочтовоеСообщение.Отправитель    = УчетнаяЗапись.АдресЭлектроннойПочты;
            ПочтовоеСообщение.Тема           = "Выгрузка документов";
            
            Получатель = ПочтовоеСообщение.Получатели.Добавить();
            Получатель.Адрес           = ЭлАдрес;
            Получатель.ОтображаемоеИмя = "" + Покупатель.ОсновноеКонтактноеЛицо;
            Получатель.Кодировка       = КодировкаСообщения;
            
            Попытка
                ИнтернетПочта.Послать(ПочтовоеСообщение);
            Исключение
                ЗаписьЖурналаРегистрации("Обмен с покупателями", УровеньЖурналаРегистрации.Предупреждение,, УзелОбменаСтороннейИБ, "СТОП (ошибка отправки e-mail: " + ОписаниеОшибки() + ")");
                Возврат;
            КонецПопытки;
            
            ИнтернетПочта.Отключиться();
        
        КонецЕсли;
    
    КонецЕсли;


(1) +1

Спасибо !!!!!!!

А это из типовой

Функция ПолучитьИнтернетПочтовыйПрофиль(УчетнаяЗапись) Экспорт

    Профиль = Новый ИнтернетПочтовыйПрофиль;
    
    Профиль.АдресСервераPOP3 = УчетнаяЗапись.POP3Сервер;
    Профиль.АдресСервераSMTP = УчетнаяЗапись.SMTPСервер;
    Если УчетнаяЗапись.ВремяОжиданияСервера > 0 Тогда
        Профиль.ВремяОжидания = УчетнаяЗапись.ВремяОжиданияСервера;
    КонецЕсли;
    Профиль.Пароль           = УчетнаяЗапись.Пароль;
    Профиль.Пользователь     = УчетнаяЗапись.Логин;
    Профиль.ПортPOP3         = УчетнаяЗапись.ПортPOP3;
    Профиль.ПортSMTP         = УчетнаяЗапись.ПортSMTP;
    
    Если УчетнаяЗапись.ТребуетсяSMTPАутентификация Тогда
        Профиль.АутентификацияSMTP = СпособSMTPАутентификации.ПоУмолчанию;
        Профиль.ПарольSMTP         = УчетнаяЗапись.ПарольSMTP;
        Профиль.ПользовательSMTP   = УчетнаяЗапись.ЛогинSMTP;
    Иначе
        Профиль.АутентификацияSMTP = СпособSMTPАутентификации.БезАутентификации;
        Профиль.ПарольSMTP         = "";
        Профиль.ПользовательSMTP   = "";
    КонецЕсли;
    
    Возврат Профиль;

КонецФункции