Сортировка результатов отчета

вот эта процедура модуля отчета формирует запрос:
Процедура ЗаполнитьНачальныеНастройки() Экспорт
    СтруктураПредставлениеПолей = Новый Структура;
    МассивОтбора = Новый Массив;
    ПостроительОтчета = ОбщийОтчет.ПостроительОтчета;

    Текст = "
    |ВЫБРАТЬ //РАЗЛИЧНЫЕ
    |    СУММА(КоличествоОстаток) КАК Количество,
    |    СУММА(КоличествоМестОстаток) КАК КоличествоМест,
    |    СУММА(КоличествоОстаток*Номенклатура.ЕдиницаХраненияОстатков.Коэффициент) КАК КоличествоБазовыхЕд,
    |    СУММА(КоличествоОстаток*Номенклатура.ЕдиницаХраненияОстатков.Коэффициент/Номенклатура.ЕдиницаДляОтчетов.Коэффициент) КАК КоличествоЕдиницОтчетов,
    |    0 КАК ЦенаВРознице,
    |    Склад КАК Склад,
    |    Склад.Представление КАК СкладПредставление,
    |    Номенклатура КАК Номенклатура,
    |    Номенклатура.Представление КАК НоменклатураПредставление,
    |    ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков КАК НоменклатураЕдиницаХраненияОстатков,
    |    ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков.Представление КАК НоменклатураЕдиницаХраненияОстатковПредставление
    |    //СВОЙСТВА
    |{ВЫБРАТЬ
    |    Склад.* КАК Склад,
    |    Номенклатура.* КАК Номенклатура,
    |    ТаблицаРегистра.Номенклатура.БазоваяЕдиницаИзмерения КАК НоменклатураБазоваяЕдиницаИзмерения,
    |    ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков КАК НоменклатураЕдиницаХраненияОстатков,
    |    ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
    |    СерияНоменклатуры.* КАК СерияНоменклатуры,
    |    Качество.* КАК Качество
    |    //СВОЙСТВА
    |}
    |ИЗ РегистрНакопления.ТоварыНаСкладах.Остатки(&ДатаКон,
    |                {Склад.* КАК Склад,
    |                Номенклатура.* КАК Номенклатура,
    |                ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
    |                СерияНоменклатуры.* КАК СерияНоменклатуры,
    |                Качество.* КАК Качество}) КАК ТаблицаРегистра
    |//СОЕДИНЕНИЯ
    |СГРУППИРОВАТЬ ПО
    |    Номенклатура,
    |    Склад
    |//СГРУППИРОВАТЬПО

    |{ГДЕ
    |    ЛОЖЬ КАК НеавтоматизированнаяТорговаяТочка
    |//СВОЙСТВА
    |//КАТЕГОРИИ
    |}
    |ОБЪЕДИНИТЬ ВСЕ
    |ВЫБРАТЬ //РАЗЛИЧНЫЕ
    |    СУММА(КоличествоОстаток) КАК Количество,
    |    СУММА(0) КАК КоличествоМест,
    |    СУММА(КоличествоОстаток*Номенклатура.ЕдиницаХраненияОстатков.Коэффициент) КАК КоличествоБазовыхЕд,
    |    СУММА(КоличествоОстаток*Номенклатура.ЕдиницаХраненияОстатков.Коэффициент/Номенклатура.ЕдиницаДляОтчетов.Коэффициент) КАК КоличествоЕдиницОтчетов,
    |    ЦенаВРознице КАК ЦенаВРознице,
    |    Склад КАК Склад,
    |    Склад.Представление КАК СкладПредставление,
    |    Номенклатура КАК Номенклатура,
    |    Номенклатура.Представление КАК НоменклатураПредставление,
    |    ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков КАК НоменклатураЕдиницаХраненияОстатков,
    |    ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков.Представление КАК НоменклатураЕдиницаХраненияОстатковПредставление
    |    //СВОЙСТВА
    |{ВЫБРАТЬ
    |    Склад.* КАК Склад,
    |    Номенклатура.* КАК Номенклатура,
    |    Номенклатура.БазоваяЕдиницаИзмерения КАК НоменклатураБазоваяЕдиницаИзмерения,
    |    ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков КАК НоменклатураЕдиницаХраненияОстатков,
    |    ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
    |    СерияНоменклатуры.* КАК СерияНоменклатуры,
    |    ЦенаВРознице КАК ЦенаВРознице,
    |    NULL КАК Качество
    |    //СВОЙСТВА
    |}
    |ИЗ РегистрНакопления.ТоварыВНеавтоматизированныхТорговыхТочках.Остатки(&ДатаКон,
    |                {Склад.* КАК Склад,
    |                Номенклатура.* КАК Номенклатура,
    |                ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
    |                СерияНоменклатуры.* КАК СерияНоменклатуры
    |                }) КАК ТаблицаРегистра
    |//СОЕДИНЕНИЯ
    |СГРУППИРОВАТЬ ПО
    |    Номенклатура,
    |    ЦенаВРознице,
    |    Склад
    |//СГРУППИРОВАТЬПО

    |{ГДЕ
    |    ИСТИНА КАК НеавтоматизированнаяТорговаяТочка
    |//СВОЙСТВА
    |//КАТЕГОРИИ
    |}
    |{УПОРЯДОЧИТЬ ПО
    |    Склад.* КАК Склад,
    |    Номенклатура.* КАК Номенклатура,
    |    ТаблицаРегистра.Номенклатура.БазоваяЕдиницаИзмерения.* КАК НоменклатураБазоваяЕдиницаИзмерения,
    |    ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков.* КАК НоменклатураЕдиницаХраненияОстатков,
    |    ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
    |    СерияНоменклатуры.* КАК СерияНоменклатуры,
    |    Качество.* КАК Качество,
    |    Количество,
    |    КоличествоМест,
    |    ЦенаВРознице КАК ЦенаВРознице,
    |    КоличествоБазовыхЕд
    |//ОБЩИЕ_СВОЙСТВА
    |}
    |{ИТОГИ ПО
    |    Склад.* КАК Склад,
    |    Номенклатура.* КАК Номенклатура,
    |    Номенклатура.БазоваяЕдиницаИзмерения.* КАК НоменклатураБазоваяЕдиницаИзмерения,
    |    Номенклатура.ЕдиницаХраненияОстатков.* КАК НоменклатураЕдиницаХраненияОстатков,
    |    ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
    |    СерияНоменклатуры.* КАК СерияНоменклатуры,
    |    Качество.* КАК Качество,
    |    ЦенаВРознице КАК ЦенаВРознице
    |//ОБЩИЕ_СВОЙСТВА
    |}
    |ИТОГИ
    |    СУММА(Количество),
    |    СУММА(КоличествоМест),
    |    СУММА(КоличествоБазовыхЕд),
    |    СУММА(КоличествоЕдиницОтчетов)
    |ПО ОБЩИЕ ,
    |    Номенклатура ИЕРАРХИЯ  КАК Номенклатура, Склад КАК Склад";

    СтруктураПредставлениеПолей = Новый Структура(
    "Склад,
    |Номенклатура,
    |ХарактеристикаНоменклатуры,
    |СерияНоменклатуры,
    |Качество,
    |ЦенаВРознице,
    |НоменклатураБазоваяЕдиницаИзмерения,
    |НоменклатураЕдиницаХраненияОстатков,
    |НеавтоматизированнаяТорговаяТочка",
    "Склад",
    "Номенклатура",
    "Характеристика номенклатуры",
    "Серия номенклатуры",
    "Качество",
    "Цена в рознице ("+ СокрЛП(Константы.ВалютаРегламентированногоУчета.Получить()) + " )",
    "Базовая единица измерения",
    "Единица хранения остатков",
    "Остатки по неавтоматизированным торговым точкам");

    Если ОбщийОтчет.ИспользоватьСвойстваИКатегории Тогда
        ТекстПоляСвойств= "";
        ТекстПоляКатегорий = "";

        ТаблицаПолей = Новый ТаблицаЗначений;
        ТаблицаПолей.Колонки.Добавить("ПутьКДанным");  // описание поля запроса поля, для которого добавляются свойства и категории. Используется в условии соединения с регистром сведений, хранящим значения свойств или категорий
        ТаблицаПолей.Колонки.Добавить("Представление");// представление поля, для которого добавляются свойства и категории.
        ТаблицаПолей.Колонки.Добавить("Назначение");   // назначение свойств/категорий объектов для данного поля
        ТаблицаПолей.Колонки.Добавить("ТипЗначения");  // тип значения поля, для которого добавляются свойства и категории. Используется, если не установлено назначение
        ТаблицаПолей.Колонки.Добавить("НетКатегорий"); // признак НЕиспользования категорий для объекта

        СтрокаТаблицы = ТаблицаПолей.Добавить();
        СтрокаТаблицы.ПутьКДанным = "Номенклатура";
        СтрокаТаблицы.Представление = "Номенклатура";
        СтрокаТаблицы.Назначение = ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_Номенклатура;

        СтрокаТаблицы = ТаблицаПолей.Добавить();
        СтрокаТаблицы.ПутьКДанным = "Склад";
        СтрокаТаблицы.Представление = "Склад";
        СтрокаТаблицы.Назначение = ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_Склады;

        СтрокаТаблицы = ТаблицаПолей.Добавить();
        СтрокаТаблицы.ПутьКДанным = "ХарактеристикаНоменклатуры";
        СтрокаТаблицы.Представление = "Характеристика номенклатуры";
        СтрокаТаблицы.Назначение = ПланыВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_ХарактеристикиНоменклатуры;

        ДобавитьВТекстСвойстваИКатегории(ТаблицаПолей, Текст, СтруктураПредставлениеПолей,
                ОбщийОтчет.мСоответствиеНазначений, ПостроительОтчета.Параметры
                ,, ТекстПоляКатегорий, ТекстПоляСвойств,,,,,,ОбщийОтчет.мСтруктураДляОтбораПоКатегориям);

        ДобавитьВТекстСвойстваОбщие(Текст, ТекстПоляСвойств, "//ОБЩИЕ_СВОЙСТВА");

    КонецЕсли;

    ПостроительОтчета.Текст = Текст;

    Если ОбщийОтчет.ИспользоватьСвойстваИКатегории = Истина Тогда

        УстановитьТипыЗначенийСвойствИКатегорийДляОтбора(ПостроительОтчета, ТекстПоляКатегорий, ТекстПоляСвойств, ОбщийОтчет.мСоответствиеНазначений, СтруктураПредставлениеПолей);

    КонецЕсли;

    Если ОбщийОтчет.Показатели.Найти("Количество", "Имя") = Неопределено Тогда
        ОбщийОтчет.ЗаполнитьПоказатели("Количество", "Количество в единицах хранения остатков", Истина, "ЧЦ=15; ЧДЦ=5");
    КонецЕсли;
    Если ОбщийОтчет.Показатели.Найти("КоличествоБазовыхЕд", "Имя") = Неопределено Тогда
        ОбщийОтчет.ЗаполнитьПоказатели("КоличествоБазовыхЕд", "Количество в базовых единицах измерения", Ложь, "ЧЦ=15; ЧДЦ=5");
    КонецЕсли;
    Если ОбщийОтчет.Показатели.Найти("КоличествоЕдиницОтчетов", "Имя") = Неопределено Тогда
        ОбщийОтчет.ЗаполнитьПоказатели("КоличествоЕдиницОтчетов", "Количество в ед. отчетов", Ложь, "ЧЦ=15; ЧДЦ=5");
    КонецЕсли;

    Если ОбщийОтчет.Показатели.Найти("КоличествоМест", "Имя") = Неопределено Тогда
        ОбщийОтчет.ЗаполнитьПоказатели("КоличествоМест", "Количество мест", Ложь, "ЧЦ=15; ЧДЦ=5");
    КонецЕсли;


    МассивОтбора.Добавить("Номенклатура");
    МассивОтбора.Добавить("Склад");

    ЗаполнитьПредставленияПолей(СтруктураПредставлениеПолей, ПостроительОтчета);
    ОчиститьДополнительныеПоляПостроителя(ПостроительОтчета);
    ЗаполнитьОтбор(МассивОтбора, ПостроительОтчета);

    ПостроительОтчета.ИзмеренияСтроки.Удалить(ПостроительОтчета.ИзмеренияСтроки.Найти("Склад"));
    ПостроительОтчета.ИзмеренияКолонки.Добавить("Склад", "Склад", ТипИзмеренияПостроителяОтчета.Элементы);

    ОбщийОтчет.мСтруктураСвязиПоказателейИИзмерений = Новый Структура("Количество, КоличествоБазовыхЕд", Новый Структура("НоменклатураЕдиницаХраненияОстатков, Номенклатура"), Новый Структура("НоменклатураБазоваяЕдиницаИзмерения, Номенклатура"), Новый Структура);

КонецПроцедуры