переструктурировать запрос

1С v8

01.10.15

✎

11:50

подскажите пожалуйста по запросу:
ВЫБРАТЬ
    ХозрасчетныйДвиженияССубконто.Регистратор КАК регистратор,
    ХозрасчетныйДвиженияССубконто.СчетКт,
    ХозрасчетныйДвиженияССубконто.СчетДт,
    ХозрасчетныйДвиженияССубконто.Сумма,
    ХозрасчетныйДвиженияССубконто.ВалютнаяСуммаДт,
    ХозрасчетныйДвиженияССубконто.ВалютнаяСуммаКт,
    ХозрасчетныйДвиженияССубконто.СуммаНУКт
ПОМЕСТИТЬ Регистры
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(
            &ДатаН,
            &ДатаК,
            счетКт = &сч
                Или счетКт = &сч1,
            ,
            ) КАК ХозрасчетныйДвиженияССубконто
ГДЕ
    ХозрасчетныйДвиженияССубконто.Регистратор.Ссылка ССЫЛКА Документ.ПриходныйКассовыйОрдер
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    регистры.регистратор КАК регистратор,
    регистры.СчетКт,
    регистры.СчетДт,
    регистры.регистратор.Номер,
    регистры.регистратор.Дата,
    регистры.регистратор.СуммаДокумента,
    сч.ДокументОснование,
    сч.Дата КАК датаСФ,
    сч.СуммаДокумента КАК суммаСФ,
    сч.Проведен,
    регистры.ВалютнаяСуммаДт,
    регистры.ВалютнаяСуммаКт,
    регистры.СуммаНУКт
ИЗ
    Регистры КАК регистры
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.СчетФактураВыданный КАК сч
        ПО регистры.регистратор.Ссылка = сч.ДокументОснование
ИТОГИ
    КОЛИЧЕСТВО(регистратор)
ПО
    ОБЩИЕ

параметры по счетам 62.01, 62.02. Если по доке есть движение по обоим счетам то он выводит 2 строки, по одной на каждую проводку, а нужно чтобы была сумма по полям "сумма проводки по кредиту 62.01" и "сумма проводки по кредиту 62.02". как сделать?!

1 Dmitriy_76

01.10.15

✎

11:54

покажи что выводит и что надо

2 NordMad

01.10.15

✎

12:00

у меня получается так (пример на 2х проводках, их может быть больше):
http://prnt.sc/8mgx0e
а нужно чтобы суммировало в 2 колонки все:
http://prnt.sc/8mgxb7

3 Dmitriy_76

01.10.15

✎

12:13

(2) в первой таблице счета..во второй суммы.. . где связь?

4 Fragster

гуру

01.10.15

✎

12:15

Если это на СКД - в настройках сделать группировку по колонкам по счету

5 NordMad

01.10.15

✎

12:59

(1) в первой дергаю регистры, во второй свожу с счет фактурами. вся необходимая информация есть, но она просто не в том виде котором надо.

6 NordMad

01.10.15

✎

12:59

(5) регистраторы*

7 NordMad

01.10.15

✎

13:00

(4) а если не в СКД как код запроса поменять?! просто не совсем представляю как строки в колонки грубо говоря переделать

8 maximus77

01.10.15

✎

14:04

Выбор
     когда счетКт = &сч
         Тогда сумма
     иначе 0
КОНЕЦ Как Суммапокредиту6201,

Выбор
     когда счетКт = &сч1
          Тогда сумма
     иначе 0
Конец как Суммапокредиту6202,

далее группируешь по регистратору и суммируешь по этим колонкам и получится один регистратор 2 колонки (зависит от колличества группировок).

2-й способ выборка из временной таблицы отдельно по каждому счету и объединение их в одну таблицу

9 NordMad

01.10.15

✎

14:44

(8) я конечно извиняюсь но не могу понять как это прикрутить к запросу?
что то типа такого - выдает ошибки
ВЫБРАТЬ
    ХозрасчетныйДвиженияССубконто.Регистратор КАК регистратор,
    ХозрасчетныйДвиженияССубконто.СчетКт,
    ХозрасчетныйДвиженияССубконто.СчетДт,
    ХозрасчетныйДвиженияССубконто.Сумма,
    ХозрасчетныйДвиженияССубконто.ВалютнаяСуммаДт,
    ХозрасчетныйДвиженияССубконто.ВалютнаяСуммаКт,
    ХозрасчетныйДвиженияССубконто.СуммаНУКт
ПОМЕСТИТЬ Регистры
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(
            &ДатаН,
            &ДатаК,
            Выбор
     когда счетКт = &сч
         Тогда сумма
     иначе 0
КОНЕЦ Как Суммапокредиту6201,

Выбор
     когда счетКт = &сч1
          Тогда сумма
     иначе 0
Конец как Суммапокредиту6202, ,
            ,
            ) КАК ХозрасчетныйДвиженияССубконто
ГДЕ
    ХозрасчетныйДвиженияССубконто.Регистратор.Ссылка ССЫЛКА Документ.ПриходныйКассовыйОрдер
;

10 maximus77

01.10.15

✎

15:00

конструкция "выбор" (это описание поля) помещается в ВЫБРАТЬ. Примерно так. Но у Вас в запросе много других полей и не понятно нужны ли они в дальнейшем или нет.

ВЫБРАТЬ
    ВложенныйЗАпрос.Регистратор,
    СУММА(ВложенныйЗАпрос.Суммапокредиту6201) как Суммапокредиту6201,
    СУММА(ВложенныйЗАпрос.Суммапокредиту6202)

ПОМЕСТИТЬ Регистры
ИЗ (

ВЫБРАТЬ
    ХозрасчетныйДвиженияССубконто.Регистратор КАК регистратор,
    ХозрасчетныйДвиженияССубконто.СчетКт,
    ХозрасчетныйДвиженияССубконто.СчетДт,
    ХозрасчетныйДвиженияССубконто.Сумма,
    ХозрасчетныйДвиженияССубконто.ВалютнаяСуммаДт,
    ХозрасчетныйДвиженияССубконто.ВалютнаяСуммаКт,
    ХозрасчетныйДвиженияССубконто.СуммаНУКт,
    Выбор
        когда ХозрасчетныйДвиженияССубконто.СчетКт = &сч
            Тогда ХозрасчетныйДвиженияССубконто.Сумма
        иначе 0
    КОНЕЦ Как Суммапокредиту6201,
    Выбор
        когда ХозрасчетныйДвиженияССубконто.СчетКт = &сч1
            Тогда ХозрасчетныйДвиженияССубконто.Сумма
        иначе 0
    КОНЕЦ Как Суммапокредиту6202

ИЗ
    РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(
            &ДатаН,
            &ДатаК,
            счетКт = &сч
                Или счетКт = &сч1,
            ,
            ) КАК ХозрасчетныйДвиженияССубконто
ГДЕ
    ХозрасчетныйДвиженияССубконто.Регистратор.Ссылка ССЫЛКА Документ.ПриходныйКассовыйОрдер) как ВложенныйЗапрос
СГРУППИРОВАТЬ ПО
ВложенныйЗАпрос.Регистратор

11 NordMad

01.10.15

✎

15:38

(10) спасибо, работает. несколько плаваю я в теме запросов. вложенными не приходилось до этого пользоваться