8.1 как из экселя в ТабЧ перенести строки и упорядочить?

Полная функция которая создает массив документов из одной большой таблицы, в которой например нужно создать множество документов по колонке Контрагент.

Могут быть и множество полей по которым создавать больше документов. Для этого просто сворачиваешь общую таблицы по большему количеству полей и в методе НайтиСтроки используешь в отборе несколько ключевых полей.

&НаСервере
Функция мЗаказПокупателя()

    УстановитьПривилегированныйРежим(Истина);

    МассивДокументов = Новый Массив;

    Объект.ОбработкаЗаказаПокупателя.Сортировать("Поле_Контрагент,Размещение,КлючСтроки");

    ТаблицаРазделения = Объект.ОбработкаЗаказаПокупателя.Выгрузить();
    ТаблицаРазделения.Свернуть("Поле_Контрагент");

    Для Каждого Шапка Из ТаблицаРазделения Цикл
        ПараметрыОтбора = Новый Структура;
        ПараметрыОтбора.Вставить("Поле_Контрагент", Шапка.Поле_Контрагент);

        ТаблЧасть = Объект.ОбработкаЗаказаПокупателя.НайтиСтроки(ПараметрыОтбора);

        НовыйДокумент = Документы.ЗаказКлиента.СоздатьДокумент();
        НовыйДокумент.Дата        = ДатаДокумента;
        Если ЗначениеЗаполнено(НомерДокумента) Тогда
            НовыйДокумент.Номер = НомерДокумента;
        КонецЕсли;

        НовыйДокумент.Комментарий = "Импорт из Excel "+Шапка.Поле_Контрагент;
        НовыйДокумент.Приоритет   = Приоритет;
        НовыйДокумент.Статус      = Статус;
        НовыйДокумент.Менеджер    = Менеджер;

        НовыйДокумент.Организация   = Организация;
        НовыйДокумент.Склад         = ОсновнойСклад;
        НовыйДокумент.Подразделение = Подразделение;
        НовыйДокумент.ЖелаемаяДатаОтгрузки = ДатаОтгрузки;

        Если НЕ ЗначениеЗаполнено(Шапка.Поле_Контрагент) Тогда
            НовыйДокумент.Партнер     = Объект.Партнер;
            Если ЗначениеЗаполнено(Объект.СоглашениеСКлиентом) Тогда
                НовыйДокумент.Соглашение  = Объект.СоглашениеСКлиентом;
                НовыйДокумент.ЗаполнитьУсловияПродажПоCоглашению();
            Иначе
                НовыйДокумент.ЗаполнитьУсловияПродажПоУмолчанию();
            КонецЕсли;
        Иначе
            НайтиКонтрагента = Справочники.Контрагенты.НайтиПоНаименованию(Шапка.Поле_Контрагент);
            НовыйДокумент.Контрагент = НайтиКонтрагента.Ссылка;
            НовыйДокумент.ЗаполнитьУсловияПродажПоУмолчанию();
        КонецЕсли;

        НовыйДокумент.ХозяйственнаяОперация = Перечисления.ХозяйственныеОперации.РеализацияКлиенту;

        НеПересчитыватьСуммуЕслиНетЦены = Ложь;

        Для Каждого Стр из ТаблЧасть Цикл
            Если НЕ ЗначениеЗаполнено(Стр.Номенклатура) Тогда
                Продолжить;
            КонецЕсли;

            Если Стр.Количество = 0 Тогда
                Продолжить;
            КонецЕсли;

            СтрокаТЧ = НовыйДокумент.Товары.Добавить();
            СТрокаТЧ.ВариантОбеспечения = ВариантОбеспечения;
            СтрокаТЧ.Номенклатура     = Стр.Номенклатура;
            СтрокаТЧ.Характеристика   = Стр.ХарактеристикаНоменклатуры;
            СтрокаТЧ.Упаковка         = Стр.Упаковка;
            СтрокаТЧ.Количество       = Стр.Количество;

            КоэффициентУпаковки = ПолучитьКоэффициентУпаковки(Стр.Упаковка);

            СтрокаТЧ.КоличествоУпаковок = Стр.Количество / КоэффициентУпаковки;
            СтрокаТЧ.ВидЦены          = Объект.ВидЦенНоменклатурыПродажи;
            СтрокаТЧ.Склад            = ?(ЗначениеЗаполнено(Стр.Размещение),Стр.Размещение,ОсновнойСклад);
            СтрокаТЧ.ДатаОтгрузки     = ДатаОтгрузки;

            Если Стр.Поле_Сумма > 0 Тогда
                НеПересчитыватьСуммуЕслиНетЦены = Истина;

                СтрокаТЧ.Сумма = Стр.Поле_Сумма;
                СтрокаТЧ.Цена  = Стр.Поле_Сумма/СтрокаТЧ.КоличествоУпаковок;
            Иначе
                СтрокаТЧ.Цена  = Стр.Поле_ЦенаПродажи;
                СтрокаТЧ.Сумма = Стр.Поле_ЦенаПродажи*СтрокаТЧ.КоличествоУпаковок;
            КонецЕсли;
        КонецЦикла;

        СтруктураПересчетаСуммы = ОбработкаТабличнойЧастиКлиентСервер.ПолучитьСтруктуруПересчетаСуммыНДСВСтрокеТЧ(НовыйДокумент);

        СтруктураДействий = Новый Структура;
        СтруктураДействий.Вставить("ЗаполнитьСтавкуНДС", НовыйДокумент.НалогообложениеНДС);
        СтруктураДействий.Вставить("ЗаполнитьСодержание", ОбработкаТабличнойЧастиКлиентСервер.ПолучитьСтруктуруЗаполненияСодержанияУслугиВСтрокеТЧ(НовыйДокумент, Ложь));
        СтруктураДействий.Вставить("ПересчитатьКоличествоЕдиниц");
        СтруктураДействий.Вставить("ПересчитатьСуммуНДС", СтруктураПересчетаСуммы);
        СтруктураДействий.Вставить("ПересчитатьСуммуСНДС", СтруктураПересчетаСуммы);

        Если НЕ НеПересчитыватьСуммуЕслиНетЦены Тогда
            СтруктураДействий.Вставить("ПересчитатьСумму");
        КонецЕсли;

        ОбработкаТабличнойЧастиСервер.ОбработатьТЧ(НовыйДокумент.Товары, СтруктураДействий,Неопределено);

        НовыйДокумент.ЗаполнитьЭтапыГрафикаОплаты();

        НовыйДокумент.СуммаДокумента = НовыйДокумент.Товары.Итог("Сумма");

        НовыйДокумент.Записать();
        МассивДокументов.Добавить(НовыйДокумент.Ссылка);

    КонецЦикла;

    Возврат МассивДокументов;

КонецФункции