Добрый день, обмен УТ11 и БП КОРП 3.0

При обмене выдает ошибку :
Ошибка в обработчике события ПослеЗагрузкиОбъекта
    ИмяПКО                 =  РасходныйКассовыйОрдер
    ТипОбъекта             =  Выдача наличных
    Объект                 =  Выдача наличных 25О00000002 from 23.05.2015 00:00:00
    Обработчик             =  ПослеЗагрузкиОбъекта
    ОписаниеОшибки         =  Cannot convert value to Boolean
    ПозицияМодуля          =  (22)
    КСообщенияОбОшибках    =  21

Загрузил правила в конвертацию, нашел обработчик. Смотрю модуль не могу понять где же тут может быть преобразование к булеву типу?

Процедура ПКО_ПриходныйКассовыйОрдер_ПослеЗагрузкиОбъекта(ФайлОбмена, Отказ, Ссылка, Объект, ПараметрыОбъекта, ОбъектМодифицирован,
    ИмяТипаОбъекта, ОбъектНайден) Экспорт

    РозничнаяТорговляОблагаетсяЕНВД = УчетнаяПолитика.РозничнаяТорговляОблагаетсяЕНВД(Объект.Организация, Объект.Дата);
    
    Если Объект.ВидОперации = Перечисления.ВидыОперацийПКО.РозничнаяВыручка Тогда
        
        Объект.Контрагент = Справочники.Склады.ПустаяСсылка();
        
        Если НЕ ЗначениеЗаполнено(Объект.СчетУчетаРасчетовСКонтрагентом)
                ИЛИ ЗначениеЗаполнено(Объект.Ссылка)
                    И (Объект.Организация <> Объект.Ссылка.Организация
                        ИЛИ Объект.Дата <> Объект.Ссылка.Дата
                        ИЛИ Объект.ВидОперации <> Объект.Ссылка.ВидОперации) Тогда
            
            Если РозничнаяТорговляОблагаетсяЕНВД Тогда
                Объект.СчетУчетаРасчетовСКонтрагентом = ПланыСчетов.Хозрасчетный.ВыручкаЕНВД;
            Иначе
                Объект.СчетУчетаРасчетовСКонтрагентом = ПланыСчетов.Хозрасчетный.ВыручкаНеЕНВД;
            КонецЕсли;
            
        КонецЕсли;
    
    КонецЕсли;
    
    Для Каждого СтрокаПлатеж Из Объект.РасшифровкаПлатежа Цикл
        
        Если (Объект.ВидОперации = Перечисления.ВидыОперацийПКО.ОплатаПокупателя)
                ИЛИ (Объект.ВидОперации = Перечисления.ВидыОперацийПКО.ВозвратОтПоставщика) Тогда
            СтрокаПлатеж.СпособПогашенияЗадолженности = Перечисления.СпособыПогашенияЗадолженности.Автоматически;
        КонецЕсли;
        
    КонецЦикла;
    
    СчетаУчетаВДокументах.ЗаполнитьПередОтображениемПользователю(Объект);

КонецПроцедуры

Процедура ПКО_ПриходныйКассовыйОрдер_ПоследовательностьПолейПоиска(НомерВариантаПоиска, СвойстваПоиска, ПараметрыОбъекта, ПрекратитьПоиск,
    СсылкаНаОбъект, УстанавливатьУОбъектаВсеСвойстваПоиска, СтрокаИменСвойствПоиска) Экспорт

    

КонецПроцедуры

Извиняюсь не тот обработчик

Процедура ПКО_РасходныйКассовыйОрдер_ПослеЗагрузкиОбъекта(ФайлОбмена, Отказ, Ссылка, Объект, ПараметрыОбъекта, ОбъектМодифицирован,
    ИмяТипаОбъекта, ОбъектНайден) Экспорт

    Если Объект.ВидОперации = Перечисления.ВидыОперацийРКО.ВыдачаПодотчетномуЛицу Тогда
        
        Если Объект.РасшифровкаПлатежа.Количество() = 0 Тогда
            Объект.РасшифровкаПлатежа.Добавить();
        КонецЕсли;
        Объект.РасшифровкаПлатежа[0].СуммаПлатежа = Объект.СуммаДокумента;
            
    КонецЕсли;
    
    Для Каждого СтрокаПлатеж Из Объект.РасшифровкаПлатежа Цикл
        
        Если Объект.ВидОперации = Перечисления.ВидыОперацийРКО.ОплатаПоставщику
                ИЛИ Объект.ВидОперации = Перечисления.ВидыОперацийРКО.ВозвратПокупателю Тогда
                
            СтрокаПлатеж.СпособПогашенияЗадолженности = Перечисления.СпособыПогашенияЗадолженности.Автоматически;
            
            Если ЗначениеЗаполнено(СтрокаПлатеж.ДоговорКонтрагента) Тогда
                
                ЗначенияРеквизитов = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(СтрокаПлатеж.ДоговорКонтрагента, "УчетАгентскогоНДС, ВидДоговора");
                
                Если ЗначенияРеквизитов.УчетАгентскогоНДС Тогда
                    СтрокаПлатеж.СтавкаНДС = Перечисления.СтавкиНДС.БезНДС;
                    СтрокаПлатеж.СуммаНДС  = 0;
                КонецЕсли;
                
            КонецЕсли;
            
        КонецЕсли;
        
    КонецЦикла;
    
    СчетаУчетаВДокументах.ЗаполнитьПередОтображениемПользователю(Объект);

КонецПроцедуры

(2) бегло судя по коду
ЗначенияРеквизитов.УчетАгентскогоНДС - может быть неопределено
Вставьте перед ним
Сообщить(типЗНЧ(ЗначенияРеквизитов.УчетАгентскогоНДС));

(3) Благодарю, сейчас посмотрю.
Пока убрал полностью весь текст обработчика - провожу загрузку, посмотрю что выйдет