Документ на основании

(7) ТиС 7.7 932

Процедура ВводНаОсновании(ДокументОснование)

    СинонимДокумента    = ПредставлениеВида();
    СинонимОснования    = ДокументОснование.ПредставлениеВида();

    Список    = глПолучитьСписокВводимыхНаОсновании(ДокументОснование);
    Поз        = Список.НайтиЗначение(Вид());

    // выполним проверку, можно ли вводить документ на основании ДокументОснование
    Если Поз = 0 Тогда
        // ДокументОснование не найден в списке разрешенных
        Предупреждение("Документ """ + СинонимДокумента + """ нельзя вводить на основании """ + СинонимОснования + """", 60);
        СтатусВозврата(0);
        Возврат;
    КонецЕсли;

    КодОперации    = Перечисление.КодыОпераций.Продажа;
    глЗаполнитьШапкуНаОсн(Контекст, ДокументОснование);

    ДатаОплаты = глБанковскаяДата(ДатаДок, Договор.ГлубинаКредита);

    // По умолчанию выписываем в той же валюте и по тому же курсу, что и документ-основание
    Валюта = ДокументОснование.Валюта;
    Курс   = ДокументОснование.Курс;

    // Документы оптовой торговли можно оформлять только с оптового склада
    Если (Склад.РозничныйСклад = 1) Тогда
        Склад = "";
    КонецЕсли;

    // если основание - неподтвержденная заявка, то нужно заполнить
    // склад по умолчанию
    Если ПустоеЗначение(Склад) = 1 Тогда
        ВремСклад    = глЗначениеПоУмолчанию("ОсновнойСклад");
        Если ВремСклад.РозничныйСклад = 0 Тогда
            Склад    = ВремСклад;
        КонецЕсли;
    КонецЕсли;

    Результат = ЗаполнениеПоИтогам();
    Если ПустоеЗначение(Результат) = 0 Тогда
        Сообщить(Результат);
        СтатусВозврата(0);
    КонецЕсли;

    СтарыйКонтрагент    = Контрагент;
    СтарыйДоговор        = Договор;

    ПечатьДоговора        = Договор;

КонецПроцедуры // ВводНаОсновании()
Функция ЗаполнениеПоИтогам()

    Перем ЗарезервированниеТовары, ТекСтрокаИтогов;

    // Фирма и договор (контрагента) должны быть заполнены.
    Если ПустоеЗначение(Фирма) = 1 Тогда
        Возврат "Не выбрана фирма!";
    КонецЕсли;

    ФирмаДляОстатковТМЦ = глФирмаДляОстатковТМЦ(Фирма);

    Если ПустоеЗначение(Договор) = 1 Тогда
        Возврат "Не выбран договор контрагента!";
    КонецЕсли;

    РегОбщ = СоздатьОбъект("Регистры");
    РегЗаявки  = РегОбщ.Заявки;
    РегОстатки = РегОбщ.ОстаткиТМЦ;
    РегРезервы = РегОбщ.РезервыТМЦ;

    // Установим фильтры на регистр "Заявки".
    РегЗаявки.УстановитьЗначениеФильтра("Фирма", ФирмаДляОстатковТМЦ, 2);
    РегЗаявки.УстановитьЗначениеФильтра("ДоговорПокупателя", Договор, 1);

    ЗаполнятьПоОснованию = 0; // Флаг варианта заполнения
    ЗаполнятьСУчетомРезервов = 0;
    ЗаполнятьСУчетомОстатков = 0;
    Если ПустоеЗначение(ДокОснование) = 0 Тогда
        Если ДокОснование.КоличествоСтрок() > 0 Тогда

            ЗаполнятьПоОснованию = 1;

            // Если есть заказ, то заполняем недополученными по нему товарами
            РегЗаявки.УстановитьЗначениеФильтра("ЗаявкаПокупателя", ДокОснование, 1);

            // Получим список номенклатуры для установки фильтров
            СписокТоваров = СоздатьОбъект("СписокЗначений");
            ДокОснование.ВыгрузитьТабличнуюЧасть(СписокТоваров, "Номенклатура");

            РегЗаявки.УстановитьЗначениеФильтра("Номенклатура", СписокТоваров, 2);

            // Определим необходимо ли контролировать остатки,
            // а, следовательно, заполнять с учетом свободных остатков.
            Если Константа.КонтрольОтрицательныхОстатков = Перечисление.СпособыКонтроляОстатковТМЦ.НеКонтролировать Тогда
                ЗаполнятьСУчетомОстатков = 0;
            Иначе
                ЗаполнятьСУчетомОстатков = 1;
                Если глПолучитьПолномочие("РазрешитьПродаватьРезерв") = 0 Тогда
                    ЗаполнятьСУчетомРезервов = 1;
                КонецЕсли;
            КонецЕсли;

            // Если склад не выбран, то заполним без учета остатков
            Если ПустоеЗначение(Склад) = 1 Тогда
                ЗаполнятьСУчетомОстатков = 0;
            КонецЕсли;

            // Установим фильтры на регистры: "ОстаткиТМЦ", "РезервыТМЦ".
            Если ЗаполнятьСУчетомОстатков = 1 Тогда
                РегОстатки.УстановитьЗначениеФильтра("Фирма",  ФирмаДляОстатковТМЦ, 2);
                РегОстатки.УстановитьЗначениеФильтра("Номенклатура", СписокТоваров, 2);
            КонецЕсли;
            Если ЗаполнятьСУчетомРезервов = 1 Тогда
                РегРезервы.УстановитьЗначениеФильтра("Фирма",  ФирмаДляОстатковТМЦ, 2);
                РегРезервы.УстановитьЗначениеФильтра("Номенклатура", СписокТоваров, 2);
            КонецЕсли;

        КонецЕсли;
    КонецЕсли;

    // Если нужно, то выполним временный расчет регистра
    Если Выбран() = 0 Тогда // новый документ
        Если ДатаДок < ПолучитьДатуТА() Тогда // выписываемый задним числом
            РегЗаявки.ВременныйРасчет();
            РегОстатки.ВременныйРасчет(ЗаполнятьСУчетомОстатков);
            РегРезервы.ВременныйРасчет(ЗаполнятьСУчетомРезервов);
            РегОбщ.РассчитатьРегистрыПо(ДатаДок);
        КонецЕсли;
    Иначе // сохраненный документ
        Если СравнитьТА() < 1 Тогда // позиция не больше ТА
            РегЗаявки.ВременныйРасчет();
            РегОстатки.ВременныйРасчет(ЗаполнятьСУчетомОстатков);
            РегРезервы.ВременныйРасчет(ЗаполнятьСУчетомРезервов);
            РегОбщ.РассчитатьРегистрыНа(ТекущийДокумент());
        КонецЕсли;
    КонецЕсли;

    РегЗаявки.ВыгрузитьИтоги(ЗарезервированниеТовары, 1, 1);
    ЗарезервированниеТовары.Свернуть("Номенклатура", "КоличествоРасход,СтоимостьРасход");

    Если ЗаполнятьПоОснованию = 0  Тогда

        ВалютаОстатков = Договор.ВалютаВзаиморасчетов;

        ЗарезервированниеТовары.ВыбратьСтроки();

        СуммаВзаиморасчетов = 0;
        Пока ЗарезервированниеТовары.ПолучитьСтроку() = 1 Цикл
            НоваяСтрока();

            Номенклатура = ЗарезервированниеТовары.Номенклатура;
            Единица      = Номенклатура.ОсновнаяЕдиница;
            Коэффициент  = Единица.Коэффициент;
            Количество   = ЗарезервированниеТовары.КоличествоРасход / ?(Коэффициент = 0, 1, Коэффициент);

            Если УчитыватьНДС = 1 Тогда
                СтавкаНДС = Номенклатура.СтавкаНДС;
            КонецЕсли;
            Если УчитыватьНП = 1 Тогда
                СтавкаНП = Номенклатура.СтавкаНП;
            КонецЕсли;

            ОбщСумма     = глПересчет(ЗарезервированниеТовары.СтоимостьРасход, ВалютаОстатков, ДатаДок, Валюта, Курс);

            ВремСтавкаНП = Номенклатура.СтавкаНП.Ставка;

            РассчитатьСуммыПоВарианту(
            ОбщСумма,
            глВыделяемыйНДС(Номенклатура.СтавкаНДС), // коэффициент выделяемого НДС
            ВремСтавкаНП/(100 + ВремСтавкаНП),       // коэффициент выделяемого НП
            Сумма, СуммаНДС, СуммаНП);

            СуммаВзаиморасчетов = СуммаВзаиморасчетов + ЗарезервированниеТовары.СтоимостьРасход;

            Если Количество <> 0 Тогда
                Цена = Сумма / Количество;
            Иначе
                Цена = Сумма;
            КонецЕсли;
        КонецЦикла;

    Иначе // Заполняем по основанию

        // При заполнении на основании Заявки цены, суммы и скидки надо брать из основания
        ТаблицаДокумента = СоздатьОбъект("ТаблицаЗначений");
        ДокОснование.ВыгрузитьТабличнуюЧасть(ТаблицаДокумента);

        ВалютаОсн    = ДокОснование.Валюта;
        КурсОсн        = ДокОснование.Курс;

        ТаблицаДокумента.ВыбратьСтроки();
        Пока ТаблицаДокумента.ПолучитьСтроку()=1 Цикл
            // Есть остатки по этой строке?
            ТекСтрокаИтогов = 0;
            Если ЗарезервированниеТовары.НайтиЗначение(ТаблицаДокумента.Номенклатура, ТекСтрокаИтогов, "Номенклатура") = 0 Тогда // нет остатков
                Продолжить;
            КонецЕсли;
            КоличествоРасход = ЗарезервированниеТовары.ПолучитьЗначение(ТекСтрокаИтогов, "КоличествоРасход");
            Если КоличествоРасход = 0 Тогда // нет остатков
                Продолжить;
            КонецЕсли;

            ТекНоменклатура = ТаблицаДокумента.Номенклатура;

            Отпустить = Мин(ТаблицаДокумента.Количество, КоличествоРасход / ТаблицаДокумента.Коэффициент);;
            Если (ТекНоменклатура.ВидНоменклатуры = Перечисление.ВидыНоменклатуры.Услуга)
             или (ТекНоменклатура.ВидНоменклатуры = Перечисление.ВидыНоменклатуры.Работа) Тогда
                // Считаем, что оказать услуги или выполнить работы нам ничего не мешает.
                МожноОтпустить  = Отпустить;
            Иначе
                Если ЗаполнятьСУчетомОстатков = 1 Тогда

                    // Получим количество с учетом свободного остатка и на складе, и по фирме.
                    МожноОтпустить = ПолучитьКоличество(ФирмаДляОстатковТМЦ, ТекНоменклатура, Отпустить,
                                                        РегОстатки, ЗаполнятьСУчетомРезервов, РегРезервы);
                Иначе
                    МожноОтпустить = Отпустить;
                КонецЕсли;
            КонецЕсли;

            Если МожноОтпустить = 0 Тогда
                Продолжить;
            КонецЕсли;

            НоваяСтрока();
            СтавкаНДС     = ТаблицаДокумента.СтавкаНДС;
            СтавкаНП     = ТаблицаДокумента.СтавкаНП;
            Номенклатура= ТаблицаДокумента.Номенклатура;
            Единица     = ТаблицаДокумента.Единица;
            Коэффициент = ТаблицаДокумента.Коэффициент;
            Количество     = МожноОтпустить;
            Цена         = глПересчет(ТаблицаДокумента.Цена, ВалютаОсн, КурсОсн, Валюта, Курс);
            ВремСумма     = ТаблицаДокумента.Сумма * Количество / ТаблицаДокумента.Количество; // для учета скидок в документе основании
            Сумма        = глПересчет(ВремСумма, ВалютаОсн, КурсОсн, Валюта, Курс);

            глПересчетТаблЧасти(Контекст,"Сумма");
        КонецЦикла; // по строкам основания

        ОснованиеСумма = ДокОснование.Итог("Сумма");
        СуммаВзаиморасчетов    = ?(ОснованиеСумма = 0, 0, ДокОснование.СуммаВзаиморасчетов * Итог("Сумма") / ОснованиеСумма);

    КонецЕсли; // ЗаполнятьПоОснованию = 0

    Если КоличествоСтрок() = 0 Тогда
        Возврат "Все заказанные товары либо получены, либо их нет в наличии!";
    КонецЕсли;

    Возврат "";    // успешное завершение

КонецФункции // ЗаполнениеПоИтогам()