Подскажите как можно оптимизировать запрос:
Запрос.Текст = “
Выбрать
РеализацияТовары.Номенклатура,
РеализацияТовары.Количество,
ОстаткиТоваров.КоличествоОстаток,
ОстаткиТоваров.СтоимостьОстаток,
ИЗ Документ.РеализацияТоваров.Товары КАК РеализацияТовары
ЛЕВОЕ СОЕДИНЕНИЕ РегистрыНакопления.ОстаткиТоваров.Остатки КАК ОстаткиТоваров
ПО РеализацияТовары.Номенклатура = ОстаткиТоваров.Номенклатура
ГДЕ ОстаткиТоваров.Склад = &Склад”

я нашел только то что раздел ГДЕ при обращении к виртуальной таблице нужно перенести в параметр. Что ещё можно сделать?

(0) "я нашел только то что раздел ГДЕ при обращении к виртуальной таблице нужно перенести в параметр"

это не только оптимизирует запрос, но и вообще меняет результат запроса

а тебе точно ТЧ всех документов нужна?

(0) что ты получить хочешь? давай с этого начнем

к тому же подумай, что будет, если в ТЧ будет несколько строк одной номенклатуры?

(2) ну это не производственная задача, а скорее учебная. задача состоит в том чтобы "Какие изменения нужно внести в запрос, чтобы повысить производительность и паралелльность работы?"
с параметром я разобрался, но это не всё.

(5) что должен возвращать запрос-то твой? Человеческим языком объяснить можешь?

то есть вариант про то чтобы заменить раздел ГДЕ на параметр (, Склад = &Склад) - это верно, но не всё

(6) как я понимаю остатки номенклатуры в зависимости от склада

(7) ты понимаешь, что у тебя запрос вернет данные ВСЕХ документов?

(5) что за м*д*к такие задачи ставит?
(8) а есть точное объяснение?

(0) какие измерения в таблице ОстаткиТоваров?

(8) главный скилл программиста - внимательно читать постановку задачи и понимать, что хотят получить в итоге. У тебя я этого не вижу.

я извиняюсь, суть запроса исходя из задания звучит так:
"В документе Реализация товаров производится списание товаров с регистра учета себестоимости. В обработке проведения происходит обращение к итогам регистра, ниже приведен фрагмент запроса"

(11) Структура регистра:
Измерения: Склад, Номенклатура. Ресурсы: Количество, Стоимость

Структура документа:
Шапка: Контрагент, Договор, Склад. Табличная часть Товары: Номенклатура, Количество, Цена, Сумма.

(0) Автор покури первый запрос тут http://1c.chistov.pro/2010/06/1-82.html если разберешься с первым запросом, читай дальше там много интересного для тебя будет

(13) тогда нужен, как минимум отбор по ссылке на документ. В предложении ГДЕ

если бы ТЧ было одного документа, условие Ссылка=&ССылка, то я бы еще в параметры остатокв добавил:

Номенклатура В (ВЫБРАТЬ Т.НОменклатура ИЗ Документ.РеализацияТоваров.Товары КАК Т ГДЕ Т.Ссылка=&Ссылка)

полный текст вопроса звучит так, (с блокировками я вроде разобрался):

В документе Реализация товаров производится списание товаров с регистра учета себестоимости. В обработке проведения происходит обращение к итогам регистра, ниже приведен фрагмент запроса. В ростом числа пользователей стали поступать жалобы на возникновение взаимоблокировки при проведении. Какие изменения нужно внести в код обработки проведения и/или текст запроса, чтобы данная проблема решилась? Предложите два способа - для режима автоматического управления блокировками и ручного. Какие еще изменения нужно внести в запрос, чтобы повысить производительность и паралелльность работы?
Фрагмент текста запроса:
Запрос.Текст = “
Выбрать
РеализацияТовары.Номенклатура,
РеализацияТовары.Количество,
ОстаткиТоваров.КоличествоОстаток,
ОстаткиТоваров.СтоимостьОстаток,
ИЗ Документ.РеализацияТоваров.Товары КАК РеализацияТовары
ЛЕВОЕ СОЕДИНЕНИЕ РегистрыНакопления.ОстаткиТоваров.Остатки КАК ОстаткиТоваров
ПО РеализацияТовары.Номенклатура = ОстаткиТоваров.Номенклатура
ГДЕ ОстаткиТоваров.Склад = &Склад”

Структура регистра:
Измерения: Склад, Номенклатура. Ресурсы: Количество, Стоимость

Структура документа:
Шапка: Контрагент, Договор, Склад. Табличная часть Товары: Номенклатура, Количество, Цена, Сумма.

и наверное остатки только по текущему (у документа) складу, это в условие соединения

выгрузить из таблица дока склад и номенклатуру и запилить их в параметры вирт таблицы (в обработке проведения и так уже считанный объект есть)

убрать нафик соединение

автору ответ будет примерно такой - включить режим разделения итогов, сначала сформировать и записать движения, затем запросом к остаткам выбрать отрицательные остатки на границу документа (включая) по складу и номенклатуре (склад и список номенклатуры получаются в коде (не в запросе), указываются в параметрах виртуальной таблицы).

у набора движений не забыть включить "для изменения"

(21) "включить режим разделения итогов" зачем?

(23) параллельность записи итогов

можете привести пример верного на ваш взгляд запроса? как он будет выглядеть. Решение должно быть одним запросом без лишнего кода.

(25) нужен доп код, а запрос вида (Выбрать * Из Регистр.Отстаки(Граница, склад = &Склад, Номенклатура в (&Номенклатура)) где КоличествоКонечныйОстаток < 0)

это самый "параллельный" вариант

(25) "Решение должно быть одним запросом без лишнего кода"
плохая постановка задачи. я бы отказался ее делать.

вот вы тут насоветуете ща и чувака вместо гения возьмут на 120к)

(0) Гений проводит собеседование на свое уже бывшее место?

(26) то есть соединение тут вообще не нужно?!

(30) :))) эта задача вроде как с экзамена на специалиста

(26) Выбрать * Из Регистр.Отстаки(Граница, склад = &Склад, Номенклатура в (&Номенклатура)) где КоличествоКонечныйОстаток < 0)
это получается что запрос будет по конкретной номенклатуре, а не по всей же, или я неверно понимаю?

(33) верно

а нужно то по всей

(35) нет, не по всей, а только по той, которая в ТЧ документа

Текст что-то типа:

ВЫБРАТЬ
   РеализацияТоваровТовары.Ссылка.Склад КАК Склад,
   РеализацияТоваровТовары.Номенклатура,
   СУММА(РеализацияТоваровТовары.Количество) КАК Количество
ПОМЕСТИТЬ ТЧТовары
ИЗ
   Документ.РеализацияТоваров.Товары КАК РеализацияТоваровТовары
ГДЕ
   РеализацияТоваровТовары.Ссылка = &Ссылка
СГРУППИРОВАТЬ ПО
   РеализацияТоваровТовары.Ссылка.Склад,
   РеализацияТоваровТовары.Номенклатура;
ВЫБРАТЬ
   ТЧТовары.Номенклатура,
   ТЧТовары.Количество,
   ОстаткиТоваров.КоличествоОстаток,
   ОстаткиТоваров.СтоимостьОстаток,
ИЗ ТЧТовары КАК ТЧТовары
ЛЕВОЕ СОЕДИНЕНИЕ РегистрыНакопления.ОстаткиТоваров.Остатки (, (Номенклатура, Склад) В (ВЫБРАТЬ ТЧТовары.Номенклатура, ТЧТовары.Склад ИЗ ТЧТовары КАК ТЧТовары)) КАК ОстаткиТоваров
ПО ТЧТовары.Номенклатура = ОстаткиТоваров.Номенклатура

Но это пример только для оптимизации самого ЗАПРОСА.
Fragster же впаривает про оптимизацию АЛГОРИТМА проведения. А это немножко разные вопросы....  ;)

мой вариант ответа был такой:
Запрос.Текст = “
Выбрать
РеализацияТовары.Номенклатура,
РеализацияТовары.Количество,
ОстаткиТоваров.КоличествоОстаток,
ОстаткиТоваров.СтоимостьОстаток,
ИЗ Документ.РеализацияТоваров.Товары КАК РеализацияТовары
ЛЕВОЕ СОЕДИНЕНИЕ РегистрыНакопления.ОстаткиТоваров.Остатки(, Склад = &Склад) КАК ОстаткиТоваров
ПО РеализацияТовары.Номенклатура = ОстаткиТоваров.Номенклатура

Пояснение: при работе с виртуальной таблицей такой как «остатки» использовать условие в разделе ГДЕ – ошибочно, так как система сначала собирает всю таблицу, затем осуществляет отбор, по этому условие отбора необходимо писать в параметрах виртуальной таблицы

на что я получил ответ: Комментарий про параметры виртуальной таблицы верен, но не все учтено. Какой еще фильтр пропущен?

вот и не пойму что имелось ввиду

(32) внимательно прочитай (21)(22) и сделай все как там

(38) если экзамен на спеца, см. (39)

+ к (37): заменить "ОстаткиТоваров.КоличествоОстаток" на "ЕСТЬNULL(ОстаткиТоваров.КоличествоОстаток, 0) КАК КоличествоОстаток"
И тоже самое с ОстаткиТоваров.СтоимостьОстаток

(37) а еще у меня сертификата нет ни одного

(38) Пропущен фильтр по ссылке на документ реализации

(42) Не грусти. Это не главное :)

(43) какой?

походу в (0) не контроль остатков, в (0) - формирование суммы по среднему для списания.

хотя зачем средняя стоимость в разрезе складов - непонятно.

(38) Можно еще номенклатуру запихать в параметры, но это надо ВТ по ТЧ делать.

(48) + как в (37) )))

(47) Не лезь в такие дебри. Наверняка средняя считается в разрезе складов. Кроме того контроль отрицательных остатков в разрезе складов однозначно нужен.

(45) см.(37): строка ГДЕ РеализацияТоваровТовары.Ссылка = &Ссылка

(43) интересно что тут за фильтр имелся ввиду? просто я думаю что если ответ на мой вариант был: Комментарий про параметры виртуальной таблицы верен, но не все учтено. Какой еще фильтр пропущен?
то имелось ввиду что то дописать к ЭТОМУ запросу

(51) понял. спасибо. ну попробую такой вариант показать, посмотрим что скажут

+ к (51). Возможно еще имеется ввиду параметр виртуальной таблицы Остатков - Период. Нужно указывать момент времени документа.

(53) Будь мужиком, прочитай (15) блажь!

(55) да яж только ЗА. но мне седня нужно ответить... вот и обратился.. потому что сам не могу понять че ему ещё надо

кстати ссыль то чет не открывается... хмм.. (15)

(18) Еще бы знать структуру регистра ОстаткиТоваров

(58) это всё что дано было по заданию, видимо предполагается что этой информации достаточно

(58) В (18) структура регистра описана.

(60) Слона-то я не приметил. :)

Тогда монстр-запрос:
ТекстЗапроса =
"ВЫБРАТЬ
|    РеализацияТовары.Номенклатура КАК Номенклатура,
|    СУММА(РеализацияТовары.Количество) КАК Количество
|ПОМЕСТИТЬ ВТРеализацияТовары
|ИЗ
|    Документ.РеализацияТоваров.Товары КАК РеализацияТовары
|ГДЕ
|    РеализацияТовары.Ссылка = &Ссылка
|
|СГРУППИРОВАТЬ ПО
|    РеализацияТовары.Номенклатура
|
|ИНДЕКСИРОВАТЬ ПО
|    Номенклатура;
|
|ВЫБРАТЬ
|    Остатки.Склад КАК Склад,
|    Остатки.Номенклатура КАК Номенклатура,
|    Остатки.КоличествоОстаток КАК КоличествоОстаток,
|    Остатки.СтоимостьОстаток КАК СтоимостьОстаток
|ПОМЕСТИТЬ ВТОстатки
|ИЗ
|    РегистрНакопления.ОстаткиТоваров.Остатки(
|            ,
|            Склад = &Склад
|                И Номенклатура В (ВЫБРАТЬ Номенклатура ИЗ ВТРеализацияТовары)) КАК Остатки
|
|ИНДЕКСИРОВАТЬ ПО
|    Номенклатура;
|
|ВЫБРАТЬ
|    ВТРеализацияТовары.Номенклатура КАК Номенклатура,
|    ВТРеализацияТовары.Количество КАК Количество,
|    ЕСТЬNULL(ВТОстатки.КоличествоОстаток, 0) КАК КоличествоОстаток,
|    ЕСТЬNULL(ВТОстатки.СтоимостьОстаток, 0) КАК СтоимостьОстаток
|ИЗ
|    ВТРеализацияТовары КАК ВТРеализацияТовары
|        ЛЕВОЕ СОЕДИНЕНИЕ ВТОстатки КАК ВТОстатки
|        ПО ВТРеализацияТовары.Номенклатура = ВТОстатки.Номенклатура"

Для автоматического режима блокировок добавить во второй запрос "ДЛЯ ИЗМЕНЕНИЯ РегистрНакопления.ОстаткиТоваров.Остатки"

Для управляемого перед выполнением запроса установить управляемую блокировку:

Блокировка = Новый БлокировкаДанных;
ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.ОстаткиТоваров");
ЭлементБлокировки.УстановитьЗначение("Склад", Склад);
ЭлементБлокировки.ИсточникДанных = Товары;
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Номенклатура", "Номенклатура");
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
Блокировка.Заблокировать();

(63) а сам запрос больше менять не нужно?! я в смысле того что имелось ввиду:  Комментарий про параметры виртуальной таблицы верен, но не все учтено. Какой еще фильтр пропущен?

(64)
> а сам запрос больше менять не нужно?!

Кроме "ДЛЯ ИЗМЕНЕНИЯ" нет, не нужно.

> Какой еще фильтр пропущен?
По номенклатуре "Номенклатура В (ВЫБРАТЬ Номенклатура ИЗ ВТРеализацияТовары)"